funits_mod.f

Go to the documentation of this file.

      MODULE funits

! Whether this processor should write the log file in DMP mode.
! Usually this flag is true only for PE_IO.  All the PEs may be forced
! to write a log file by setting ENABLE_DMP_LOG to .true. in output_mod.f.
      LOGICAL :: dmp_log

! Flag indicated that the log was opened globally.
      LOGICAL :: log_was_closed = .false.

! RRATES debug file unit number
      INTEGER, PARAMETER :: unit_rrates = 43

! mfix.dat file unit number
      INTEGER, PARAMETER :: unit_dat = 51

! RUN_NAME.OUT file unit number
      INTEGER, PARAMETER :: unit_out = 52

! RUN_NAME.LOG file unit number. (DEFAULT/Serial 53)
      INTEGER, PARAMETER :: unit_log = 53

! Temporary (scratch) file unit number
      INTEGER, PARAMETER :: unit_tmp = 54

! RUN_NAME.RES file unit number
      INTEGER, PARAMETER :: unit_res = 55

! RUN_NAME.SPx file unit offset number
      INTEGER, PARAMETER :: unit_spx = 60

      CONTAINS


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: NEWUNIT                                                !
!  Author: A. Choudhary                               Date: 01/21/2015 !
!                                                                      !
!  Purpose: Finds an open i/o unit number; Usage:                      !
!   integer myunit                                                     !
!   open(convert='big_endian',unit=newunit(myunit),file='filename')    !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      INTEGER FUNCTION newunit(unit)
      IMPLICIT NONE

! optional variable to hold unit number
      INTEGER, INTENT(OUT), OPTIONAL  :: unit
! lower and upper limits to search for available units
      INTEGER, PARAMETER  :: lun_min = 100, lun_max= 999
! check to see if the unit is open
      LOGICAL :: is_open
! looping variable
      INTEGER :: lun

      newunit = -1

      DO lun = lun_min, lun_max
        INQUIRE(unit=lun, opened=is_open)
        IF(.NOT.is_open) THEN
          newunit = lun
          EXIT
        END IF
      END DO

      IF(present(unit)) unit=newunit

      RETURN
      END FUNCTION newunit

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CREATE_DIR                                             !
!  Author: J.Musser                                      Date: 06/2015 !
!                                                                      !
!  Purpose: Create the directory pDIR in the run directory.            !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE create_dir(PDIR)

      use compar, only: mype, pe_io

      IMPLICIT NONE

      CHARACTER(LEN=*), INTENT(IN) :: pDIR

      CHARACTER(LEN=256) :: CMD
      INTEGER :: IOS
      INTEGER, PARAMETER :: tUNIT = 9638

      IF(mype /= pe_io) RETURN

      OPEN(file=trim(pdir)//'/tmp',unit=tunit,status='NEW',iostat=ios)

      IF(ios == 0 )THEN
         close(tunit)
         WRITE(cmd,"('rm ',A,'/tmp')")adjustl(trim(pdir))
         CALL system(trim(cmd))
      ELSE
         write(*,"('Creating directory ',A)") pdir
         WRITE(cmd,"('mkdir ',A)")pdir
         CALL system(trim(cmd))
      ENDIF

      RETURN
      END SUBROUTINE create_dir


      END MODULE funits