check_dmp_prereqs.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_DMP_PREREQS                                       !
!  Purpose: Check the distributed parallel namelist variables.         !
!                                                                      !
!  Author: P. Nicoletti                               Date: 14-DEC-99  !
!  Reviewer: J.Musser                                 Date: 16-Jan-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_dmp_prereqs


! Global Variables:
!---------------------------------------------------------------------//
! Number of ranks.
      use compar, only: numpes
! DMP grid partitioning data:
      use compar, only: nodesi  ! Partitions along x-axis
      use compar, only: nodesj  ! Partitions along y-axis
      use compar, only: nodesk  ! Partitions along z-axis
! Domain partitions in various directions.
      use geometry, only: imax
      use geometry, only: jmax
      use geometry, only: kmax

! Global Parameters:
!---------------------------------------------------------------------//
      use param1, only: undefined_i

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      implicit none

! Local Variables:
!---------------------------------------------------------------------//
! The approximate number of domain partitions that will be assigned
! to each process for DMP runs. (eg IMAX/NODESI)
      INTEGER :: LAYERS

! Local Parameters:
!---------------------------------------------------------------------//
! The minimum number of computational cell layers required.
      INTEGER, PARAMETER :: DMP_MIN = 3

! Initialize the error manager.
      CALL init_err_msg("CHECK_DMP_PREREQS")

! Verify that DMP partitioning information is provided given if
! there is more than one rank.
      IF( numpes > 1 ) then
         IF(nodesi .EQ. undefined_i .AND.                              &
            nodesj .EQ. undefined_i .AND.                              &
            nodesk .EQ. undefined_i) THEN
            WRITE(err_msg,1000)
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

! Initialize NODE values if undefined. If this is a DMP run, then a
! warning message is passed to the user.
      IF (nodesi .EQ. undefined_i) THEN
         IF(numpes > 1) THEN
            WRITE(err_msg,1001)'I','I'
            CALL flush_err_msg
         ENDIF
         nodesi = 1
! Verify that the DMP partition is appropriate for the domain.
      ELSEIF(nodesi > 1) THEN
         layers=int(imax/nodesi)
         IF(layers < dmp_min) THEN
            WRITE(err_msg,1002) 'X', dmp_min, 'I', 'I', layers
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

      IF (nodesj .EQ. undefined_i) THEN
         IF(numpes > 1) THEN
            WRITE(err_msg,1001)'J','J'
            CALL flush_err_msg
         ENDIF
         nodesj = 1

! Verify that the DMP partition is appropriate for the domain.
      ELSEIF(nodesj > 1) THEN
         layers=int(jmax/nodesj)
         IF(layers < dmp_min) THEN
            WRITE(err_msg,1002) 'Y', dmp_min, 'J', 'J', layers
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

      IF (nodesk .EQ. undefined_i) THEN
         IF(numpes > 1) THEN
            WRITE(err_msg,1001)'K','K'
            CALL flush_err_msg
         ENDIF
         nodesk = 1
! Verify that the DMP partition is appropriate for the domain.
      ELSEIF(nodesk > 1) THEN
         layers=int(kmax/nodesk)
         IF(layers < dmp_min) THEN
            WRITE(err_msg,1002) 'Z', dmp_min, 'K', 'K', layers
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

! Verify that the number of requested processes (munPEs) matches
! the domain decomposition (nodesi * nodesj * nodesk).
      IF(numpes .NE. (nodesi*nodesj*nodesk)) THEN
         WRITE(err_msg,1003) numpes, (nodesi*nodesj*nodesk)
         CALL flush_err_msg(abort=.true.)
      ENDIF


      CALL finl_err_msg

      RETURN


 1000 FORMAT('Error 1000: No DMP grid partitioning data provided in ', &
         'mfix.dat.',/'NODESI, NODESJ, and NODESK are all undefined.',/&
         'Refer to the users manual for required input and make the ', &
         'necessary',/'corrections to the input data file.')

 1001 FORMAT('Warning 1001: Setting NODES',a1,' to default: ',         &
         'NODES',a1,'=1.')

 1002 FORMAT('Error 1002:  Too many DMP partitions specified for ',    &
         a1,' axis.',/'There must be at least ',i2,' computational ',  &
         'cells per DMP parition.',/' >>> Computational Cells/DMP ',   &
         'Partition = int(',a1,'MAX/NODES',a1,') = ',i2,/'Refer to ',  &
         'the users manual for required input and make the necessary',/&
         'corrections to the input data file.')

 1003 FORMAT('Error 1003: The number of requested processors is ',     &
         'inconsistent',/'with the domain decomposition, (NODESi * ',  &
         'NODESj * NODESk).',/' These numbers must match.',2/,         &
         '  Number of requested processes: ',i8,/,                     &
         '  Domain decomposition : ',i8,/)


      END SUBROUTINE check_dmp_prereqs