mod_bc_i.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: MOD_BC_I                                                C
!  Author: P. Nicoletti                               Date: 10-DEC-91  C
!                                                                      C
!  Purpose: modify the "I" values for the b.c. plane                   C
!     This is a yz plane                                               C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE mod_bc_i(BCV)

      use bc, only: bc_i_w, bc_i_e
      use bc, only: bc_j_s, bc_j_n
      use bc, only: bc_k_b, bc_k_t
      use bc, only: bc_plane

      USE geometry, only: icbc_flag

      USE compar
      USE mpi_utility

      use error_manager
      USE functions

      IMPLICIT NONE

!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! boundary condition index
      INTEGER, INTENT(IN) :: BCV

! i cell indices defining location of yz plane
      INTEGER :: I_w, I_e
! south/bottom j,k cell indices of yz plane
      INTEGER :: J_s, K_b

!-----------------------------------------------
! Local variables
!-----------------------------------------------
!     'IJK' indices
      INTEGER :: OWNER
      INTEGER :: J, K
      INTEGER :: IJK , IPJK

      INTEGER :: IER
      LOGICAL :: ERROR
      INTEGER :: I_FLUID, IJK_FLUID
      INTEGER :: I_WALL,  IJK_WALL

      CALL init_err_msg("MOD_BC_I")

      i_w = bc_i_w(bcv)
      i_e = bc_i_e(bcv)

      j_s = bc_j_s(bcv)
      k_b = bc_k_b(bcv)

! Establish the OWNER of the BC
      owner = merge(mype, 0, is_on_mype_owns(i_w, j_s, k_b))
      CALL global_all_sum(owner)

      IF(mype == owner) THEN

         ijk  = funijk(i_w,   j_s, k_b)
         ipjk = funijk(i_w+1, j_s, k_b)

! Flow on west boundary (fluid cell on east).
         IF(wall_icbc_flag(ijk) .AND. icbc_flag(ipjk)(1:1)=='.') THEN
            i_w = i_w
            i_e = i_e
            bc_plane(bcv) = 'E'

! Flow on east boundary (fluid cell on west).
         ELSEIF(wall_icbc_flag(ipjk) .AND. icbc_flag(ijk)(1:1)=='.') THEN
            i_w = i_w + 1
            i_e = i_e + 1
            bc_plane(bcv) = 'W'

! Set the plane of a value we know to be wrong so we can detect the error.
         ELSE
            bc_plane(bcv) = '.'
         ENDIF
      ENDIF

! The owner distributes the new Iw/Ie coordinates to the other ranks.
      CALL bcast(i_w,   owner)
      CALL bcast(i_e,   owner)
      CALL bcast(bc_plane(bcv), owner)


! If there is an error, send IJK/IPJK to all ranks. Report and exit.
      IF(bc_plane(bcv) == '.') THEN
         CALL bcast(ipjk,owner)
         CALL bcast(ijk, owner)

         WRITE(err_msg, 1100) bcv, i_w, i_e, j_s, k_b,                 &
            ijk, icbc_flag(ijk),  ipjk, icbc_flag(ipjk)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1100 FORMAT('Error 1100: Cannot locate flow plane for boundary ',     &
         'condition ',i3,'.',2/3x,'I West   =  ',i6,' I East   = ',i6,/&
         3x,'J South  =  ',i6,' K Bottom = ',i6,2/' The following ',   &
         'should conttain a wall cell and fluid cell:',/3x,'IJK  ',i9, &
         ' :: ',a3,/3x,'IPJK ',i9,' :: ',a3,2/' Maybe no IC was ',     &
         'specified for the fluid cell.')

! Store the new values in the global data array.
      bc_i_w(bcv) = i_w
      bc_i_e(bcv) = i_e

! Set up the I-indices for checking the entire BC region.
      i_wall = bc_i_w(bcv)
      i_fluid = merge(i_wall-1, i_wall+1, bc_plane(bcv)=='W')


! First pass through all of the BC region and verify that you have
! inflow/outflow specified against a wall. Flag any errors.
      error = .false.
      DO k = bc_k_b(bcv), bc_k_t(bcv)
      DO j = bc_j_s(bcv), bc_j_n(bcv)

         IF(.NOT.is_on_mype_plus2layers(i_fluid,j,k)) cycle
         IF(.NOT.is_on_mype_plus2layers(i_wall, j,k)) cycle
         IF(dead_cell_at(i_fluid,j,k)) cycle
         IF(dead_cell_at(i_wall, j,k)) cycle

         ijk_wall = funijk(i_wall,j,k)
         ijk_fluid = funijk(i_fluid,j,k)

! Verify that the the fluid and wall cells match the ICBC_FLAG.
         IF(.NOT.(wall_icbc_flag(ijk_wall) .AND.                       &
            icbc_flag(ijk_fluid)(1:1) == '.')) error = .true.

      ENDDO
      ENDDO

! Sync up the error flag across all processes.
      CALL global_all_or(error)

! If an error is detected, have each rank open a log file and write
! it's own message. Otherwise, we need to send all the data back to
! PE_IO and that's too much work!
      IF(error) THEN

         CALL open_pe_log(ier)

         WRITE(err_msg, 1200) bcv
         CALL flush_err_msg(footer=.false.)

         DO k = bc_k_b(bcv), bc_k_t(bcv)
         DO j = bc_j_s(bcv), bc_j_n(bcv)

            IF(.NOT.is_on_mype_plus2layers(i_fluid,j,k)) cycle
            IF(.NOT.is_on_mype_plus2layers(i_wall, j,k)) cycle
            IF(dead_cell_at(i_fluid,j,k)) cycle
            IF(dead_cell_at(i_wall, j,k)) cycle

            ijk_wall = funijk(i_wall,j,k)
            ijk_fluid = funijk(i_fluid,j,k)

            IF(.NOT.(wall_icbc_flag(ijk_wall) .AND.                    &
               icbc_flag(ijk_fluid)(1:1) == '.')) THEN

               WRITE(err_msg, 1201) &
                  i_wall,  j, k, ijk_wall, icbc_flag(ijk_wall),        &
                  i_fluid, j, k, ijk_fluid, icbc_flag(ijk_fluid)
               CALL flush_err_msg(header=.false., footer=.false.)
            ENDIF
         ENDDO
         ENDDO

         WRITE(err_msg,"('Please correct the mfix.dat file.')")
         CALL flush_err_msg(header=.false., abort=.true.)

      ENDIF


 1200 FORMAT('Error 1200: Illegal geometry for boundary condition:',i3)

 1201 FORMAT(' ',/14x,'I',7x,'J',7x,'K',7x,'IJK',4x,'FLAG',/3x,        &
         'WALL ',3(2x,i6),2x,i9,3x,a,/3x,'FLUID',3(2x,i6),2x,i9,3x,a)


      CALL finl_err_msg

      RETURN
      END SUBROUTINE mod_bc_i