cfwallcontact.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
!
!  Subroutine: CFWALLCONTACT(WALL, L, WALLCONTACT)
!  Purpose: Check if particle L is in contact with WALL.  If so, set
!           WALLCONTACT to 1, else WALLCONTACT is 0
!
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

      SUBROUTINE cfwallcontact(WALL, L, WALLCONTACT)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param1
      USE constant
      USE parallel
      USE compar
      Use discretelement
      USE des_bc
      use geometry, only: do_k
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! Given wall ID number (1=west, 2=east, 3=south, 4=north, 5=bottom,
! 6=top)
      INTEGER, INTENT (IN) :: WALL
! Given particle ID number
      INTEGER, INTENT (IN) :: L
! Flag to indicate whether given particle is in contact with given wall
! (1=contact, 0 = no contact)
      INTEGER, INTENT (INOUT) :: WALLCONTACT
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! local variables for x, y, z position of the particle
      DOUBLE PRECISION :: XPOS, YPOS, ZPOS
! local variables to define system dimensions
      DOUBLE PRECISION :: LXE, LXW, LYN, LYS, LZT, LZB
! local variables: distance between particle surface and wall
      DOUBLE PRECISION :: DistApart
!-----------------------------------------------

! assign temporary local variables for quick reference
      lxe = ex2
      lxw = wx1
      lyn = ty2
      lys = by1
      lzt = nz2
      lzb = sz1

! assign temporary local variables for manipulation/use
      xpos = des_pos_new(l,1)
      ypos = des_pos_new(l,2)
      IF(do_k) zpos = des_pos_new(l,3)


! initialize
      wallcontact = 0

      IF (des_le_bc) THEN
! Current implementation of Lees & Edwards boundaries implies all other
! boundaries are periodic (i.e. no walls in system)
         RETURN
      ELSEIF (des_periodic_walls) THEN
! Check if current wall corresponds to a periodic boundary (i.e. no wall)
         IF( (des_periodic_walls_x .AND. (wall.EQ.1.OR.wall.EQ.2)).OR.&
             (des_periodic_walls_y .AND. (wall.EQ.3.OR.wall.EQ.4)).OR.&
             (do_k.AND.des_periodic_walls_z .AND. &
             (wall.EQ.5.OR.wall.EQ.6)) ) THEN
            RETURN
         ENDIF
      ENDIF

! Note that if no cohesion is used WALL_VDW_OUTER_CUTOFF = zero.
! west wall (X)
      IF(wall.EQ.1) THEN
         distapart = xpos-lxw-des_radius(l)
! consider wall contact calculations for particle wall distances less
! than the cutoff
         IF( distapart <= wall_vdw_outer_cutoff ) wallcontact = 1

! east wall (X)
      ELSEIF(wall.EQ.2) THEN
         distapart = lxe-xpos-des_radius(l)
         IF( distapart <= wall_vdw_outer_cutoff ) wallcontact = 1

! south wall (Y)
      ELSEIF(wall.EQ.3) THEN
         distapart = ypos-(lys)-des_radius(l)
         IF( distapart <= wall_vdw_outer_cutoff ) wallcontact = 1

! north wall (Y)
      ELSEIF(wall.EQ.4) THEN
         distapart = lyn-ypos-des_radius(l)
         IF( distapart <= wall_vdw_outer_cutoff ) wallcontact = 1

! bottom wall (Z)
      ELSEIF(wall.EQ.5) THEN
         distapart = zpos-lzb-des_radius(l)
         IF( distapart <= wall_vdw_outer_cutoff ) wallcontact = 1

! top wall (Z)
      ELSEIF(wall.EQ.6) THEN
         distapart = lzt-zpos-des_radius(l)
         IF( distapart <= wall_vdw_outer_cutoff ) wallcontact = 1
      ENDIF

      RETURN
      END SUBROUTINE cfwallcontact