toleranc_mod.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: tolerance                                              C
!  Purpose: Specify all tolerance parameters                           C
!                                                                      C
!  Author: M. Syamlal                                 Date: 24-JUL-92  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      MODULE toleranc

      use param1, only: one

! Minimum value of solids volume fraction tracked
      DOUBLE PRECISION, PARAMETER :: zero_ep_s = 1.0d-8

! Small value for species mass fraction for disregarding residual
! calculation
      DOUBLE PRECISION, PARAMETER :: zero_x_gs = 1.0d-7

! Dilute flow threshold. When the volume fraction of a certain phase
! in a cell is smaller than this value the momentum equation for that
! phase is not solved in the cell.
      DOUBLE PRECISION, PARAMETER :: dil_ep_s = 1.0d-4

! Tolerance used for comparing two numbers for equality in function
! compare(a, b)
      DOUBLE PRECISION, PARAMETER :: tol_com = 1.0d-4

! Upper bound for temperatures
      DOUBLE PRECISION, PARAMETER :: tmax = 4000.d0

! Lower bound for temperatures
      DOUBLE PRECISION, PARAMETER :: tmin = 250.d0

! Reciprocal of a maximum molecular weight
      DOUBLE PRECISION, PARAMETER :: omw_max = (one/500.d0)

! Maximum value of velocities set to avoid divergence problems.
      DOUBLE PRECISION :: max_inlet_vel

! User definable factor used to scale MAX_INLET_VEL. Default value is 1.
      DOUBLE PRECISION :: max_inlet_vel_fac

! Maximum allowed velocity of gas or solids in case no inlet velocities
! (or zero velocities) are defined at inlet (see function
! check_vel_bound)
      DOUBLE PRECISION, PARAMETER :: max_allowed_vel = 500.0d+2

! The following quantities can be specified through the input data
! file, with namelist inputs of the same name.
! ------------------------------------------------------------------->>
! Tolerance in residuals allowed for convergence
      DOUBLE PRECISION :: tol_resid

! Tolerance in energy eq residuals allowed for convergence
      DOUBLE PRECISION :: tol_resid_t

! Tolerance in species eq residuals allowed for convergence
      DOUBLE PRECISION :: tol_resid_x

! Tolerance in scalr eq residuals allowed for convergence
      DOUBLE PRECISION :: tol_resid_scalar

! Tolerance in K & Epsilon eq residuals allowed for convergence
      DOUBLE PRECISION :: tol_resid_k_epsilon

! Tolerance in Granular Temperature eq residuals allowed for convergence
      DOUBLE PRECISION :: tol_resid_th

! Minimum residual for declaring divergence
      DOUBLE PRECISION :: tol_diverge

! Factor for normalizing the residual of gas cont. eq.
      DOUBLE PRECISION :: norm_g

! Factor for normalizing the residual of solids cont. eq.
      DOUBLE PRECISION :: norm_s
! -------------------------------------------------------------------<<

! Detect negative Rho_g in physical_prop to reduce DT in iterate
      LOGICAL :: neg_rho_g = .false.

      CONTAINS


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Purpose: Test if two small values are nearly equal                  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!

      LOGICAL FUNCTION compare (V1, V2)

      use param1, only: small_number, one
      IMPLICIT NONE

! Dummy arguments
! -------------------------------------------------------------------//
! Values to be compared
      DOUBLE PRECISION, INTENT(IN) :: V1, V2

      IF (abs(v1) <= small_number) THEN
         IF (abs(v2) <= small_number) THEN
            compare = .true.
         ELSE
            compare = .false.
         ENDIF
      ELSE
         IF (abs(v2/v1 - one) <= tol_com) THEN
            compare = .true.
         ELSE
            compare = .false.
         ENDIF
      ENDIF
      RETURN
      END FUNCTION compare


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Purpose: Test if given variable is smaller than specified tolerance !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!

      LOGICAL FUNCTION is_small (V, TOL)

      use compar, only: ijkstart3, ijkend3
      use functions, only: fluid_at
      use param, only: dimension_3
      IMPLICIT NONE

! Dummy arguments
!--------------------------------------------------------------------//
! Tolerance value for small
      DOUBLE PRECISION, INTENT(IN) :: TOL
! Field variable array
      DOUBLE PRECISION, INTENT(IN), DIMENSION(DIMENSION_3) :: V

! Local variables
!--------------------------------------------------------------------//
      INTEGER :: IJK

      is_small = .false.
      DO ijk = ijkstart3, ijkend3
         IF (fluid_at(ijk)) THEN
            IF (abs(v(ijk)) > tol) RETURN
         ENDIF
      END DO
      is_small = .true.

      RETURN
      END FUNCTION is_small

      END MODULE toleranc