open_file.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: OPEN_FILE                                              C
!  Purpose: open a file                                                C
!                                                                      C
!  Author: P. Nicoletti                               Date: 12-DEC-91  C
!  Reviewer: P. Nicoletti, W. Rogers, M. Syamlal      Date: 24-JAN-92  C
!                                                                      C
!  Revision Number:                                                    C
!  Purpose:                                                            C
!  Author:                                            Date: dd-mmm-yy  C
!  Reviewer:                                          Date: dd-mmm-yy  C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE open_file(FILENAME, NB, IUNIT, EXT, FULL_NAME,        &
         open_stat, open_access, open_form, irecl, ier)

      use cdist
      use compar

      IMPLICIT NONE

! Dummy Arguments
!---------------------------------------------------------------------//
! FILENAME (without extension)
      CHARACTER(LEN=*), INTENT(IN) :: FILENAME
! File extension.
      CHARACTER(LEN=*), INTENT(IN) :: EXT
! FILENAME + EXTENSION
      CHARACTER(LEN=*), INTENT(INOUT) :: FULL_NAME
! File status (NEW, OLD, UNKNOWN)
      CHARACTER(LEN=*), INTENT(IN) :: OPEN_STAT
! File access method ('SEQUENTIAL', 'DIRECT')
      CHARACTER(LEN=*), INTENT(IN) :: OPEN_ACCESS
! Open form ('FORMATTED' or 'UNFORMATTED')
      CHARACTER(LEN=*)   OPEN_FORM
! Index to first blank character in FILENAME
      INTEGER, INTENT(IN) :: NB
! Unit number to open
      INTEGER, INTENT(IN) :: IUNIT
! Record length
      INTEGER, INTENT(IN) :: IRECL
! Integer Error index:
! 000 - no error
! 100 - NEW run with existing files in directory
! 101 - OLD run missing RES and/or SPx files
! 102 - Unknown OPEN_STAT
      INTEGER, INTENT(OUT) :: IER

! Local Variables
!---------------------------------------------------------------------//
! Logical used to store result of file INQUIRE
      LOGICAL :: FILE_EXISTS

! Logicals that determine if files should be index.
      LOGICAL :: RES_IDX  ! Index RES files
      LOGICAL :: SPX_IDX  ! Index SPx files
      LOGICAL :: USE_IDX  ! Use the IDX value

! Initialize the error flag.
      ier = 0

! Conditions for indexing the RES files for distributed IO.
      res_idx = (mype .NE. pe_io) .OR. (.NOT.bstart_with_one_res)
! Conditions for indexing the SPX files for distributed IO.
      spx_idx = .true.

! Flag for indexing files.
      use_idx = bdist_io .AND. (                                       &
         (spx_idx .AND. (ext(2:3) .EQ. 'SP')) .OR.                     &
         (res_idx .AND. (ext(2:4) .EQ. 'RES')))

! Construct the file name.
      full_name = ''
      IF(use_idx)THEN
         WRITE(full_name,1000) filename(1:nb-1), mype, ext(1:4)
      ELSE
         WRITE(full_name,1001) filename(1:nb-1), ext(1:4)
      ENDIF

! Check to see if the file already exists in the run directory.
      INQUIRE(file=trim(full_name),exist=file_exists)

! NEW files should not be in the run directory.
      IF(file_exists .AND. (open_stat == 'NEW')) THEN
         ier = 100; RETURN
! OLD files must be in the run directory.
      ELSEIF(.NOT. file_exists .AND. open_stat .EQ. 'OLD') THEN
         ier = 101; RETURN
      ENDIF

! Open direct access files.
      IF (open_access == 'DIRECT') THEN
         OPEN(convert='BIG_ENDIAN',unit=iunit, file=trim(full_name), status=open_stat,     &
            recl=irecl, access=open_access, form=open_form, iostat=ier)
      ELSE
! No matter the status passed to the routine, the file is created as
! NEW if it doesn't exist in the run directory.
         IF(.NOT.file_exists) THEN
            OPEN(convert='BIG_ENDIAN',unit=iunit, file=trim(full_name), status='NEW',       &
               access=open_access, form=open_form, iostat=ier)
         ELSEIF(open_stat == 'REPLACE') THEN
            OPEN(convert='BIG_ENDIAN',unit=iunit, file=trim(full_name), status=open_stat,   &
               access=open_access, form=open_form, iostat=ier)
         ELSEIF(open_stat == 'APPEND' .OR. open_stat == 'UNKNOWN') THEN
            OPEN(convert='BIG_ENDIAN',unit=iunit, file=trim(full_name), status='UNKNOWN',   &
               access=open_access, form=open_form, position='APPEND',  &
               iostat=ier)
         ELSE
            ier = 102
         ENDIF
      ENDIF

      RETURN

 1000 FORMAT(a,'_',i5.5,a4)
 1001 FORMAT(a,a4)

      END SUBROUTINE open_file