check_axis.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_AXIS                                              !
!  Author: P. Nicoletti                               Date: 27-NOV-91  !
!                                                                      !
!  Purpose: check geometry data for one axis                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_axis(NA, DIMEN, ALENGTH, DA, AXIS, &
         axis_index, no_ijk, shift)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param
      USE param1
!      USE funits

      use error_manager


      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! number of axis cells (IMAX,JMAX,KMAX)
      INTEGER, INTENT(INOUT) :: NA
! maximum number of cells along axis based on domain decomposition
      INTEGER, INTENT(IN) :: DIMEN
! axis length (XLENGTH,YLENGTH,ZLENGTH)
      DOUBLE PRECISION, INTENT(INOUT) :: ALENGTH
! flag that specifies whether variation along that axis is
! considered (passed variable for NO_I, NO_J, or NO_K)
      LOGICAL, INTENT(IN) :: NO_IJK
! shift dx, dy and dz values (true only for new and restart_1 runs)
      LOGICAL, INTENT(IN) :: SHIFT
! axis checked ('X','Y','Z')
      CHARACTER, INTENT(IN) :: AXIS
! index associated with AXIS ('I','J','K')
      CHARACTER, INTENT(IN) :: AXIS_INDEX
! cell sizes (DX,DY,DZ);
! use explicit dimension for DA
! DA should be dimensioned DA(DIMEN) rather than DA(0:DIMEN+1) to be
! able to use the logic from previous versions that assumed DA(1)
! as the first element.  An error check has been added to ensure that
! DX, DY and DZ definitions in mfix.dat starts with the zeroth
! element; i.e. DA(1).
      DOUBLE PRECISION, INTENT(INOUT), DIMENSION(DIMEN) :: DA
!-----------------------------------------------
! Local parameters
!-----------------------------------------------
! percent error allowed in axis length checks
      DOUBLE PRECISION, PARAMETER :: PERCENT_ERROR = 1.0
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! number of items specified from NA, ALENGTH, DA
      INTEGER :: N_SPECIFIED
! loop counter
      INTEGER :: LC
! temporary storage
      DOUBLE PRECISION :: TEMP_STOR, lSUM, lERR
!-----------------------------------------------


      CALL init_err_msg("CHECK_AXIS")

! 0) Ensure that if DA is defined then it starts with DA(1); i.e. DX(0), DY(0) or DZ(0)
      IF(.NOT.no_ijk)THEN
        IF( da(2) /= undefined .AND. da(1) == undefined) THEN
          WRITE(err_msg, 1001) axis
          CALL flush_err_msg(abort=.true.)
        ENDIF
      ENDIF

 1100 FORMAT('Error 1100: The grid specification must start with D',   &
         a1,'(0)',/'Please correct the mfix.dat file.')

! 1) MAKE SURE AT LEAST TWO OF NA, ALENGTH, DA ARE SPECIFIED
      n_specified = 0
      IF (na /= undefined_i) n_specified = n_specified + 1
      IF (alength /= undefined) n_specified = n_specified + 1
      IF (da(1) /= undefined) n_specified = n_specified + 1
      IF (n_specified < 2) THEN
         WRITE(err_msg, 1101) axis, axis, axis, axis_index
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1101 FORMAT('Error 1101: Insufficient grid information for ',a1,'-',   &
         'axis. You must',/'specify at least two of the following: ',  &
         a1,'LENGTH, D',a1,', and ',a1,'MAX','Please correct the ',    &
         'mfix.dat file.')


! 2) NUMBER OF CELLS NOT SPECIFIED - calculate NA based on
!    input that was specified
      IF(na == undefined_i) THEN
        IF(no_ijk) THEN
          na = 1
        ELSE
          IF(da(2) == undefined) THEN
            temp_stor = alength/da(1)
            na = nint(temp_stor)
            IF(na - 1 > 0) da(2:na) = da(1)
          ELSE
            na = dimen
            DO lc = 2, dimen
               IF (da(lc) == undefined) THEN
                  na = lc - 1
                  EXIT
               ENDIF
            ENDDO
          ENDIF
        ENDIF
        GO TO 700
      ENDIF


      IF(na>=0 .AND. na<=dimen) THEN

! 3) AXIS LENGTH NOT SPECIFIED - calculate ALENGTH based on
!    input that was specified
         IF (alength == undefined) THEN
            IF(no_ijk) THEN
               alength = da(1)
            ELSE
               IF(da(2) == undefined) THEN
                  IF(na - 1 > 0) da(2:na) = da(1)
               ENDIF
               alength = 0.0
               IF (na > 0) alength = sum(da(:na))
            ENDIF
         ENDIF

! 4) CELL SIZE NOT SPECIFIED - calculate NON_VARIABLE DA based on
!    input that was specified
         IF(da(1) == undefined) THEN
            temp_stor = alength/dble(na)
            IF(na > 0) da(:na) = temp_stor
         ENDIF

! 5) ALL 3 SPECIFIED
         IF(.NOT.no_ijk) THEN
            IF(da(2) == undefined) THEN
               IF (na - 1 > 0) da(2:na) = da(1)
            ENDIF
         ENDIF

      ENDIF

! 6) CHECK CONSISTENCY OF AXIS INPUT
  700 CONTINUE

! This must be a legacy check because the code shouldn't get here
! without exiting and DIMEN is calculated, not a hard-coded param.
      IF (na<0 .OR. .NOT.no_ijk .AND. na>dimen-2) THEN
         WRITE(err_msg, 1001) axis_index//'MAX', trim(ival(na))
         CALL flush_err_msg(abort=.true.)
      ENDIF

      IF(alength <= 0.0) THEN
         WRITE(err_msg, 1001) axis//'LENGTH'
         CALL flush_err_msg(abort=.true.)
      ENDIF

      lsum = 0.0
      DO lc = 1, na
         IF (da(lc)<=0.0 .OR. da(lc)==undefined) THEN
            WRITE(err_msg, 1201) trim(ivar(axis,lc))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         lsum = lsum + da(lc)
      ENDDO

 1201 FORMAT('Error 1201: D',a,' is not specified or negative. ',      &
         'Please correct',/'the mfix.dat file.')


      lerr = 100.0*abs(lsum - alength)/alength
      IF(lerr > percent_error) THEN
         WRITE(err_msg,1202) axis, axis, axis, alength, axis, lsum, &
            lerr, percent_error
         CALL flush_err_msg(footer=.false.)

         DO lc = 1, na
            WRITE(err_msg,"(4x,A,' = ',A)") trim(ivar('D'//axis,lc)),   &
               trim(ival(da(lc)))
            CALL flush_err_msg(header=.false., footer=.false.)
         ENDDO
         WRITE(err_msg,"('Please correct the mfix.dat file')")
         CALL flush_err_msg(header=.false., abort=.true.)
      ENDIF

 1202 FORMAT('Error 1202: ',a1,'LENGTH and sum(D',a1,') are not ',     &
         'consistent.',/3x,a1,'LENGTH = ',g12.5,3x,'sum(D',a1,') = ',  &
         g12.5,/3x,'ERROR   = ',g12.5,3x,'ERR TOL = ',g12.5,/'  ')

      DO lc = na + 1, dimen
         IF(shift .AND. da(lc)/=undefined) THEN
            WRITE(err_msg, 1205) axis, axis_index
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

 1205 FORMAT('Error 1205: Too many D',a1,' values specified. Only ',a1,&
         'MAX permitted.',/'Please correct the mfix.dat file.')


      CALL finl_err_msg

      RETURN


 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/      &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_axis