report_stats_pic.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: REPORT_STATS_PIC                                        !
!                                                                      !
!  Purpose: Output stats about PIC simulation.                         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE report_stats_pic

! Global Variables:
!---------------------------------------------------------------------//
! Flag to report minimum EP_G
      use mfix_pic, only: pic_report_min_epg
! Gas phase volume fraction
      use fldvar, only: ep_g
! Location of cell faces (East, North, Top)
      use discretelement, only: xe, yn, zt

      use param1, only: large_number
      use mpi_utility
      USE error_manager
      USE functions

      IMPLICIT NONE

! Local Variables:
!----------------------------------------------------------------------!
! Loop counters
      INTEGER I, J, K, IJK, IPROC

      INTEGER :: EPg_MIN_loc(0:numpes-1, 4), EPg_MIN_loc2(1)
      DOUBLE PRECISION :: EPg_MIN(0:numpes-1), EPg_min2

!-----------------------------------------------

      CALL init_err_msg("REPORT_STATS_PIC")


      IF(pic_report_min_epg) THEN

         epg_min(:) = 0
         epg_min(mype) = large_number

         epg_min_loc(:,:) = 0
         epg_min_loc(mype,:) = -1

         DO k = kstart1, kend1
            DO j = jstart1, jend1
               DO i = istart1, iend1
                  ijk = funijk(i,j,k)

                  IF(ep_g(ijk) < epg_min(mype)) THEN
                     epg_min_loc(mype,1) = i
                     epg_min_loc(mype,2) = j
                     epg_min_loc(mype,3) = k
                     epg_min_loc(mype,4) = ijk
                     epg_min(mype) = ep_g(ijk)
                  ENDIF
               ENDDO
            ENDDO
         ENDDO

         call global_all_sum(epg_min)
         CALL global_all_sum(epg_min_loc)

         epg_min2     = minval(epg_min(0:numpes-1))
         epg_min_loc2 = minloc(epg_min(0:numpes-1)) - 1
         !-1, since minloc goes from 1:size of the array.
         !If not corrected by -1, then the proc id will be off by 1

         iproc = epg_min_loc2(1)

         i     = epg_min_loc(iproc, 1)
         j     = epg_min_loc(iproc, 2)
         k     = epg_min_loc(iproc, 3)
         ijk   = epg_min_loc(iproc, 4)
         WRITE(err_msg,1014) epg_min2, iproc, i, j, k, ijk, &
            xe(i) - 0.5*dx(i), yn(j)-0.5*dy(j), zt(k) - 0.5*dz(k)

 1014       FORMAT( /, &
            &      5x,'EPGMIN                    = ', 2x,g17.8,/ &
            &      5x,'EPGMIN PROC RANK          = ', 2x, i10, / &
            &      5x,'EPGMIN (I, J, K, IJK)     = ', 3(2x,i5),2x,i10,/ &
            &      5x,'XMID, YMID, ZMID FOR CELL = ', 3(2x,g17.8))

            call flush_err_msg(header = .false., footer = .false.)

      ENDIF

      CALL finl_err_msg

      RETURN
      END SUBROUTINE report_stats_pic