energy_mod.f

Go to the documentation of this file.

! -*- f90 -*-
MODULE energy


!   Gas-phase heat of reaction
  DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::  hor_g

!   Solids-phase heat of reaction
  DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  hor_s

!   Gas-solids heat transfer coefficient
  DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  gama_gs

!   Gas-phase radiation coefficient
  DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::  gama_rg

!   Solids-phase radiation coefficient
  DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  gama_rs

!   Gas-phase radiation temperature
  DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::  t_rg

!   Solids-phase radiation temperature
  DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  t_rs

CONTAINS

  !vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
  !  Source terms for the energy equations.  The source term is linearized as
  !  S = S_c - S_p * T,  where S_c and S_p must be positive.
  !
  !  By default the source terms have been coded for radiation sources.

  !
  !  S_p for gas phase at i, j, k
  DOUBLE PRECISION FUNCTION s_rpg(IJK)
    USE fldvar, only: t_g
    IMPLICIT NONE
    INTEGER IJK
    s_rpg = 4.d0 * gama_rg(ijk) *  t_g(ijk)**3
  END FUNCTION s_rpg

  !  S_c for gas phase at i, j, k
  DOUBLE PRECISION FUNCTION s_rcg(IJK)
    USE fldvar, only: t_g
    IMPLICIT NONE
    INTEGER IJK
    s_rcg = gama_rg(ijk) * ( t_rg(ijk)**4 + 3.d0 * t_g(ijk)**4 )
  END FUNCTION s_rcg

  !  S_p for solids phase at i, j, k
  DOUBLE PRECISION FUNCTION s_rps(IJK, M)
    USE fldvar, only: t_s
    IMPLICIT NONE
    INTEGER IJK, M
    s_rps = 4.d0 * gama_rs(ijk, m) *  t_s(ijk, m)**3
  END FUNCTION s_rps

  !  S_c for solids phase at i, j, k
  DOUBLE PRECISION FUNCTION s_rcs(IJK, M)
    USE fldvar, only: t_s
    IMPLICIT NONE
    INTEGER IJK, M
    s_rcs = gama_rs(ijk, m) * ( t_rs(ijk, m)**4 &
         + 3.d0 * t_s(ijk, m)**4 )
  END FUNCTION s_rcs

END MODULE energy