cfrelvel.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
!
!  Subroutine: CFRELVEL
!  Purpose: Calculate the normal and tangential components of the
!           relative velocity between contacting particles
!
!  Author: Jay Boyalakuntla                           Date: 12-Jun-04
!  Reviewer: Rahul Garg                               Date: 01-Aug-07
!
!  Comments: Relative (translational) velocity required for eqn 6
!  from the following paper:
!    Tsuji Y., Kawaguchi T., and Tanak T., "Lagrangian numerical
!    simulation of plug glow of cohesionless particles in a
!    horizontal pipe", Powder technology, 71, 239-250, 1992
!
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

      SUBROUTINE cfrelvel(L, II, VRN, VSLIP, NORM, DIST_LI)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE discretelement, only: des_vel_new, des_radius, omega_new, des_crossprdct
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! indices of particle-particle contact pair
      INTEGER, INTENT(IN) :: L, II
! distance between particle centers
      DOUBLE PRECISION, INTENT(IN) :: DIST_LI
! unit normal vector along the line of contact pointing from
! particle L to particle II
      DOUBLE PRECISION, INTENT(IN) :: NORM(3)
! slip velocity at point of contact
      DOUBLE PRECISION, INTENT(OUT) :: VSLIP(3)
! normal component of relative contact velocity (scalar)
      DOUBLE PRECISION, INTENT(OUT) :: VRN
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! translational relative velocity
      DOUBLE PRECISION :: VRELTRANS(3)
! rotational velocity at point of contact
      DOUBLE PRECISION :: V_ROT(3), OMEGA_SUM(3)
! distance from the contact point to the particle centers
      DOUBLE PRECISION :: DIST_CL, DIST_CI
!-----------------------------------------------

! translational relative velocity
         vreltrans(:) = (des_vel_new(l,:) - des_vel_new(ii,:))

! calculate the distance from the particle center to the contact point,
! which is taken as the radical line
! dist_ci+dist_cl=dist_li; dist_ci^2+a^2=ri^2;  dist_cl^2+a^2=rl^2
         dist_cl = (dist_li**2 + des_radius(l)**2 - des_radius(ii)**2)/&
            (2.d0*dist_li)
         dist_ci = dist_li - dist_cl

         omega_sum(:) = omega_new(l,:)*dist_cl + &
              omega_new(ii,:)*dist_ci

! calculate the rotational relative velocity
      v_rot = des_crossprdct(omega_sum, norm)

! total relative velocity
      vreltrans(:) =  vreltrans(:) + v_rot(:)

! normal component of relative velocity (scalar)
      vrn = dot_product(vreltrans,norm)

! slip velocity of the contact point
! Equation (8) in Tsuji et al. 1992
      vslip(:) =  vreltrans(:) - vrn*norm(:)

      RETURN
      END SUBROUTINE cfrelvel