cfslide.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
!
!  Subroutine: CFSLIDE(V_TANG, PARTICLE_SLIDE, MU)
!  Purpose:  Check for Coulombs friction law - calculate sliding
!            friction
!
!  Author: Jay Boyalakuntla                           Date: 12-Jun-04
!  Reviewer:                                          Date:
!
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

      SUBROUTINE cfslide(V_TANG, PARTICLE_SLIDE, MU, FT_tmp, FN_tmp)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE discretelement, only: debug_des
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! tangent to the plane of contact
      DOUBLE PRECISION, INTENT(IN) :: V_TANG(3)
! logic set to T when a sliding contact occurs
      LOGICAL, INTENT(OUT) :: PARTICLE_SLIDE
! Coefficient of friction
      DOUBLE PRECISION, INTENT(IN) :: MU
! normal force
      DOUBLE PRECISION, DIMENSION(3), INTENT(IN) :: FN_tmp
! tangential force
      DOUBLE PRECISION, DIMENSION(3), INTENT(INOUT) :: FT_tmp
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! squared magnitude of tangential and normal forces
      DOUBLE PRECISION FTMD, FNMD
!-----------------------------------------------

      ftmd = dot_product(ft_tmp(:),ft_tmp(:))
      fnmd = dot_product(fn_tmp(:),fn_tmp(:))

      IF (ftmd.GT.(mu*mu*fnmd)) THEN
! tangential force based on sliding friction
         particle_slide = .true.
         IF(all(v_tang.EQ.0)) THEN
            ft_tmp(:) =  mu * ft_tmp(:) * sqrt(fnmd/ftmd)
         ELSE
            ft_tmp(:) = -mu * v_tang(:) * sqrt(fnmd/dot_product(v_tang,v_tang))
         ENDIF

         IF(debug_des) THEN
            WRITE(*,'(7X,A)') &
                 'FROM CFSLIDE.F ---------->'
            WRITE(*,'(9X,A)') 'PARTICLE_SLIDE = T'
            WRITE(*,'(9X,A,2(ES15.7,1X))')&
                 'FTMD, mu*FNMD = ', ftmd, mu*fnmd
            WRITE(*,'(7X,A)') '<----------END CFSLIDE.F'
         ENDIF

      ENDIF

      RETURN
      END SUBROUTINE cfslide