set_geometry_des.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: SET_GEOMETRY_DES                                        !
!  Author:   R.Garg                                   Date: 19-Mar-14  !
!                                                                      !
!  Purpose: Allocate des arrays that are based on Eulerian grid.       !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE set_geometry_des


! Global Variables:
!---------------------------------------------------------------------//
! Arrays for DEM simulations delineating cell edges.
      use discretelement, only: xe, yn, zt, dimn
! Domain bounds (max/min).
      use discretelement, only: ex2, ty2, nz2, wx1, by1, sz1
! Fluid grid cell dimensions and mesh size
      USE geometry, only: dx, imin2, imax2
      USE geometry, only: dy, jmin2, jmax2
      USE geometry, only: dz, kmin2, kmax2
! Number of particles in the I/J/K direction
      use param, only: dimension_i, dimension_j, dimension_k

! Global Parameters:
!---------------------------------------------------------------------//
      use param1, only: zero

! Module proceedures.
!---------------------------------------------------------------------//
      use mpi_utility
      use error_manager

      IMPLICIT NONE

! Local Variables:
!---------------------------------------------------------------------//
! Generic loop indices
      INTEGER :: I, J, K
! Error Flag
      INTEGER :: IER
!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("SET_GEOMETRY_DES")

      Allocate( xe(0:dimension_i), stat=ier )
      Allocate( yn(0:dimension_j), stat=ier )
      Allocate( zt(0:dimension_k), stat=ier )

! Collect the error flags from all ranks. If all allocaitons were
! successfull, do nothing. Otherwise, flag the error and abort.
      CALL global_all_sum(ier)


! Set boundary edges.
! In some instances wx1,ex2, etc have been used and in others
! xlength,zero, etc are used. the code should be modified for
! consistency throughout
      ex2 = xlength;    wx1 = zero  ! East/West
      ty2 = ylength;    by1 = zero  ! North/South
      nz2 = zlength;    sz1 = zero  ! Top/Bottom

! Initialize arrays.
      xe(:) = zero
      yn(:) = zero
      zt(:) = zero

! Each loop starts at 2 and goes to max+2 (i.e., imin1=2, imax2=imax+2)
! However, the indices range to include ghost cells (0-imax2) to avoid
! multiple if statements in particles_in_cell
      xe(imin2-1) = zero-dx(imin2)
      DO i = imin2, imax2
         xe(i) = xe(i-1) + dx(i)
      ENDDO

      yn(jmin2-1) = zero-dy(jmin2)
      DO j  = jmin2, jmax2
         yn(j) = yn(j-1) + dy(j)
      ENDDO

      IF(dimn.EQ.3) THEN
         zt(kmin2-1) = zero-dz(kmin2)
         DO k = kmin2, kmax2
            zt(k) = zt(k-1) + dz(k)
         ENDDO
      ENDIF

      CALL finl_err_msg

      RETURN
      END SUBROUTINE set_geometry_des