calc_drag_des.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CALC_DRAG_DES                                           !
!                                                                      !
!  Purpose: This subroutine is called from DES routines. It calls      !
!  functions that calcultate the drag force acting on particles. No    !
!  field variables are updated.                                        !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_drag_des

! Modules
!---------------------------------------------------------------------//
      use discretelement, only: des_continuum_coupled
      use discretelement, only: des_continuum_hybrid
      use discretelement, only: des_explicitly_coupled
      use discretelement, only: drag_fc, fc, max_pip
      use functions, only: is_normal
      use particle_filter, only: des_interp_scheme_enum
      use particle_filter, only: des_interp_garg
      IMPLICIT NONE

! Local variables
!---------------------------------------------------------------------//
      INTEGER :: II
!......................................................................!

! Apply the drag force calculated by the gas phase.
      IF(des_explicitly_coupled) THEN

         IF(des_continuum_coupled) THEN
!$omp parallel do default(none) private(II) &
!$omp shared(FC, DRAG_FC, MAX_PIP)
            DO ii = 1, max_pip
               IF(is_normal(ii)) &
                  fc(ii,:) = fc(ii,:) + drag_fc(ii,:)
            ENDDO
!$omp end parallel do
         ENDIF


      ELSE

! Calculate gas-solids drag force on particle
         IF(des_continuum_coupled) THEN
            SELECT CASE(des_interp_scheme_enum)
            CASE(des_interp_garg) ; CALL drag_gs_des0
            CASE DEFAULT; CALL drag_gs_des1
            END SELECT
         ENDIF

! Calculate solids-solids drag force on particle.
         IF(des_continuum_hybrid) THEN
            SELECT CASE(des_interp_scheme_enum)
            CASE DEFAULT; CALL drag_ss_dem_noninterp
            END SELECT
         ENDIF
      ENDIF

      RETURN
      END SUBROUTINE calc_drag_des