set_max2.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: SET_MAX2                                               C
!  Purpose: calculate IMAX1,IMAX2,JMAX1,JMAX2,KMAX1,KMAX2,IJMAX2       C
!                     IJKMAX2                                          C
!                                                                      C
!  Author: P. Nicoletti                               Date: 04-DEC-91  C
!  Reviewer: M.SYAMLAL, W.ROGERS, P.NICOLETTI         Date: 24-JAN-92  C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced: IMAX, JMAX, KMAX, NO_I, NO_J, NO_K            C
!  Variables modified: IMAX1, IMAX2, JMAX1, JMAX2, KMAX1, KMAX2        C
!                      IJMAX2, IJKMAX2, IMIN1, JMIN1, KMIN1            C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE set_max2

! X-Axix partition specifications.
      USE compar, only: nodesi
      USE geometry, only: imax,  no_i,  do_i
      USE geometry, only: imin1, imin2, imin3, imin4
      USE geometry, only: imax1, imax2, imax3, imax4

! Y-Axix partition specifications.
      USE compar, only: nodesj
      USE geometry, only: jmax,  no_j,  do_j
      USE geometry, only: jmin1, jmin2, jmin3, jmin4
      USE geometry, only: jmax1, jmax2, jmax3, jmax4

! Z-Axix partition specifications.
      USE compar, only: nodesk
      USE geometry, only: kmax,  no_k,  do_k
      USE geometry, only: kmin1, kmin2, kmin3, kmin4
      USE geometry, only: kmax1, kmax2, kmax3, kmax4

! Calculated array sizes.
      USE geometry, only: ijmax2
      USE geometry, only: ijkmax1, ijkmin1
      USE geometry, only: ijkmax2, ijkmax3, ijkmax4

      IMPLICIT NONE


! Initialize I's
      imin1=1;  imin2=1;  imin3=1;  imin4=1
      imax1=1;  imax2=1;  imax3=1;  imax4=1

      do_i=.NOT.no_i

! Set the domain specific values.
      IF(do_i) THEN
         imin1 = 2
         imax1 = imax + 1
         imax2 = imax + 2
         imin2 = 1
         IF(nodesi.NE.1) THEN
            imin3 = 0
            imax3 = imax + 3
            imin4 = -1
            imax4 = imax + 4
         ELSE
            imin3 = imin2
            imax3 = imax2
            imin4 = imin3
            imax4 = imax3
         ENDIF
      ENDIF


! Initialize J's
      jmin1=1;  jmin2=1;  jmin3=1;  jmin4=1
      jmax1=1;  jmax2=1;  jmax3=1;  jmax4=1

      do_j=.NOT.no_j

! Set the domain specific values.
      IF(do_j) THEN
         jmin1 = 2
         jmax1 = jmax + 1
         jmax2 = jmax + 2
         jmin2 = 1
         IF(nodesj.NE.1) THEN
            jmin3 = 0
            jmax3 = jmax + 3
            jmin4 = -1
            jmax4 = jmax + 4
         ELSE
            jmin3 = jmin2
            jmax3 = jmax2
            jmin4 = jmin3
            jmax4 = jmax3
         ENDIF
      ENDIF


! Initialize J's
      kmin1=1;  kmin2=1;  kmin3=1;  kmin4=1
      kmax1=1;  kmax2=1;  kmax3=1;  kmax4=1

      do_k=.NOT.no_k

! Set the domain specific values.
      IF (do_k) THEN
         kmin1 = 2
         kmax1 = kmax + 1
         kmax2 = kmax + 2
         kmin2 = 1
         IF(nodesk.NE.1) THEN
            kmin3 = 0
            kmax3 = kmax + 3
            kmin4 = -1
            kmax4 = kmax + 4
         ELSE
            kmin3 = kmin2
            kmax3 = kmax2
            kmin4 = kmin3
            kmax4 = kmax3
         ENDIF
      ENDIF

! Number of cells in I/J plane.
      ijmax2 = imax2*jmax2
! Totoal number of possible fluid cells.
      ijkmax2 = imax2*jmax2*kmax2

      IF (do_k) THEN
         ijkmin1 = ijmax2 + 1
         ijkmax1 = ijkmax2 - ijmax2
      ELSE
         ijkmin1 = imax2 + 1
         ijkmax1 = ijkmax2 - imax2
      ENDIF

! Max cell count with one layer of ghost cells.
      ijkmax3 = (imax3-imin3+1)*(jmax3-jmin3+1)*(kmax3-kmin3+1)
! Max cell count with two layers of ghost cells.
      ijkmax4 = (imax4-imin4+1)*(jmax4-jmin4+1)*(kmax4-kmin4+1)

      RETURN
      END SUBROUTINE set_max2