stiff_chem_stats_mod.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: STIFF_CHEM_DEBUG                                       !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Author: J.Musser                                   Date:            !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      MODULE stiff_chem_stats

      PRIVATE

! Variable Access:
!---------------------------------------------------------------------//
      PUBLIC :: failedcount


! Subroutine Access:
!---------------------------------------------------------------------//
      PUBLIC :: allocate_stiff_chem_stats

      PUBLIC :: init_stiff_chem_stats
      PUBLIC :: update_stiff_chem_stats
      PUBLIC :: write_stiff_chem_stats


! Routine used to compare to values.
      LOGICAL, external :: compare


! Static variables/parameters.
!---------------------------------------------------------------------//
! Frequency to report the number of steps distribution.
      INTEGER, parameter :: reportnst_freq = 10

! Variables updated once each call to the stiff solver.
!---------------------------------------------------------------------//
! Frequency to report the number of steps distribution.
      INTEGER :: reportnst

      INTEGER :: failedcount_total
      INTEGER :: countincpt_total


! Variables updated every IJK loop cycle.
!---------------------------------------------------------------------//

! The minimum number of integrations needed (over all IJK)
      INTEGER, allocatable :: minnst(:)                     ! local
      INTEGER, allocatable :: minnst_all(:)                 ! global

! The maximum number of integrations needed (over all IJK)
      INTEGER, allocatable :: maxnst(:)                     ! local
      INTEGER, allocatable :: maxnst_all(:)                 ! global

! An array that stores the distrubtion of the number of steps needed
! to integrate ODES.
      INTEGER, allocatable :: countnst(:)                   ! local
      INTEGER, allocatable :: countnst_all(:)               ! global

! Number of cells that only have homogeneous chemical reactions.
      INTEGER, allocatable :: homogns(:)                    ! local
      INTEGER, allocatable :: homogns_all(:)                ! global

! Number of cells that only have homogeneous and/or heterogeneous
! chemical reactions.
      INTEGER, allocatable :: hetrgns(:)                    ! local
      INTEGER, allocatable :: hetrgns_all(:)                ! global

! Number of cells that failed to successfully integration ODEs.
      INTEGER, allocatable :: failedcount(:)                ! local
      INTEGER, allocatable :: failedcount_all(:)            ! global

! Maximum number of attempts to integrate.
      INTEGER, allocatable :: maxattempts(:)                ! local
      INTEGER, allocatable :: maxattempts_all(:)            ! global

! Maximum number of incomplete integrations.
      INTEGER, allocatable :: countincpt(:)                 ! local
      INTEGER, allocatable :: countincpt_all(:)             ! global

      DOUBLE PRECISION :: ode_starttime

      contains


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: ALLOCATE_STIFF_CHEM_STATS                              !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Author: J.Musser                                   Date:            !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE allocate_stiff_chem_stats

      use compar, only: mype
      use compar, only: numpes
      use output, only: full_log

      implicit none

      reportnst = 1
      failedcount_total = 0
      countincpt_total = 0

! Number of cells that failed to successfully integration ODEs.
      allocate( failedcount(0:numpes-1) ); failedcount = 0    ! local
      allocate( failedcount_all(0:numpes-1) )                 ! global

      if(.NOT.full_log) return

! The minimum number of integrations needed (over all IJK)
      allocate( minnst(0:numpes-1)); minnst = 0               ! local
      allocate( minnst_all(0:numpes-1) )                      ! global
      minnst(mype) = 5000

! The maximum number of integrations needed (over all IJK)
      allocate( maxnst(0:numpes-1) ); maxnst = 0              ! local
      allocate( maxnst_all(0:numpes-1) )                      ! global

! An array that stores the distrubtion of the number of steps needed
! to integrate ODES.
      allocate( countnst(5) ); IF(reportnst==1) countnst = 0  ! local
      allocate( countnst_all(5) )                             ! global

! Number of cells that only have homogeneous chemical reactions.
      allocate( homogns(0:numpes-1) ); homogns = 0            ! local
      allocate( homogns_all(0:numpes-1) )                     ! global

! Number of cells that only have homogeneous and/or heterogeneous
! chemical reactions.
      allocate( hetrgns(0:numpes-1) ); hetrgns = 0;           ! local
      allocate( hetrgns_all(0:numpes-1) )                     ! global

! Maximum number of attempts to integrate.
      allocate( maxattempts(0:numpes-1) ); maxattempts = 0    ! local
      allocate( maxattempts_all(0:numpes-1) )                 ! global

! Number of cells that fail to completely integrate the time step
! given the maximum number of steps.
      allocate( countincpt(0:numpes-1) ); countincpt = 0      ! local
      allocate( countincpt_all(0:numpes-1) )                  ! global


      RETURN
      END SUBROUTINE allocate_stiff_chem_stats


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: INIT_ODE_STATS0                                        !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Author: J.Musser                                   Date:            !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE init_stiff_chem_stats

      use compar, only: mype
      use compar, only: pe_io
      use output, only: full_log

      implicit none

      if(.NOT.full_log) return

      CALL cpu_time(ode_starttime)

      hetrgns = 0
      homogns = 0
      failedcount = 0
      countincpt = 0

      if(mype == pe_io) &
         write(*,"(/3x,'Integrating stiff chemistry...')",advance="NO")

      RETURN
      END SUBROUTINE init_stiff_chem_stats


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: UPDATE_STIFF_CHEM_STATS                                !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Author: J.Musser                                   Date:            !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE update_stiff_chem_stats(lNEQ, lNEQ_DIMN, lNST, &
         lode_dimn, latps, lincpt)

      use compar, only: mype

      implicit none

! The number of steps needed to integrate.
      INTEGER, intent(in) :: lNEQ_DIMN

! (1) :: Number of ODEs
! (2) :: Fluid cell index (IJK) passed into ODEPACK
      INTEGER, dimension(lNEQ_DIMN), intent(in) :: lNEQ
! The number of steps needed to integrate.
      INTEGER, intent(in) :: lNST
! The number ODEs (maximum).
      INTEGER, intent(in) :: lODE_DIMN

! The number of attempts.
      INTEGER, intent(in) :: lAtps

! Flag that the integration is incomplete
      LOGICAL, intent(in) :: lIncpt


      IF(lneq(1) == lode_dimn) THEN
         hetrgns(mype) = hetrgns(mype) + 1
      ELSE
         homogns(mype) = homogns(mype) + 1
      ENDIF

      maxattempts(mype) = max(latps, maxattempts(mype))

      minnst(mype) = min(minnst(mype), lnst)
      maxnst(mype) = max(maxnst(mype), lnst)

      IF (lnst <           10) THEN
         countnst(1) = countnst(1) + 1
      ELSE IF (lnst <     100) THEN
         countnst(2) = countnst(2) + 1
      ELSE IF (lnst <    1000) THEN
         countnst(3) = countnst(3) + 1
      ELSE IF (lnst <   10000) THEN
         countnst(4) = countnst(4) + 1
      ELSE
         countnst(5) = countnst(5) + 1
      ENDIF

      IF(lincpt) countincpt(mype) = countincpt(mype) + 1

      RETURN
      END SUBROUTINE update_stiff_chem_stats


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  Module name: WRITE_ODE_STATS                                        !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Author: J.Musser                                   Date:            !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE write_stiff_chem_stats

      use compar, only: mype
      use compar, only: pe_io
      use output, only: full_log

      use mpi_utility

      implicit none

! Message buffer.
      CHARACTER(LEN=64) :: lMsg0, lMsg1

      DOUBLE PRECISION :: lODE_EndTime, lODE_RunTime

      IF(.NOT.full_log) return


! Update screen message.
      IF(mype == pe_io) WRITE(*,"(2x,'DONE.',/)")


      CALL cpu_time(lode_endtime)
      lode_runtime = lode_endtime - ode_starttime


! Collect stats on min/max number of steps.
      minnst_all = 0; CALL global_sum(minnst, minnst_all)
      maxnst_all = 0; CALL global_sum(maxnst, maxnst_all)

! Collect stats on the number of cells with pure homogeneous reactions.
      homogns_all = 0;
      CALL global_sum(homogns, homogns_all)

! Collect stats on the number of cells with heterogeneous and
! homogeneous reactions.
      hetrgns_all = 0
      CALL global_sum(hetrgns, hetrgns_all)

! Collect stats on the maximum number of integration attempts.
      maxattempts_all = 0
      CALL global_sum(maxattempts, maxattempts_all)

! Collect stats on the maximum number of incomplete integrations.
      countincpt_all = 0
      CALL global_sum(countincpt, countincpt_all)

! Collect stats on the number of failed integrations.
      failedcount_all = 0
      CALL global_sum(failedcount, failedcount_all)


! Display stiff solver summary.
      IF(mype == pe_io) THEN

! Report Min/Max steps:
         lmsg0=''; write(lmsg0,*) minval(minnst_all)
         lmsg1=''; write(lmsg1,*) maxval(maxnst_all)
         write(*,1000)  trim(adjustl(lmsg0)), trim(adjustl(lmsg1))

! Report Homogeneous/Heterogeneous reactions:
         lmsg0=''; write(lmsg0,*) sum(homogns_all)
         lmsg1=''; write(lmsg1,*) sum(hetrgns_all)
         write(*,1001) trim(adjustl(lmsg0)), trim(adjustl(lmsg1))

! Report Max attempts:
         lmsg0=''; write(lmsg0,*) maxval(maxattempts_all)
         write(*,1004)  trim(adjustl(lmsg0))

! Report incomplete integrations:
         countincpt_total = countincpt_total + sum(countincpt_all)

         IF(countincpt_total > 0) THEN
            lmsg0=''; write(lmsg0,*) sum(countincpt_all)
            lmsg1=''; write(lmsg1,*) countincpt_total
            write(*,1002) 'incomplete', trim(adjustl(lmsg0)), trim(adjustl(lmsg1))
         ENDIF

! Report failed integrations:
         failedcount_total = failedcount_total + sum(failedcount_all)

         IF(failedcount_total > 0) THEN
            lmsg0=''; write(lmsg0,*) sum(failedcount_all)
            lmsg1=''; write(lmsg1,*) failedcount_total
            write(*,1002) 'failed', trim(adjustl(lmsg0)), trim(adjustl(lmsg1))
         ENDIF

         IF(lode_runtime > 3.6d3) THEN
            lmsg0=''; write(lmsg0,"(f8.4)") lode_runtime/3.6d3
            lmsg1='hrs'
         ELSEIF(lode_runtime > 6.0d1) THEN
            lmsg0=''; write(lmsg0,"(f8.4)") lode_runtime/6.0d1
            lmsg1='min'
         ELSE
            lmsg0=''; write(lmsg0,"(f8.4)") lode_runtime
            lmsg1='sec'
         ENDIF
         write(*,1003) trim(adjustl(lmsg0)), trim(adjustl(lmsg1))

      ENDIF


      if(reportnst == reportnst_freq) then
! Collect the number of steps distributions.
         countnst_all = 0;
         CALL global_sum(countnst, countnst_all)

         countnst_all = int(countnst_all/reportnst_freq)

         if(mype == pe_io) then
            write(*,"(/5x,'Average Integration Distribution:')")
            write(*,"(7x,'NST < 10^1: ', I6)")countnst_all(1)
            write(*,"(7x,'NST < 10^2: ', I6)")countnst_all(2)
            write(*,"(7x,'NST < 10^3: ', I6)")countnst_all(3)
            write(*,"(7x,'NST < 10^4: ', I6)")countnst_all(4)
            write(*,"(7x,'NST > 10^5: ', I6)")countnst_all(5)
         endif
! Reset the reporting counter.
         reportnst = 1
! Clear out old data.
         countnst = 0
         countnst_all = 0
      else
! Increment the reporting counter.
         reportnst = reportnst + 1
      endif

      if(mype == pe_io)write(*,"(/' ')")

      RETURN

 1000 Format(5x,'Minimum/Maximum number of steps over all cells: ',a,'/',a)
 1001 Format(5x,'Number of cells with Homogeneous/Heterogeneous reactions: ',a,'/',a)
 1002 Format(5x,'Number of Current/Cumulative ',a,' integrations: ',a,'/',a)
 1003 Format(5x,'CPU Time Used: ',a,' ',a)
 1004 Format(5x,'Maximum number of integration attempts: ',a)

      END SUBROUTINE write_stiff_chem_stats

      END MODULE stiff_chem_stats