check_ab_m.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: Check_Ab_m(A_m, b_m, M, src, IER)                      C                     C
!  Purpose: Check the entries of the sparse matrix coefficients and theC
!           source vector, if src is set true.                         C
!                                                                      C
!                                                                      C
!  Author: M. Syamlal                                 Date: 16-MAY-96  C
!  Reviewer:                                          Date:            C
!                                                                      C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE check_ab_m(A_M, B_M, M, SRC, IER)
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!
!  Include param.inc file to specify parameter values
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE compar
      USE exit, ONLY: mfix_exit
      USE functions
      USE geometry
      USE indices
      USE param
      USE param1
      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   D u m m y   A r g u m e n t s
!-----------------------------------------------
!
!                      Error index
      INTEGER          IER
!
!                      Phase index
      INTEGER          M
!
!                      Check source.  Check source term only for
!                      variables, such as temperatures and
!                      mass fractions, that are always positive.
      LOGICAL          SRC
!
!                      Error message
      CHARACTER(LEN=80) :: LINE(1)
!
!                      cell index
      INTEGER          IJK
!
!                      Septadiagonal matrix A_m
      DOUBLE PRECISION A_m(dimension_3, -3:3, 0:dimension_m)
!
!                      Source vector
      DOUBLE PRECISION b_m(dimension_3, 0:dimension_m)
!-----------------------------------------------

      ier = 0
      DO ijk = ijkstart3, ijkend3
         IF (.NOT.wall_at(ijk)) THEN
            IF (a_m(ijk,bottom,m) < zero) THEN
               IF (abs(a_m(ijk,bottom,m)) > small_number) THEN
                  WRITE (line(1), *) 'Error: Diagonal-b < 0. Phase = ', m, &
                     ' IJK = ', ijk
                  CALL write_error ('CHECK_Ab_m', line, 1)
                  GO TO 500
               ELSE
                  a_m(ijk,bottom,m) = zero
               ENDIF
            ENDIF
            IF (a_m(ijk,south,m) < zero) THEN
               IF (abs(a_m(ijk,south,m)) > small_number) THEN
                  WRITE (line(1), *) 'Error: Diagonal-s < 0. Phase = ', m, &
                     ' IJK = ', ijk
                  CALL write_error ('CHECK_Ab_m', line, 1)
                  GO TO 500
               ELSE
                  a_m(ijk,south,m) = zero
               ENDIF
            ENDIF
            IF (a_m(ijk,west,m) < zero) THEN
               IF (abs(a_m(ijk,west,m)) > small_number) THEN
                  WRITE (line(1), *) 'Error: Diagonal-w < 0. Phase = ', m, &
                     ' IJK = ', ijk
                  CALL write_error ('CHECK_Ab_m', line, 1)
                  GO TO 500
               ELSE
                  a_m(ijk,west,m) = zero
               ENDIF
            ENDIF
            IF (a_m(ijk,east,m) < zero) THEN
               IF (abs(a_m(ijk,east,m)) > small_number) THEN
                  WRITE (line(1), *) 'Error: Diagonal-e < 0. Phase = ', m, &
                     ' IJK = ', ijk
                  CALL write_error ('CHECK_Ab_m', line, 1)
                  GO TO 500
               ELSE
                  a_m(ijk,east,m) = zero
               ENDIF
            ENDIF
            IF (a_m(ijk,north,m) < zero) THEN
               IF (abs(a_m(ijk,north,m)) > small_number) THEN
                  WRITE (line(1), *) 'Error: Diagonal-n < 0. Phase = ', m, &
                     ' IJK = ', ijk
                  CALL write_error ('CHECK_Ab_m', line, 1)
                  GO TO 500
               ELSE
                  a_m(ijk,north,m) = zero
               ENDIF
            ENDIF
            IF (a_m(ijk,top,m) < zero) THEN
               IF (abs(a_m(ijk,top,m)) > small_number) THEN
                  WRITE (line(1), *) 'Error: Diagonal-t < 0. Phase = ', m, &
                     ' IJK = ', ijk
                  CALL write_error ('CHECK_Ab_m', line, 1)
                  GO TO 500
               ELSE
                  a_m(ijk,top,m) = zero
               ENDIF
            ENDIF
            IF (a_m(ijk,0,m) >= zero) THEN
               WRITE (line(1), *) 'Error: Main Diagonal >= 0. Phase = ', m, &
                  ' IJK = ', ijk
               CALL write_error ('CHECK_Ab_m', line, 1)
               GO TO 500
            ENDIF
            IF (src) THEN
               IF (b_m(ijk,m) > zero) THEN
                  IF (b_m(ijk,m) > small_number) THEN
                     WRITE (line(1), *) 'Error: Source term >0. Phase = ', m, &
                        ' IJK = ', ijk
                     CALL write_error ('CHECK_Ab_m', line, 1)
                     GO TO 500
                  ELSE
                     b_m(ijk,m) = zero
                  ENDIF
               ENDIF
            ENDIF
         ENDIF
      END DO
      RETURN
!
!     error condition
  500 CONTINUE
      ier = 1
      CALL write_ab_m (a_m, b_m, ijkmax2, m, ier)
      call mfix_exit(mype)
      END SUBROUTINE check_ab_m


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: Check_symmetry(A_m, M, IER)
!  Purpose: Check whether the A_m matrix is symmetric
!                                                                      C
!  Author: M. Syamlal                                 Date: 19-JUL-07  C
!  Reviewer:                                          Date:            C
!                                                                      C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE check_symmetry(A_M, M, IER)
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE geometry
      USE indices
      USE compar
      USE functions
      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   D u m m y   A r g u m e n t s
!-----------------------------------------------
!
!                      Error index
      INTEGER          IER
!
!                      Phase index
      INTEGER          M

!                      cell index
      INTEGER          IJK, ipjk, ijpk, ijkp, i, j, k
!
!                      Septadiagonal matrix A_m
      DOUBLE PRECISION A_m(dimension_3, -3:3, 0:dimension_m)
!-----------------------------------------------
      ier = 0
      DO ijk = ijkstart3, ijkend3
        !No need to check the matrix entries for cyclic
        ! cells as they are not used during the linear solve.
        if(.not. cyclic_at(ijk))then
          ipjk = ip_of(ijk)
          ijpk = jp_of(ijk)
          ijkp = kp_of(ijk)
          i = i_of(ijk)
          j = j_of(ijk)
          k = k_of(ijk)
          IF(a_m(ijk, east, m) .ne. a_m(ipjk, west, m))then
            print *, i,j,k, 'east-west asymmetry', a_m(ijk,east,m), a_m(ipjk,west,m)
            ier = ier + 1
          endif
          IF(a_m(ijk, north, m) .ne. a_m(ijpk, south, m))then
            print *, i,j,k, 'north-south asymmetry', a_m(ijk,north,m), a_m(ijpk,south,m)
            ier = ier + 1
          endif
          IF(a_m(ijk, top, m) .ne. a_m(ijkp, bottom, m))then
            print *, i,j,k, 'top-bottom asymmetry', a_m(ijk,top,m), a_m(ijkp,bottom,m)
            ier = ier + 1
          endif
        endif
      enddo
      if(ier > 0) print *, 'Asymmetry in ', ier, ' instances'
      RETURN
      END SUBROUTINE check_symmetry