calc_cell.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine name: CALC_CELL                                          C
!  Purpose: calculate the i, j or k cell index for the corresponding   C
!     x y or z reactor location. the index returned depends on which   C
!     half of the i, j or k cell that the x, y, or z position          C
!     intersects                                                       C
!                                                                      C
!  Author: P. Nicoletti                               Date: 02-DEC-91  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE calc_cell(RMIN, REACTOR_LOC, D_DIR, N_DIR, CELL_LOC)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param1, only : half
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! the starting value of the x, y or z axis for which the i, j or k cell
! index is to be found -- XMIN need not be zero, however, YMIN and ZMIN
! are assumed to be zero.
      DOUBLE PRECISION, INTENT(IN) :: RMIN
! the x, y or z location along the axis for which the cell index (i, j
! or k) is to be found
      DOUBLE PRECISION, INTENT(IN) :: REACTOR_LOC
! number of cells in the corresponding direction (IMAX, JMAX, or KMAX)
      INTEGER, INTENT(IN) :: N_DIR
! the cell lengths along the corresponding axis (DX, DY or DZ)
      DOUBLE PRECISION, INTENT(IN), DIMENSION(0:(N_DIR+3)) :: D_DIR
! the i, j, or k cell index that corresponds to the x, y or z
! reactor_location (calculated value)
      INTEGER, INTENT(INOUT) :: CELL_LOC
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! loop counter
      INTEGER :: LC
! start and end coordinate for cell
      DOUBLE PRECISION :: CELL_START, CELL_END
!-----------------------------------------------

      cell_loc = -1
      cell_start = rmin
      DO lc = 2, n_dir + 1
         cell_end = cell_start + d_dir(lc)
         IF (reactor_loc <= cell_start + half*d_dir(lc)) THEN
            cell_loc = lc - 1
            RETURN
         ELSEIF (reactor_loc <= cell_end + half*d_dir(lc+1)) THEN
            cell_loc = lc
            RETURN
         ENDIF
         cell_start = cell_end
      ENDDO
      RETURN
      END SUBROUTINE calc_cell


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine name: CALC_LOC                                           C
!  Purpose: calculate the x, y, or z position corresponding to the     C
!     given i, j or k cell index. this call returns the x, y or z      C
!     position corresponding to the east, north or top face of the     C
!     cell with the given i, j or k index.                             C
!                                                                      C
!  Author: P. Nicoletti                               Date: 02-DEC-91  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE calc_loc(RMIN, D_DIR, CELL_LOC, REACTOR_LOC)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! the starting value of the x, y or z axis for which the x, y or z
! position is to be found -- XMIN need not be zero, however, YMIN and
! ZMIN are assumed to be zero.
      DOUBLE PRECISION, INTENT(IN) :: RMIN
! the i, j, or k cell index that corresponds to the x, y or z
! reactor_location to be found
      INTEGER, INTENT(IN) :: CELL_LOC
! the cell lengths along the corresponding axis (DX, DY or DZ)
      DOUBLE PRECISION, INTENT(IN), DIMENSION(0:CELL_LOC) :: D_DIR
! the x, y or z location along the axis that corresponds to the i, j
! k cell index  (calculated value)
      DOUBLE PRECISION, INTENT(INOUT) :: REACTOR_LOC
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! loop counter
      INTEGER :: LC
!-----------------------------------------------

      reactor_loc = rmin
      lc = 2
      IF (cell_loc - 1 > 0) THEN
         reactor_loc = reactor_loc + sum(d_dir(2:cell_loc))
         lc = cell_loc + 1
      ENDIF
      RETURN
      END SUBROUTINE calc_loc


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CALC_CELL_INTERSECT                                     !
!  Author: J.Musser                                   Date: 23-APR-14  !
!                                                                      !
!  Purpose: Calculate the cell index that intersects LOC. Unlike the   !
!  base routine (CALC_CELL), this routine does not shift the index     !
!  based on which half of the cell the point intersects.               !
!                                                                      !
!  Comment: This is a brute force approach and should not be called    !
!  from within any critical routines/loops.                            !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_cell_intersect(RMIN, LOC, D_DIR, N_DIR, CELL)

      IMPLICIT NONE

! Passed Arguments:
!---------------------------------------------------------------------//
! Starting value of the axis (ZERO except for maybe XMIN)
      DOUBLE PRECISION, INTENT(in) :: RMIN
! Point to check for intersection.
      DOUBLE PRECISION, INTENT(in) :: LOC
! Number of cells in this direction (IMAX,JMAX,KMAX)
      INTEGER, INTENT(in) :: N_DIR
! Cell lengths (DX,DY,DZ)
      DOUBLE PRECISION, INTENT(IN) :: D_DIR(0:(n_dir+3))
! Cell indices corresponding to LOC
      INTEGER, INTENT(out) :: CELL

! Local Variables:
!---------------------------------------------------------------------//
! Loop counter
      INTEGER :: LC
! Start/End coordinates for cell
      DOUBLE PRECISION :: CELL_START, CELL_END
!......................................................................!

     cell = -1

      cell_start = rmin
      DO lc=2, n_dir+1
         cell_end = cell_start + d_dir(lc)
         IF(cell_start <= loc .AND. loc <= cell_end) THEN
            cell = lc
            RETURN
         ENDIF
         cell_start=cell_end
      ENDDO

      RETURN
      END SUBROUTINE calc_cell_intersect