mod_bc_k.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: MOD_BC_K (BC, I_w, J_s, K_b, K_t, PLANE)               !
!  Author: P. Nicoletti                               Date: 10-DEC-91  !
!                                                                      !
!  Purpose: modify the "K" values for the b.c. plane                   !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE mod_bc_k(BCV)

      use bc, only: bc_i_w, bc_i_e
      use bc, only: bc_j_s, bc_j_n
      use bc, only: bc_k_b, bc_k_t
      use bc, only: bc_plane

      USE geometry, only: icbc_flag

      USE compar
      USE mpi_utility

      use error_manager
      USE functions

      IMPLICIT NONE

! boundary condition index
      INTEGER, INTENT(in) :: BCV

! calculated cell indices in I,J,K directions
      INTEGER :: K_b, K_t
      INTEGER :: I_w, J_s

      INTEGER :: OWNER

      INTEGER :: I, J
      INTEGER :: IJK, IJKP

      INTEGER :: IER
      LOGICAL :: ERROR
      INTEGER :: K_FLUID, IJK_FLUID
      INTEGER :: K_WALL,  IJK_WALL


!-----------------------------------------------

      CALL init_err_msg("MOD_BC_K")

      k_b = bc_k_b(bcv)
      k_t = bc_k_t(bcv)

      i_w = bc_i_w(bcv)
      j_s = bc_j_s(bcv)


! Establish the OWNER of the BC
      owner = merge(mype, 0, is_on_mype_owns(i_w, j_s, k_b))
      CALL global_all_sum(owner)

      IF(mype == owner) THEN

         ijk  = funijk(i_w, j_s, k_b)
         ijkp = funijk(i_w, j_s, k_b+1)

         IF(wall_icbc_flag(ijk) .AND. icbc_flag(ijkp)(1:1)=='.')THEN
            k_b = k_b
            k_t = k_t
            bc_plane(bcv) = 'T'
         ELSEIF(wall_icbc_flag(ijkp) .AND. icbc_flag(ijk)(1:1)=='.')THEN
            k_b = k_b + 1
            k_t = k_t + 1
            bc_plane(bcv) = 'B'
         ELSE
            bc_plane(bcv) = '.'
         ENDIF
      ENDIF

! The owner distributes the new Iw/Ie coordinates to the other ranks.
      CALL bcast(k_b,owner)
      CALL bcast(k_t,owner)
      CALL bcast(bc_plane(bcv),owner)

! If there is an error, send IJK/IPJK to all ranks. Report and exit.
      IF(bc_plane(bcv) == '.') THEN
         CALL bcast(ijkp,owner)
         CALL bcast(ijk, owner)

         WRITE(err_msg, 1100) bcv, k_b, k_t, i_w, j_s,                 &
            ijk, icbc_flag(ijk),  ijkp, icbc_flag(ijkp)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1100 FORMAT('Error 1100: Cannot locate flow plane for boundary ',     &
         'condition ',i3,'.',2/3x,'K Bottom =  ',i6,' K Top    = ',i6,/&
         3x,'I West   =  ',i6,' J South  = ',i6,2/' The following ',   &
         'should conttain a wall cell and fluid cell:',/3x,'IJK  ',i9, &
         ' :: ',a3,/3x,'IJKP ',i9,' :: ',a3,2/' Maybe no IC was ',     &
         'specified for the fluid cell.')

! Store the new values in the global data array.
      bc_k_b(bcv) = k_b
      bc_k_t(bcv) = k_t

! Set up the I-indices for checking the entire BC region.
      k_wall = bc_k_b(bcv)
      k_fluid = merge(k_wall-1, k_wall+1, bc_plane(bcv)=='B')


      error = .false.
      DO j = bc_j_s(bcv), bc_j_n(bcv)
      DO i = bc_i_w(bcv), bc_i_e(bcv)

! Only check cells that you own and contain fluid.
         IF(.NOT.is_on_mype_plus2layers(i,j,k_fluid)) cycle
         IF(.NOT.is_on_mype_plus2layers(i,j,k_wall )) cycle
         IF(dead_cell_at(i,j,k_fluid)) cycle
         IF(dead_cell_at(i,j,k_wall )) cycle

         ijk_wall = funijk(i,j,k_wall)
         ijk_fluid = funijk(i,j,k_fluid)

         IF(.NOT.(wall_icbc_flag(ijk_wall) .AND.                       &
            icbc_flag(ijk_fluid)(1:1)=='.')) error = .true.

      ENDDO
      ENDDO

! Sync up the error flag across all processes.
      CALL global_all_or(error)
! If an error is detected, have each rank open a log file and write
! it's own message. Otherwise, we need to send all the data back to
! PE_IO and that's too much work!
      IF(error) THEN

         CALL open_pe_log(ier)

         WRITE(err_msg, 1200) bcv
         CALL flush_err_msg(footer=.false.)

 1200 FORMAT('Error 1200: Illegal geometry for boundary condition:',i3)

         DO j = bc_j_s(bcv), bc_j_n(bcv)
         DO i = bc_i_w(bcv), bc_i_e(bcv)

! Only check cells that you own and contain fluid.
            IF(.NOT.is_on_mype_plus2layers(i,j,k_fluid)) cycle
            IF(.NOT.is_on_mype_plus2layers(i,j,k_wall )) cycle
            IF(dead_cell_at(i,j,k_fluid)) cycle
            IF(dead_cell_at(i,j,k_wall )) cycle

            ijk_wall = funijk(i,j,k_wall)
            ijk_fluid = funijk(i,j,k_fluid)

            IF(.NOT.(wall_icbc_flag(ijk_wall) .AND.                    &
               icbc_flag(ijk_fluid)(1:1)=='.')) THEN

               WRITE(err_msg, 1201) &
                  i, j, k_wall,  ijk_wall,  icbc_flag(ijk_wall),       &
                  i, j, k_fluid, ijk_fluid, icbc_flag(ijk_fluid)
               CALL flush_err_msg(header=.false., footer=.false.)
            ENDIF

 1201 FORMAT(' ',/14x,'I',7x,'J',7x,'K',7x,'IJK',4x,'FLAG',/3x,        &
         'WALL ',3(2x,i6),2x,i9,3x,a,/3x,'FLUID',3(2x,i6),2x,i9,3x,a)

         ENDDO
         ENDDO

         WRITE(err_msg,"('Please correct the mfix.dat file.')")
         CALL flush_err_msg(header=.false., abort=.true.)

      ENDIF

      CALL finl_err_msg

      RETURN
      END SUBROUTINE mod_bc_k