remove_comment.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine Name: REMOVE_COMMENT (LINE, LSTART, MAXCOL)              !
!  Author: P.Nicoletti                                Date: -unknown-  !
!  Reviewer: J.Musser                                 Date: 19-Sept-13 !
!                                                                      !
!  Purpose: Remove comments                                            !
!                                                                      !
!           Example:  IN: > LINE ::  "MW_g( 3 ) =  32.0 ! Oxygen"      !
!                     OUT > LINE ::  "MW_g( 3 ) =  32.0         "      !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE remove_comment(LINE, LSTART, MAXCOL)

      IMPLICIT NONE

! Passed Variables: Dummy argument format required by ODEPACK.
!---------------------------------------------------------------------//
! Input data line
      CHARACTER(len=*), intent(INOUT) :: LINE
!Start of comments
      INTEGER, intent(IN) :: LSTART
! Maximum column of input data line to search
      INTEGER, intent(IN) :: MAXCOL

! Local Variables:
!---------------------------------------------------------------------//
! Loop index
      INTEGER :: L

      DO l = lstart, maxcol
         line(l:l) = ' '
      END DO

      RETURN
      END SUBROUTINE remove_comment


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine Name: REMOVE_PAR_BLANKS (LINE)                           !
!  Author: J.Musser                                   Date: 19-Spt-13  !
!                                                                      !
!  Purpose: Remove blanks within parentheses. This addition was need   !
!           to resolve portability issues on ALCF machines.            !
!                                                                      !
!           Example:  IN: > LINE :: "MW_g( 3 ) = 32.0"                 !
!                     OUT > LINE :: "MW_g(3)   = 32.0"                 !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE remove_par_blanks(LINE)

      IMPLICIT NONE

! Passed Variables: Dummy argument format required by ODEPACK.
!---------------------------------------------------------------------//
! Input data line
      CHARACTER(len=*), intent(INOUT) :: LINE

! Local Variables:
!---------------------------------------------------------------------//
! Loop index
      INTEGER :: L
! Search positions
      INTEGER :: POS, lP, rP
! Flag for space replacement
      LOGICAL :: searchRight
! Internal search flag
      LOGICAL :: replace
! Debug flag
      LOGICAL, parameter :: verbose = .false.


! Exit if the string is empty.
      IF(len_trim(line) == 0) return

! Get the position of the first left parentheses.
      lp = index(line,"(")

! Initialize the loop flag.
      searchright = (lp /= 0)
      DO WHILE(searchright)
! Find the position of the first right parentheses.
        rp = lp + index(line(lp:),")")
! Check if there are any blank spaces:
        IF(index(line(lp:rp-1)," ") /= 0) THEN

           IF(verbose) WRITE(*,"(3X,'Removing spaces: ')")
           IF(verbose) WRITE(*,"(5X,'Before: ',A)") trim(line)

! Initialize the loop flag and sub-string position.
            replace = .true.
            pos = lp+1
            DO WHILE(replace)
! If a blank is located, slide all entries to the left one position and
! add a blank to the end of the sub-string.
               IF(line(pos:pos) == " ") THEN
                  DO l=pos,rp-2
                     line(l:l) = line(l+1:l+1)
                  ENDDO
                  line(rp-1:rp-1) = " "
               ELSE
! If there the character is not a space, increment character index.
                  pos = pos + 1
               ENDIF
! Exit if all that remains in the sub-string are empty spaces.
               replace = (len_trim(line(pos:rp-1)) /= 0)
            ENDDO
           IF(verbose) WRITE(*,"(5X,'After:  ',A)") trim(line)
        ENDIF
! Check if there is another set of parentheses.
        lp = rp + index(line(rp+1:),"(")
! Exit if no addition parentheses pair is found.
        searchright = (lp.NE.rp)
      ENDDO

      return
      END SUBROUTINE remove_par_blanks