check_bc_pic.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
! minimum amount of geometry data.                                     !
!                                                                      !
! Subroutine: CHECK_BC_PIC                                             !
! Author: R. Garg                                     Date: 11-Jun-14  !
!                                                                      !
! Purpose: Determine if BCs are "DEFINED" and that they contain the    !
! minimum amount of geometry data.                                     !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_pic(M_TOT)

! Global Variables:
!---------------------------------------------------------------------//

! Simulation dimension (2D/3D)
      USE discretelement, only: dimn
! User specified BC
      use bc
! User specified: BC geometry
      use bc, only: bc_ep_s
! Use specified flag for ignoring PO BC for discrete solids
      USE bc, only: bc_po_apply_to_des
! PIC model specific BC region specification.
      USE bc, only: bc_pic_mi_const_npc, bc_pic_mi_const_statwt
      USE bc, only: bc_x_w, bc_x_e, bc_y_s, bc_y_n, bc_z_b, bc_z_t

! Solids phase identifier
      use run, only: solids_model
! Number of PIC inlet/outlet BCs detected.
      use pic_bc, only: pic_bcmi, pic_bcmo
!
      use pic_bc, only: pic_bcmi_map
      use pic_bc, only: pic_bcmo_map
! Global Parameters:
!---------------------------------------------------------------------//
! The max number of BCs.
      use param, only: dimension_bc
! Parameter constants
      use param1, only: zero, undefined


! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      IMPLICIT NONE


! Passed Arguments:
!---------------------------------------------------------------------//
! Total number of solids phases.
      INTEGER, INTENT(in) :: M_TOT

! Local Variables:
!---------------------------------------------------------------------//
! loop/variable indices
      INTEGER :: BCV, M, BCV_I, IDIM
      INTEGER :: BCV2, BCV2_I

! Temp logical variables for checking constant npc and statwt specification
      LOGICAL :: CONST_NPC, CONST_STATWT

      DOUBLE PRECISION :: BC_ORIG(3), BC_END(3), BC2_ORIG(3) , BC2_END(3)
      DOUBLE PRECISION :: BC_MIN, BC_MAX, BC2_MIN, BC2_MAX

      LOGICAL :: SEP_AXIS

!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BC_PIC")

! Initialize
      pic_bcmi = 0
      pic_bcmo = 0

! Loop over all BCs looking for PIC solids inlets/outlets
      DO bcv = 1, dimension_bc

         SELECT CASE (bc_type_enum(bcv))

! Determine the number of mass inlets that contain PIC solids.
         CASE (mass_inflow)
            m_lp: DO m=1,m_tot
               IF(solids_model(m)=='PIC' .AND.                         &
                  bc_ep_s(bcv,m) > zero) THEN
                  pic_bcmi = pic_bcmi + 1
                  pic_bcmi_map(pic_bcmi) = bcv
                  EXIT m_lp
               ENDIF
            ENDDO m_lp

! Count the number of pressure outflows.
         CASE (p_outflow)
            IF(bc_po_apply_to_des(bcv)) then
               pic_bcmo = pic_bcmo + 1
               pic_bcmo_map(pic_bcmo) = bcv
            ENDIF

! Flag CG_MI as an error if PIC solids are present.
         CASE (cg_mi)
            DO m=1,m_tot
               IF(solids_model(m)=='PIC') THEN
                  IF(bc_ep_s(bcv,m) /= undefined .AND.                 &
                     bc_ep_s(bcv,m) > zero) THEN
                     WRITE(err_msg,1000) trim(ivar('BC_TYPE',bcv)),    &
                        'GC_MI'
                     CALL flush_err_msg(abort=.true.)
                  ENDIF
               ENDIF
            ENDDO

         CASE (cg_po)
            WRITE(err_msg,1000) trim(ivar('BC_TYPE',bcv)), 'GC_PO'
            CALL flush_err_msg(abort=.true.)

         CASE (mass_outflow, outflow, p_inflow)
            WRITE(err_msg,1000) trim(ivar('BC_TYPE',bcv)),             &
               bc_type_enum(bcv)
            CALL flush_err_msg(abort=.true.)

         END SELECT

      ENDDO


      CALL finl_err_msg


1000  FORMAT('Error 1000: Unsupported boundary condition specified ',  &
           'with',/'PIC simulation: ',a,' = ',a,/'Please correct the ',&
           'mfix.dat file.')


! Loop over all MI BC's for data consistency checks
      DO bcv_i = 1, pic_bcmi

! Get the user defined BC ID.
         bcv = pic_bcmi_map(bcv_i)

         DO m=1,m_tot
            IF(solids_model(m)=='PIC' .AND.                         &
                 bc_ep_s(bcv,m) > zero) THEN
               const_npc    = (bc_pic_mi_const_npc  (bcv, m) .ne. 0)
               const_statwt = (bc_pic_mi_const_statwt(bcv, m) .ne. zero  )
               IF(const_npc.and.const_statwt) then
                  WRITE(err_msg, 1100) bcv, m
                  CALL flush_err_msg(abort=.true.)
               ENDIF

               IF(.not.const_npc.and.(.not.const_statwt)) then
                  WRITE(err_msg, 1101) bcv, m
                  CALL flush_err_msg(abort=.true.)
               ENDIF


            ENDIF
         ENDDO

1100     FORMAT('Error 1100: In PIC model for BC # ',i5, &
              ' and solid phase # ', i5, /, &
              'Non zero Values specified for both ', &
              'BC_PIC_MI_CONST_NPC and BC_PIC_MI_CONST_STATWT.', /, &
              'Choose between constant number of parcels per cell or ', &
              'constant statistical weight', /, &
              'See MFIX readme',/'Please correct the data file.')


1101     FORMAT('Error 1101: In PIC model for BC # ',i5, &
              ' and solid phase # ', i5, /, &
              'A non-zero value not specified for ', &
              'BC_PIC_MI_CONST_NPC or BC_PIC_MI_CONST_STATWT. ', /, &
              'Choose between constant number of parcels per cell or ', &
              'constant statistical weight', /, &
              'See MFIX readme',/'Please correct the data file.')


         bc_orig(1) = bc_x_w(bcv)
         bc_orig(2) = bc_y_s(bcv)
         bc_orig(3) = bc_z_b(bcv)
         bc_end(1)  = bc_x_e(bcv)
         bc_end(2)  = bc_y_n(bcv)
         bc_end(3)  = bc_z_t(bcv)
         bcvtwoloop: DO bcv2_i = bcv_i+1, pic_bcmi

            ! Get the user defined BC ID.
            bcv2 = pic_bcmi_map(bcv2_i)


            bc2_orig(1) = bc_x_w(bcv2)
            bc2_orig(2) = bc_y_s(bcv2)
            bc2_orig(3) = bc_z_b(bcv2)
            bc2_end(1)  = bc_x_e(bcv2)
            bc2_end(2)  = bc_y_n(bcv2)
            bc2_end(3)  = bc_z_t(bcv2)

            sep_axis  = .false.
            DO idim = 1, dimn

               bc_min = bc_orig(idim)
               bc_max = bc_end(idim)
               bc2_min = bc2_orig(idim)
               bc2_max = bc2_end(idim)


               if(bc_min.eq.bc_max.and.bc_min.eq.bc2_min.and.bc_min.eq.bc2_max) cycle
               !if above is true, then the sep_axis will be true (see below) and
               !overlapping bc regions will also be deemed as non-overlapping

               !Check for separating axis. If the separating axis exists, then
               !the BC regions can't overlap.
               !generally equality implies lack of sep_axis, and thus, overlapping
               !However, doing so will flag all BC's as overlapping since
               !BC's have to share common edges. So here the equality is considered
               !as existence of a separating axis, and hence, no overlap
               !equality is also considered as separating axis which is
               if ((bc_min .ge. bc2_max)  .or. (bc_max .le. bc2_min) ) then
                  sep_axis = .true.
                  exit
               endif

            end DO

            if(.not.sep_axis) then
               !implies the BC regions could not find a separating axis and are therefore
               !overlapping

               write(err_msg, 1004) bcv, bcv2
               CALL flush_err_msg(footer = .false.)

               DO idim = 1, dimn

                  write(err_msg, 1005) 'BC1', idim, bc_orig(idim), bc_end(idim)
                  CALL flush_err_msg(header = .false., footer = .false.)

                  write(err_msg, 1005) 'BC2', idim, bc2_orig(idim), bc2_end(idim)
                  CALL flush_err_msg(header = .false., footer = .false.)

               ENDDO
               write(err_msg, 1006)

               CALL flush_err_msg(header=.false., abort=.true.)

            endif
         end DO bcvtwoloop


      ENDDO

1004  FORMAT('Error # 1004 for PIC Solids MI BC:',/5x, &
           'Overlapping MI BC regions with non zero', /, &
           'solids volume fraction  not allowed.', /, &
           'Overlapping BCs are', 2(2x, i4))

1005  FORMAT('Spans of ', a, ' in dir ', i2, /5x, 2(2x, g17.8))


1006  Format('Please correct the data file. Exiting.')


      END SUBROUTINE check_bc_pic