comp_mean_fields1.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE comp_mean_fields1

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param, only: dimension_3
      USE param1, only: zero, one
      USE fldvar, only: u_s, v_s, w_s, rop_s, ro_s
      USE geometry
      USE indices
      USE compar
      USE parallel
      USE sendrecv
      USE discretelement
      use desgrid
      use desmpi
      USE mfix_pic
      USE functions
      use particle_filter, only: des_interp_on
      use particle_filter, only: filter_weight
      use particle_filter, only: filter_cell
      use particle_filter, only: filter_size
      use sendrecvnode, only: des_collect_gdata
      use physprop, only: mmax
      use param1, only: small_number

      IMPLICIT NONE
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Loop counters: particles, filter cells, phases
      INTEGER NP, LC, M, mLB, mUB
! Fluid cell index
      INTEGER IJK
! Total Mth solids phase volume in IJK
      DOUBLE PRECISION :: SOLVOLINC(dimension_3,mmax+des_mmax)
! One divided by the total solids volume.
      DOUBLE PRECISION :: OoSOLVOL
! PVOL times statistical weight, and times filter weight
      DOUBLE PRECISION :: VOL_WT, VOLxWEIGHT
! Loop bound for filter
      INTEGER :: LP_BND


!-----------------------------------------------


      solvolinc(:,:) = zero

      mlb = mmax+1
      mub = des_mmax+mmax

      IF(mppic) THEN
! initialize only information related to the discrete 'phases' of these 
! continuous variables
         u_s(:,mlb:mub) = zero
         v_s(:,mlb:mub) = zero
         IF(do_k) w_s(:,mlb:mub) = zero
      ENDIF

! Calculate the gas phase forces acting on each particle.
!$omp parallel default(none) &
!$omp private(NP, VOL_WT, M, LC, IJK, VOLXWEIGHT) &
!$omp shared(MAX_PIP, PVOL, DES_STAT_WT, PIJK, LP_BND, MPPIC, &
!$omp       FILTER_WEIGHT, SOLVOLINC, U_S, V_S, W_S, DO_K, &
!$omp       FILTER_CELL, FILTER_SIZE, DES_VEL_NEW)
!$omp do
      do np=1,max_pip
         IF(.NOT.is_normal(np)) cycle

         vol_wt = pvol(np)
         IF(mppic) vol_wt = vol_wt*des_stat_wt(np)
! Particle phase for data binning.
         m = pijk(np,5)

         DO lc=1,filter_size
            ijk = filter_cell(lc,np)
! Particle volume times the weight for this cell.
            volxweight = vol_wt*filter_weight(lc,np)
! Accumulate total solids volume (by phase)
!$omp atomic
            solvolinc(ijk,m) = solvolinc(ijk,m) + volxweight
            IF(mppic) THEN
! Accumulate total solids momentum (by phase)
!$omp atomic
               u_s(ijk,1) = u_s(ijk,1) + &
                  des_vel_new(np,1)*volxweight
!$omp atomic
               v_s(ijk,1) = v_s(ijk,1) + &
                  des_vel_new(np,2)*volxweight
               IF(do_k) THEN
!$omp atomic
                  w_s(ijk,1) = w_s(ijk,1) + &
                     des_vel_new(np,3)*volxweight
               ENDIF
            ENDIF
         ENDDO
      ENDDO
!$omp end do
!$omp end parallel


! Summ data interpolted into ghost cells into physical cells
!---------------------------------------------------------------------//
      IF(des_interp_on) THEN
         CALL des_collect_gdata(solvolinc(:,mlb:mub))
         IF(mppic) THEN
            CALL des_collect_gdata(u_s(:,1))
            CALL des_collect_gdata(v_s(:,1))
            IF(do_k) CALL des_collect_gdata(w_s(:,1))
         ENDIF
      ENDIF


! Calculate the cell average solids velocity, the bulk density,
! and the void fraction.
!---------------------------------------------------------------------//
!$omp parallel do if(ijkend3 .ge. 2000) default(shared)                &
!$omp private(IJK,M,OoSOLVOL)
      DO ijk = ijkstart3, ijkend3
         IF(.NOT.fluid_at(ijk)) cycle

! calculating the bulk density of solids phase
         rop_s(ijk,mlb:mub) = ro_s(ijk,mlb:mub)*&
            solvolinc(ijk,mlb:mub)/vol(ijk)

! calculating the cell average solids velocity for each solids phase
         IF(mppic) THEN
            oosolvol = sum(solvolinc(ijk,:))
            IF(oosolvol > small_number) THEN
               oosolvol = one/oosolvol
               u_s(ijk,1) = u_s(ijk,1)*oosolvol
               v_s(ijk,1) = v_s(ijk,1)*oosolvol
               IF(do_k) w_s(ijk,1) = w_s(ijk,1)*oosolvol
            ENDIF
         ENDIF
      ENDDO
!$omp end parallel do


! Halo exchange of solids volume fraction data.
      calL send_recv(rop_s,2)

      end SUBROUTINE comp_mean_fields1