physprop_mod.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module: physprop                                                    C
!  Purpose: Common block containing physical property data             C
!                                                                      C
!  Author: M. Syamlal                                 Date: dd-mmm-yy  C
!  Reviewer:                                          Date: dd-mmm-yy  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      MODULE physprop

! Modules
!---------------------------------------------------------------------//
      Use param, only: dim_m, dim_n, dim_n_g, dim_n_s
!---------------------------------------------------------------------//


! Number of solids phases
      INTEGER :: mmax

! Real number of solids phases for GHD theory
      INTEGER :: smax

! Particle diameters
      DOUBLE PRECISION :: d_p0(dim_m)

! Constant or baseline solids phase densities.
      DOUBLE PRECISION :: ro_s0(dim_m)

! Constant solids phase species mass fractions. These values delinate
! the baseline/initial solids phase composition for ariable density
      DOUBLE PRECISION :: x_s0(dim_m, dim_n_s)

! Density of solid species (constant)
      DOUBLE PRECISION :: ro_xs0(dim_m, dim_n_s)

! The index of an inert solids phase species. This is needed for
! calculating the variable solids phase density.
      INTEGER :: inert_species(dim_m)

! Inert solids phase species mass fraction in dilute region.  This is needed for
! calculating the variable solids phase density.
      DOUBLE PRECISION :: dil_inert_x_vsd(dim_m)

! Factor to define dilute region for special treatment of
! the variable solids phase density.
      DOUBLE PRECISION :: dil_factor_vsd

! Particle shape factor
      DOUBLE PRECISION :: shape_factor(dim_m)

! Specified constant solids viscosity
      DOUBLE PRECISION mu_s0(dim_m)

! Flag indicates whether the phase becomes close-packed at ep_star
      LOGICAL :: close_packed (dim_m)

! Specified constant gas density
      DOUBLE PRECISION ro_g0

! Specified constant gas viscosity
      DOUBLE PRECISION mu_g0

! Virtual (added) mass coefficient Cv
      DOUBLE PRECISION cv

! Gas viscosity
      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::  mu_g

! Average molecular weight of gas
      DOUBLE PRECISION mw_avg

! Constant constant-pressure specific heat of gas
      DOUBLE PRECISION c_pg0

! Reference temperature for enthalpy calculations (K)
      DOUBLE PRECISION, PARAMETER :: t_ref = 298

! Constant pressure specific heat of gas
      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::  c_pg

! Constant constant-pressure specific heat of solids
      DOUBLE PRECISION c_ps0(dim_m)

! Constant pressure specific heat of solids
      DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  c_ps

! Specified constant gas conductivity
      DOUBLE PRECISION :: k_g0

! Conductivity of gas
      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE ::  k_g

! Specified constant solids conductivity
      DOUBLE PRECISION k_s0(dim_m)

! Conductivity of solids
      DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  k_s

! Granular Temperature Conductivity (associated with temperature grad)
      DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  kth_s

! Granular Temperature Conductivity (associated with volume fraction grad)
      DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  kphi_s

! Specified constant gas diffusivity
      DOUBLE PRECISION dif_g0

! Diffusivity of gas species N
      DOUBLE PRECISION, DIMENSION(:, :), ALLOCATABLE ::  dif_g

! Specified constant solids diffusivity
      DOUBLE PRECISION dif_s0(dim_m)

! Diffusivity of solids species N
      DOUBLE PRECISION, DIMENSION(:, :, :), ALLOCATABLE ::  dif_s

! Total number of gas or solids species
      INTEGER :: nmax(0:dim_m) ! Runtime (all phases)
      INTEGER :: nmax_g        ! Number of gas phase species
      INTEGER :: nmax_s(dim_m) ! Number of solids phase species

! Molecular weight of gas species
      DOUBLE PRECISION :: mw_g (dim_n_g)

! Molecular weight of solids species
      DOUBLE PRECISION :: mw_s (dim_m, dim_n_s)

! Molecular weight of gas mixture
      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE :: mw_mix_g

! Logical for reading thermochemical database.
      LOGICAL :: database_read = .true.

! Polynomical coefficients for calculating specific heat.
      DOUBLE PRECISION alow (7,0:dim_m, dim_n) ! Tlow --> Tcom
      DOUBLE PRECISION ahigh(7,0:dim_m, dim_n) ! Tcom --> Thigh

! Range where the polynomials are valid.
      DOUBLE PRECISION thigh(0:dim_m, dim_n) ! Upper bound
      DOUBLE PRECISION tlow (0:dim_m, dim_n) ! Lower bound
      DOUBLE PRECISION tcom (0:dim_m, dim_n) ! Switch from low to high

! Heat of formation at Tref divided by the gas constant.
      DOUBLE PRECISION hfrefor(0:dim_m, dim_n)

! Reference values.
      DOUBLE PRECISION icpor_l(0:dim_m, dim_n)
      DOUBLE PRECISION icpor_h(0:dim_m, dim_n)

CONTAINS

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: CALC_MW (X_g, DIM, L, NMAX, MW_g)                      C
!  Purpose: Calculate average molecular weight of gas                  C
!                                                                      C
!  Author: M. Syamlal                                 Date: 19-OCT-92  C
!  Reviewer: P. Nicoletti                             Date: 11-DEC-92  C
!                                                                      C
!  Revision Number:                                                    C
!  Purpose:                                                            C
!  Author:                                            Date: dd-mmm-yy  C
!  Reviewer:                                          Date: dd-mmm-yy  C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:None                                           C
!  Variables modified:None                                             C
!                                                                      C
!  Local variables: SUM, N                                             C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
!
      DOUBLE PRECISION FUNCTION calc_mw (X_G, DIM, L, NMAX, MW_G)
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE toleranc
      IMPLICIT NONE
!-----------------------------------------------
!   D u m m y   A r g u m e n t s
!-----------------------------------------------
!
!                      Mass fraction array's Ist dimension
      INTEGER          DIM
!
!
!                      Max of X_g array 2nd index and MW_g array index
      INTEGER          NMAX
!
!                      Mass fraction array
!
      DOUBLE PRECISION X_g(dim, nmax)
!
!                      Moleculare weight array
!
      DOUBLE PRECISION MW_g(nmax)
!
!                      Mass fraction array Ist index
      INTEGER          L
!
!  Local variable
!
!                      local sum
      DOUBLE PRECISION SUM
!
!                      local index
      INTEGER           NN
!-----------------------------------------------
!
      sum = zero
      DO nn = 1, nmax
         sum = sum + x_g(l,nn)/mw_g(nn)
      END DO
      calc_mw = one/max(sum,omw_max)
!
      RETURN
      END FUNCTION calc_mw

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  FUNCTION: blend_function                                            C
!  Purpose: To calculate blending function                             C
!                                                                      C
!  Author: S. Pannala                                 Date: 28-FEB-06  C
!  Reviewer:                                          Date:            C
!  Modified:                                          Date: 24-OCT-06  C
!                                                                      C
!                                                                      C
!  Literature/Document References:                                     C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      DOUBLE PRECISION FUNCTION blend_function(IJK)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE compar
      USE constant
      USE fldvar
      USE fun_avg
      USE functions
      USE geometry
      USE indices
      USE param
      USE param1
      USE run
      USE toleranc
      USE visc_s
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! IJK index
      INTEGER, INTENT(IN) :: IJK
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Logical to see whether this is the first entry to this routine
      LOGICAL,SAVE:: FIRST_PASS = .true.
! Blend Factor
      Double Precision:: blend, blend_right
! Scale Factor
      Double Precision, Save:: scale
! Midpoint
      Double Precision, Save:: ep_mid_point
!-----------------------------------------------

! Tan hyperbolic blending of stresses
      IF(tanh_blend) THEN
         IF(ep_g(ijk) .LT. ep_g_blend_end(ijk).AND. ep_g(ijk) .GT. ep_g_blend_start(ijk)) THEN
            ep_mid_point = (ep_g_blend_end(ijk)+ep_g_blend_start(ijk))/2.0d0
            blend = tanh(2.0d0*pi*(ep_g(ijk)-ep_mid_point)/ &
            (ep_g_blend_end(ijk)-ep_g_blend_start(ijk)))
            blend = (blend+1.0d0)/2.0d0
         ELSEIF(ep_g(ijk) .GE. ep_g_blend_end(ijk)) THEN
            blend = 1.0d0
         ELSEIF(ep_g(ijk) .LE. ep_g_blend_start(ijk)) THEN
            blend = 0.0d0
         ENDIF

! Truncated and Scaled Sigmoidal blending of stresses
      ELSEIF(sigm_blend) THEN
         IF(first_pass) THEN
            blend_right =  1.0d0/(1+0.01d0**((ep_g_blend_end(ijk)-ep_star_array(ijk))&
            /(ep_g_blend_end(ijk)-ep_g_blend_start(ijk))))
            blend_right = (blend_right+1.0d0)/2.0d0
            scale = 1.0d0/blend_right
            write(*,*) 'Blending value at end and scaling factor', blend_right, scale
            first_pass = .false.
         ENDIF
         IF(ep_g(ijk) .LT. ep_g_blend_end(ijk)) THEN
            blend =  scale/(1+0.01d0**((ep_g(ijk)-ep_star_array(ijk))&
            /(ep_g_blend_end(ijk)-ep_g_blend_start(ijk))))
         ELSEIF(ep_g(ijk) .GE. ep_g_blend_end(ijk)) THEN
            blend = 1.0d0
         ENDIF

      ENDIF

      blend_function = blend

      RETURN
      END FUNCTION blend_function

      END MODULE physprop