check_geometry_prereqs.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_GEOMETRY_PREREQS                                  !
!  Purpose: Check the distributed parallel namelist variables.         !
!                                                                      !
!  Author: P. Nicoletti                               Date: 14-DEC-99  !
!  Reviewer: J.Musser                                 Date: 16-Jan-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_geometry_prereqs



! Global Variables:
!---------------------------------------------------------------------//
! Domain partitions in various directions.
      use geometry, only: imax, no_i, xmin
      use geometry, only: jmax, no_j
      use geometry, only: kmax, no_k, dz, zlength

! Runtime flag specifying 2D simulations
!      use geometry, only: NO_K

      use geometry, only: coordinates, cylindrical
      use geometry, only: cyclic_x, cyclic_x_pd
!      use geometry, only: COORDINATES

! Global Parameters:
!---------------------------------------------------------------------//
      use param1, only: one, zero, undefined_i, undefined

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      use toleranc

      implicit none

! Initialize the error manager.
      CALL init_err_msg("CHECK_GEOMETRY_PREREQS")

! Verify that the domain decomposition was specified.
      IF(imax == undefined_i .OR. jmax == undefined_i .OR.             &
         (.NOT.no_k .AND. kmax == undefined_i) ) THEN
         WRITE(err_msg,1000)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1000 FORMAT('Error 1000: IMAX or JMAX or KMAX not specified in ',     &
          'mfix.dat')

! If no variation in a direction is considered, the number of cells in
! that direction should be 1
      IF(no_i) THEN
         WRITE(err_msg, 1100) 'I','I','east and west'
         CALL flush_err_msg(abort=.true.)
      ENDIF

      IF(no_j) THEN
         WRITE(err_msg, 1100) 'J','J','north and south'
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1100 FORMAT('Error 1100: Illegal geometry: NO_',a1,' is disabled. ',  &
         'The same functionality',/'is achieved with one cell (',a1,   &
         'MAX=1) and making the ',a,' walls',/'free-slip. Please ',    &
         'correct the mfix.dat file.')

      IF (xmin < zero) THEN
         WRITE(err_msg, 1101) 'XMIN'
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1101 FORMAT('Error 1101: Illegal geometry: ',a,' cannot be less ',    &
         'than zero.',/'Please correct the mfix.dat file.')


      SELECT CASE(trim(coordinates))
      CASE ('CYLINDRICAL')
         cylindrical = .true.
         IF(cyclic_x .OR. cyclic_x_pd) THEN
            WRITE(err_msg, 1102)
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1102 FORMAT('Error 1102: X-axis cannot be CYCLIC in cylindrical ',    &
         'coordinates',/'Please correct the mfix.dat file.')

      CASE ('CARTESIAN')
         cylindrical = .false.

      CASE DEFAULT
         WRITE(err_msg, 1103)
         CALL flush_err_msg(abort=.true.)

 1103 FORMAT('Error 1103: Unknown COORDINATES specified. Please ',     &
         'correct the ',/'mfix.dat file.')

      END SELECT


      IF(no_k) THEN
         IF(kmax == undefined_i) THEN
            kmax = 1
         ELSEIF(kmax /= 1) THEN
            WRITE(err_msg, 1110) 'KMAX','NO_K'
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1110 FORMAT('Error 1110: Illegal geometry: ',a,' must remain ',       &
         'UNDEFINED_I or 1 when',/a,' is TRUE. Please correct the ',   &
         'mfix.dat file.')

         IF(dz(1)==undefined) THEN
            IF(zlength==undefined) THEN
               IF(cylindrical) THEN
                  dz(1) = 8.*atan(one)
                  zlength = 8.*atan(one)
               ELSE
                  dz(1) = one
                  zlength = one
               ENDIF
            ELSE
               dz(1) = zlength
            ENDIF
         ELSE
            IF(zlength==undefined) THEN
               zlength = dz(1)
            ELSE
               IF(.NOT.compare(zlength,dz(1)))THEN
                  WRITE(err_msg, 1111) 'DZ(1) and ZLENGTH'
                  CALL flush_err_msg(abort=.true.)
               ENDIF

  1111 FORMAT('Error 1111: Illegal geometry: ',a,' are not equal.',/   &
           'Please correct the mfix.dat file.')

            ENDIF
         ENDIF
      ENDIF

      CALL finl_err_msg

      RETURN



      END SUBROUTINE check_geometry_prereqs