check_geometry.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_GEOMETRY                                          !
!  Purpose: Check the distributed parallel namelist variables.         !
!                                                                      !
!  Author: P. Nicoletti                               Date: 14-DEC-99  !
!  Reviewer: J.Musser                                 Date: 16-Jan-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_geometry(SHIFT)

         use check_data_cg, only: get_dxyz_from_control_points

! Global Variables:
!---------------------------------------------------------------------//
! Domain partitions in various directions.
      use geometry, only: dx, xlength
      use geometry, only: dy, ylength
      use geometry, only: dz, zlength

      use geometry, only: no_i, imin1, imax, imax1, imax3
      use geometry, only: no_j, jmin1, jmax, jmax1, jmax3
      use geometry, only: no_k, kmin1, kmax, kmax1, kmax3

! Runtime flag specifying 2D simulations
!      use geometry, only: NO_K

      use geometry, only: cylindrical
      use geometry, only: cyclic_x, cyclic_x_pd
      use geometry, only: cyclic_y, cyclic_y_pd
      use geometry, only: cyclic_z, cyclic_z_pd
!      use geometry, only: COORDINATES

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      implicit none


      LOGICAL, intent(IN) :: SHIFT
      LOGICAL, external :: COMPARE

! Local Variables:
!---------------------------------------------------------------------//


! Initialize the error manager.
      CALL init_err_msg("CHECK_GEOMETRY")

      CALL get_dxyz_from_control_points

      CALL check_axis(imax, imax3, xlength, dx, 'X', 'I', no_i, shift)
      CALL check_axis(jmax, jmax3, ylength, dy, 'Y', 'J', no_j, shift)
      CALL check_axis(kmax, kmax3, zlength, dz, 'Z', 'K', no_k, shift)

      IF(shift) CALL shift_dxyz

!  Ensure that the cell sizes across cyclic boundaries are comparable
      IF(cyclic_x .OR. cyclic_x_pd) THEN
         IF(dx(imin1) /= dx(imax1)) THEN
            WRITE(err_msg,1100) 'DX(IMIN1)',dx(imin1),'DX(IMAX1)',dx(imax1)
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

      IF(cyclic_y .OR. cyclic_y_pd) THEN
         IF(dy(jmin1) /= dy(jmax1)) THEN
            WRITE(err_msg,1100) 'DY(JMIN1)',dy(jmin1),'DY(JMAX1)',dy(jmax1)
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

      IF(cyclic_z .OR. cyclic_z_pd .OR. cylindrical) THEN
         IF (dz(kmin1) /= dz(kmax1)) THEN
            WRITE(err_msg,1100) 'DZ(KMIN1)',dz(kmin1),'DZ(KMAX1)',dz(kmax1)
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

 1100 FORMAT('Error 1100: Cells adjacent to cyclic boundaries must ',  &
         'be of same size:',/2x,a,' = ',g12.5,/2x,a,' = ',g12.5,/      &
         'Please correct the mfix.dat file.')


      CALL finl_err_msg

      RETURN

      END SUBROUTINE check_geometry


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_GEOMETRY_DES                                      !
!  Author: Pradeep Gopalakrishnan                     Date:    Nov-11  !
!                                                                      !
!  Purpose: Checks the des grid input parameters.                      !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_geometry_des

! Global Variables:
!---------------------------------------------------------------------//
! Domain partition for DEM background mesh.
      use discretelement, only: desgridsearch_imax
      use discretelement, only: desgridsearch_jmax
      use discretelement, only: desgridsearch_kmax
! Domain size specified by the user.
      use geometry, only: xlength, ylength, zlength, no_k
! Maximum particle size.
      use discretelement, only: max_radius


! Global Parameters:
!---------------------------------------------------------------------//
      use param1, only: undefined_i

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      implicit none


! Local Variables:
!---------------------------------------------------------------------//
! Maximum particle diameter.
      DOUBLE PRECISION :: MAX_DIAM
! Calculated cell dimension based on particle size
      DOUBLE PRECISION :: WIDTH
!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("CHECK_GEOMETRY_DES")

! Calculate the max particle diameter and cell width.
      max_diam = 2.0d0*max_radius
      width = 3.0d0*(max_diam)

! Calculate and/or verify the grid in the X-axial direction.
      IF(desgridsearch_imax == undefined_i) THEN
         desgridsearch_imax = max(int(xlength/width), 1)
      ELSEIF((xlength/dble(desgridsearch_imax)) < max_diam) THEN
         WRITE(err_msg, 1100) 'X', max_diam,                           &
            xlength/dble(desgridsearch_imax)
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Calculate and/or verify the grid in the Y-axial direction.
      IF(desgridsearch_jmax == undefined_i) THEN
         desgridsearch_jmax = max(int(ylength/width), 1)
      ELSEIF((ylength/dble(desgridsearch_jmax)) < max_diam) THEN
         WRITE(err_msg, 1100) 'Y', max_diam,                           &
            ylength/dble(desgridsearch_jmax)
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Calculate and/or verify the grid in the Z-axial direction.
      IF(no_k) THEN
         desgridsearch_kmax = 1
      ELSEIF(desgridsearch_kmax == undefined_i) THEN
         desgridsearch_kmax = max(int(zlength/width), 1)
      ELSEIF((zlength/dble(desgridsearch_kmax)) < max_diam) THEN
         WRITE(err_msg, 1100) 'Z', max_diam,                           &
            zlength/dble(desgridsearch_kmax)
         CALL flush_err_msg(abort=.true.)
      ENDIF

      CALL finl_err_msg

 1100 FORMAT('Error 1100: The des search grid is too fine in the ',a1, &
         '-direction. The',/'maximum particle diameter is larger than',&
         ' the cell width:',/2x,'MAX DIAM:   ',g12.5,/2x,'CELL ',      &
         'WIDTH: ',g12.5,/'Decrease the values for DESGRIDSEARCH in ', &
         'the mfix.dat file.')

      RETURN
      END SUBROUTINE check_geometry_des