check_numerics.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_NUMERICS                                          !
!  Purpose: Check the numerics control namelist section                !
!                                                                      !
!  Author: P. Nicoletti                               Date: 27-NOV-91  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_numerics


! Global Variables:
!---------------------------------------------------------------------//
! Flag: Use the Fourth-order scheme
      use run, only: fpfoi
! Flag: Use the Chi-scheme
      use run, only: chi_scheme
! Flag: Set optimal LEQ solver parameters for parallel runs.
      use leqsol, only: opt_parallel
! Discretization scheme for various equations
      USE run, only: discretize, shear
! Solve system transpose
      use leqsol, only: do_transpose
! Minimize dot products in BiCGSTAB
      use leqsol, only: minimize_dotproducts
! Report solver stats.
      use leqsol, only: solver_statistics
! Controls reduction of global sums for residuals.
      use run, only: debug_resid
! Linear equation, preconditioner sweep method.
      use leqsol, only: leq_sweep
! Linear equation solution method.
      use leqsol, only: leq_method
! Calculate dot-products more efficiently for serial runs.
      use parallel, only: is_serial

      use param, only: dim_eqs

! Global Parameters:
!---------------------------------------------------------------------//
! NONE

! Global Module procedures:
!---------------------------------------------------------------------//
      use error_manager


      IMPLICIT NONE


! Local Variables:
!---------------------------------------------------------------------//
! Loop counter
      INTEGER :: L


!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_NUMERICS")

      DO l = 1,dim_eqs
         IF(discretize(l) > 9 .OR. discretize(l) < 0) THEN
            WRITE(err_msg,2002) trim(ivar('DISCRETIZE',l)),&
               trim(ival(discretize(l)))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO
 2002 FORMAT('Error 2002: Invalid option ', a,' = ', a, '.',/  &
         'Please correct the mfix.dat file.')


! Check fourth-order scheme requirements.
      IF (fpfoi) THEN
         DO l = 1,dim_eqs
            IF(discretize(l) <= 1) THEN
               WRITE(err_msg,2000)
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDDO
 2000 FORMAT('Error 2000: Fourth-order scheme (FPFOI) requires ',     &
         'DISCRETIZE >= 2',/'for all equations. Please correct the ',  &
         'mfix.dat file.')
      ENDIF


! Check chi scheme requirements.
      IF(chi_scheme)THEN
         IF(discretize(7) .NE. 3 .AND. discretize(7).NE.6) THEN
            WRITE(err_msg,2001)
            CALL flush_err_msg(abort=.true.)
 2001 FORMAT('Error 2001: CHI_SCHEME for species equations is only ',  &
         'implemented',/'for SMART and MUSCL discretization schemes ', &
         '[DISCRTIZE(7)].',/'Please correct the mfix.dat file.')
         ENDIF
         IF (shear) THEN
            WRITE(err_msg,2003)
            CALL flush_err_msg(abort=.true.)
 2003 FORMAT('Error 2003: CHI_SCHEME is currently not implemented ',   &
         'with SHEAR ',/'option. See calc_chi in module chischeme for '&
         'details.',/'Please correct the mfix.dat file.')
         ENDIF
      ENDIF


! Set the optimizations for DMP runs.
      IF (opt_parallel) THEN
         is_serial = .false.
         do_transpose = .false.
         minimize_dotproducts = .true.
         solver_statistics = .true.
         debug_resid = .false.
         leq_sweep(1:2) = 'ASAS'
         leq_method(1:2) = 2
         leq_method(3:9) = 1
      ENDIF

! Finalize the error msg.
      CALL finl_err_msg

      RETURN

      END SUBROUTINE check_numerics