calc_outflow.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: calc_outflow                                            C
!  Purpose: Calculate mass and volumetric out flow rates from an       C
!  outflow boundary                                                    C
!                                                                      C
!  Author: M. Syamlal                                 Date: 28-OCT-92  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE calc_outflow(L)

! Modules
!--------------------------------------------------------------------//
      use bc, only: bc_plane
      use bc, only: bc_k_b, bc_k_t
      use bc, only: bc_j_s, bc_j_n
      use bc, only: bc_i_w, bc_i_e
      use bc, only: bc_out_n
      use bc, only: bc_mout_g, bc_vout_g
      use bc, only: bc_mout_s, bc_vout_s
      use geometry, only: dx, dy, dz
      use geometry, only: x_e, x
      use physprop, only: smax
      use fldvar, only: u_g, v_g, w_g, u_s, v_s, w_s
      use fldvar, only: rop_g, ep_g
      use fldvar, only: rop_s, ep_s
      use functions, only: im_of, ip_of, jm_of, jp_of, km_of, kp_of
      use functions, only: fluid_at
      use functions, only: is_on_mype_plus2layers
      use functions, only: funijk
      use compar, only: dead_cell_at
      IMPLICIT NONE

! Dummy arguments
!--------------------------------------------------------------------//
! Boundary condition number
      INTEGER, INTENT(IN) :: L

! Local variables
!--------------------------------------------------------------------//
! Indices
      INTEGER :: I, J, K, IJK
! Solids phase
      INTEGER :: M
! ijk index of fluid cell adjacent to boundary cell
      INTEGER :: IJK2
!--------------------------------------------------------------------//

      bc_out_n(l) = bc_out_n(l) + 1
      DO k = bc_k_b(l), bc_k_t(l)
         DO j = bc_j_s(l), bc_j_n(l)
            DO i = bc_i_w(l), bc_i_e(l)
! Check if current i,j,k resides on this PE
               IF (.NOT.is_on_mype_plus2layers(i,j,k)) cycle
               IF (dead_cell_at(i,j,k)) cycle  ! skip dead cells
               ijk = funijk(i,j,k)
               SELECT CASE (trim(bc_plane(l)))
               CASE ('W')
                  ijk2 = im_of(ijk)
                  bc_mout_g(l) = bc_mout_g(l) + dy(j)*x_e(i-1)*dz(k)*&
                     u_g(ijk2)*rop_g(ijk2)
                  bc_vout_g(l) = bc_vout_g(l) + dy(j)*x_e(i-1)*dz(k)*&
                     u_g(ijk2)*ep_g(ijk2)
               CASE ('E')
                  ijk2 = ip_of(ijk)
                  bc_mout_g(l) = bc_mout_g(l) + dy(j)*x_e(i)*dz(k)*&
                     u_g(ijk)*rop_g(ijk2)
                  bc_vout_g(l) = bc_vout_g(l) + dy(j)*x_e(i)*dz(k)*&
                     u_g(ijk)*ep_g(ijk2)
               CASE ('S')
                  ijk2 = jm_of(ijk)
                  bc_mout_g(l) = bc_mout_g(l) + dx(i)*x(i)*dz(k)*&
                     v_g(ijk2)*rop_g(ijk2)
                  bc_vout_g(l) = bc_vout_g(l) + dx(i)*x(i)*dz(k)*&
                     v_g(ijk2)*ep_g(ijk2)
               CASE ('N')
                  ijk2 = jp_of(ijk)
                  bc_mout_g(l) = bc_mout_g(l) + dx(i)*x(i)*dz(k)*&
                     v_g(ijk)*rop_g(ijk2)
                  bc_vout_g(l) = bc_vout_g(l) + dx(i)*x(i)*dz(k)*&
                     v_g(ijk)*ep_g(ijk2)
               CASE ('B')
                  ijk2 = km_of(ijk)
                  bc_mout_g(l) = bc_mout_g(l) + dx(i)*dy(j)*&
                     w_g(ijk2)*rop_g(ijk2)
                  bc_vout_g(l)=bc_vout_g(l)+dx(i)*dy(j)*&
                     w_g(ijk2)*ep_g(ijk2)
               CASE ('T')
                  ijk2 = kp_of(ijk)
                  bc_mout_g(l)=bc_mout_g(l)+dx(i)*dy(j)*&
                     w_g(ijk)*rop_g(ijk2)
                  bc_vout_g(l) = bc_vout_g(l) + dx(i)*dy(j)*&
                     w_g(ijk)*ep_g(ijk2)
               END SELECT

               DO m = 1, smax
                  SELECT CASE (trim(bc_plane(l)))
                  CASE ('W')
                     ijk2 = im_of(ijk)
                     bc_mout_s(l,m) = bc_mout_s(l,m) + dy(j)*x_e(i-1)*&
                        dz(k)*u_s(ijk2,m)*rop_s(ijk2,m)
                     bc_vout_s(l,m) = bc_vout_s(l,m) + dy(j)*x_e(i-1)*&
                        dz(k)*u_s(ijk2,m)*ep_s(ijk2,m)
                  CASE ('E')
                     ijk2 = ip_of(ijk)
                     bc_mout_s(l,m) = bc_mout_s(l,m) + dy(j)*x_e(i)*&
                        dz(k)*u_s(ijk,m)*rop_s(ijk2,m)
                     bc_vout_s(l,m) = bc_vout_s(l,m) + dy(j)*x_e(i)*&
                        dz(k)*u_s(ijk,m)*ep_s(ijk2,m)
                  CASE ('S')
                     ijk2 = jm_of(ijk)
                     bc_mout_s(l,m) = bc_mout_s(l,m) + dx(i)*x(i)*&
                        dz(k)*v_s(ijk2,m)*rop_s(ijk2,m)
                     bc_vout_s(l,m) = bc_vout_s(l,m) + dx(i)*x(i)*&
                        dz(k)*v_s(ijk2,m)*ep_s(ijk2,m)
                  CASE ('N')
                     ijk2 = jp_of(ijk)
                     bc_mout_s(l,m) = bc_mout_s(l,m) + dx(i)*x(i)*&
                        dz(k)*v_s(ijk,m)*rop_s(ijk2,m)
                     bc_vout_s(l,m) = bc_vout_s(l,m) + dx(i)*x(i)*&
                        dz(k)*v_s(ijk,m)*ep_s(ijk2,m)
                  CASE ('B')
                     ijk2 = km_of(ijk)
                     bc_mout_s(l,m) = bc_mout_s(l,m) + dx(i)*dy(j)*&
                        w_s(ijk2,m)*rop_s(ijk2,m)
                     bc_vout_s(l,m) = bc_vout_s(l,m) + dx(i)*dy(j)*&
                        w_s(ijk2,m)*ep_s(ijk2,m)
                  CASE ('T')
                     ijk2 = kp_of(ijk)
                     bc_mout_s(l,m) = bc_mout_s(l,m) + dx(i)*dy(j)*&
                        w_s(ijk,m)*rop_s(ijk2,m)
                     bc_vout_s(l,m) = bc_vout_s(l,m) + dx(i)*dy(j)*&
                        w_s(ijk,m)*ep_s(ijk2,m)
                  END SELECT
               ENDDO   ! end do loop m = 1,smax

            ENDDO   ! end do loop (i=bc_i_w(l), bc_i_e(l))
         ENDDO   ! end do loop (j=bc_j_s(l), bc_j_n(l))
      ENDDO   ! end do loop (k=bc_k_b(l), bc_k_t(l))

      RETURN
      END SUBROUTINE calc_outflow