qmomk_gas_drag.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: QMOMK_GAS_DRAG(A_M, B_M, IER, UV, VV, WV)              C
!  Purpose: QMOMK - Accounting for the equal and opposite drag force   C
!           on gas due to particles by introducing the drag            C
!           as a source term. Face centered                            C
!                                                                      C
!  Author: Jay Boyalakuntla                           Date: 12-Jun-04  C
!  Reviewer: Alberto Passalacqua                      Date:            C
!            Re-used to develop QMOMK_GAS_DRAG from the                C
!            original DES_GAS_DRAG                                     C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE qmomk_gas_drag(A_M, B_M, IER, UV, VV, WV)
!-----------------------------------------------
!     M o d u l e s
!-----------------------------------------------

      USE compar, only: ijkstart3, ijkend3
      USE discretelement, only: dimn
      USE fun_avg, only: avg_x, avg_y, avg_z
      USE functions, only: fluid_at, east_of, north_of, top_of
      USE indices, only: i_of, j_of, k_of
      USE geometry, only: vol_u, vol_v, vol_w
      USE param
      USE param1
      USE physprop, only: mmax
      USE qmom_kinetic_equation, only: qmomk_nn
      USE qmom_kinetic_equation

      IMPLICIT NONE
!-----------------------------------------------
!     G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!     D u m m y   A r g u m e n t s
!-----------------------------------------------
!
!     Error index
      INTEGER          IER
!
!     Indices
      INTEGER          IJK
!
!     Phase index
      INTEGER          M, UV, VV, WV
!     Averaging Factor
      DOUBLE PRECISION :: AVG_FACTOR
!     Grid indices
      INTEGER          I,J,K,IN
!
      DOUBLE PRECISION USFCM, VSFCM, WSFCM
      DOUBLE PRECISION A_M(dimension_3, -3:3, 0:dimension_m)
      DOUBLE PRECISION B_M(dimension_3, 0:dimension_m)
      DOUBLE PRECISION tmp_A, tmp_B

!-----------------------------------------------
      avg_factor = 0.25d0*(dimn-2) + 0.5d0*(3-dimn)
      IF(uv.EQ.1) THEN
         DO m = 1, mmax
            DO ijk = ijkstart3, ijkend3
               IF(fluid_at(ijk)) THEN
                  i = i_of(ijk)
                  j = j_of(ijk)
                  k = k_of(ijk)

                  DO in = 1, qmomk_nn
                    usfcm = avg_x(qmomk_u1(in,ijk,m),qmomk_u1(in,east_of(ijk),m),i_of(ijk))
                    tmp_a = -avg_x(qmomk_f_gs(in,ijk,m),qmomk_f_gs(in,east_of(ijk),m),i)*vol_u(ijk)
                    tmp_b = tmp_a*usfcm

                    a_m(ijk,0,0) = a_m(ijk,0,0) + tmp_a
                    b_m(ijk,0) = b_m(ijk,0) + tmp_b
                  END DO
               END IF
            END DO
         END DO

      ELSE IF(vv.EQ.1) THEN

         DO m = 1, mmax
            DO ijk = ijkstart3, ijkend3
               IF(fluid_at(ijk)) THEN
                  i = i_of(ijk)
                  j = j_of(ijk)
                  k = k_of(ijk)

                  DO in = 1, qmomk_nn
                     vsfcm = avg_y(qmomk_v1(in,ijk,m), qmomk_v1(in,north_of(ijk),m),j_of(ijk))
                     tmp_a = -avg_y(qmomk_f_gs(in,ijk,m),qmomk_f_gs(in,north_of(ijk),m),j)*vol_v(ijk)
                     tmp_b = tmp_a*vsfcm

                     a_m(ijk,0,0) = a_m(ijk,0,0) + tmp_a
                     b_m(ijk,0) = b_m(ijk,0) + tmp_b
                  END DO
               END IF

            END DO
         END DO
         close(900)

      ELSE IF(wv.EQ.1) THEN
         DO m = 1, mmax
            DO ijk = ijkstart3, ijkend3
               IF(fluid_at(ijk)) THEN
                  i = i_of(ijk)
                  j = j_of(ijk)
                  k = k_of(ijk)

                  DO in = 1, qmomk_nn
                     wsfcm = avg_z(qmomk_w1(in,ijk,m),qmomk_w1(in,top_of(ijk),m),k_of(ijk))
                     tmp_a = -avg_z(qmomk_f_gs(in,ijk,m),qmomk_f_gs(in,top_of(ijk),m),k)*vol_w(ijk)
                     tmp_b = tmp_a*wsfcm

                     a_m(ijk,0,0) = a_m(ijk,0,0) + tmp_a
                     b_m(ijk,0) = b_m(ijk,0) + tmp_b
                  END DO
               END IF
            END DO
         END DO

      END IF

      RETURN
      END SUBROUTINE qmomk_gas_drag