calc_nflux.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!                                                                      C
!  Module name: CALC_NFLUX(IER)                                        C
!  Purpose: Calculate the convection fluxes based on total species     C
!           number density for use with GHD theory only.               C
!           Adapted from routine calc_mflux.                           C
!                                                                      C
!  Author: S. Benyahia                                Date: 31-DEC-08  C
!  Reviewer:                                          Date:            C
!                                                                      C
!                                                                      C
!  Literature/Document References:                                     C
!      Christine Hrenya handnotes and my own derivation                C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
!
      SUBROUTINE calc_nflux()
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!
!  Include param.inc file to specify parameter values
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE parallel
      USE fldvar
      USE geometry
      USE physprop
      USE constant
      USE indices
      USE mflux
      USE compar
      USE functions
      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   D u m m y   A r g u m e n t s
!-----------------------------------------------
!
!
!
!                      Total Number density
      DOUBLE PRECISION Ni_E(dimension_3), Ni_N(dimension_3), Ni_T(dimension_3)
!
!                      Indices
      INTEGER          IJK, IMJK, IJMK, IJKM, L
!
!                      Particle mass
      DOUBLE PRECISION Mp_L
!
!  First compute total number density at faces
!!!$omp  parallel do private( IJK, IMJK, IJMK, IJKM) &
!!!$omp&  schedule(static)
      DO ijk = ijkstart3, ijkend3
        ni_e(ijk) = zero
        ni_n(ijk) = zero
        ni_t(ijk) = zero
!
        IF (fluid_at(ijk)) THEN
           DO l = 1, smax
             mp_l = ro_s(ijk,l) * pi*d_p(ijk,l)**3/6d0
             ni_e(ijk) = ni_e(ijk) + rop_se(ijk,l) / mp_l
             imjk = im_of(ijk)
             IF (.NOT.fluid_at(imjk)) THEN
                ni_e(imjk) = ni_e(imjk) + rop_se(imjk,l) / mp_l
             ENDIF
             ni_n(ijk) = ni_n(ijk) + rop_sn(ijk,l) / mp_l
             ijmk = jm_of(ijk)
             IF (.NOT.fluid_at(ijmk)) THEN
               ni_n(ijmk) = ni_n(ijmk) + rop_sn(ijmk,l) / mp_l
             ENDIF
!
             IF (do_k) THEN
               ni_t(ijk) = ni_t(ijk) + rop_st(ijk,l) / mp_l
               ijkm = km_of(ijk)
                 IF (.NOT.fluid_at(ijkm)) THEN
                   ni_t(ijkm) = ni_t(ijkm) + rop_st(ijkm,l) / mp_l
                 ENDIF
             ENDIF
           ENDDO
        ENDIF
      ENDDO

!
!  Interpolate the face value of density for calculating the convection fluxes
!!!$omp  parallel do private( IJK, IMJK, IJMK, IJKM) &
!!!$omp&  schedule(static)
      DO ijk = ijkstart3, ijkend3
!
         IF (fluid_at(ijk)) THEN
!
!         East face (i+1/2, j, k)
            flux_ne(ijk) = ni_e(ijk)*ayz(ijk)*u_s(ijk,mmax)
!
!         North face (i, j+1/2, k)
            flux_nn(ijk) = ni_n(ijk)*axz(ijk)*v_s(ijk,mmax)
!
!         Top face (i, j, k+1/2)
            IF (do_k) THEN
               flux_nt(ijk) = ni_t(ijk)*axy(ijk)*w_s(ijk,mmax)
            ENDIF
!
!         West face (i-1/2, j, k)
            imjk = im_of(ijk)
            IF (.NOT.fluid_at(imjk)) THEN
               flux_ne(imjk) = ni_e(imjk)*ayz(imjk)*u_s(imjk,mmax)
            ENDIF
!
!         South face (i, j-1/2, k)
            ijmk = jm_of(ijk)
            IF (.NOT.fluid_at(ijmk)) THEN
              flux_nn(ijmk) = ni_n(ijmk)*axz(ijmk)*v_s(ijmk,mmax)
            ENDIF
!
!         Bottom face (i, j, k-1/2)
            IF (do_k) THEN
               ijkm = km_of(ijk)
               IF (.NOT.fluid_at(ijkm)) THEN
                 flux_nt(ijkm) = ni_t(ijkm)*axy(ijkm)*w_s(ijkm,mmax)
               ENDIF
            ENDIF
         ENDIF
      END DO

      RETURN
      END SUBROUTINE calc_nflux

!// Comments on the modifications for DMP version implementation
!// 001 Include header file and common declarations for parallelization
!// 350 Changed do loop limits: 1,ijkmax2-> ijkstart3, ijkend3