check_bc_dem.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
! minimum amount of geometry data.                                     !
!                                                                      !
! Subroutine: CHECK_BC_DEM                                             !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Determine if BCs are "DEFINED" and that they contain the    !
! minimum amount of geometry data.                                     !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_dem(M_TOT)

! Global Variables:
!---------------------------------------------------------------------//
! User specified BC
      use bc
! User specified: BC geometry
      use bc, only: bc_ep_s
! Use specified flag for ignoring PO BC for discrete solids
      USE bc, only: bc_po_apply_to_des
! Solids phase identifier
      use run, only: solids_model
! Number of DEM inlet/outlet BCs detected.
      use des_bc, only: dem_bcmi, dem_bcmo
!
      use des_bc, only: dem_bcmi_map
      use des_bc, only: dem_bcmo_map
! Global Parameters:
!---------------------------------------------------------------------//
! The max number of BCs.
      use param, only: dimension_bc
! Parameter constants
      use param1, only: zero, undefined

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      IMPLICIT NONE


! Passed Arguments:
!---------------------------------------------------------------------//
! Total number of solids phases.
      INTEGER, INTENT(in) :: M_TOT

! Local Variables:
!---------------------------------------------------------------------//
! loop/variable indices
      INTEGER :: BCV, M
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BC_DEM")

! Initialize
      dem_bcmi = 0
      dem_bcmo = 0

! Loop over all BCs looking for DEM solids inlets/outlets
      DO bcv = 1, dimension_bc

         SELECT CASE (bc_type_enum(bcv))

! Determine the number of mass inlets that contain DEM solids.
         CASE (mass_inflow)
            m_lp: DO m=1,m_tot
               IF(solids_model(m)=='DEM' .AND.                         &
                  bc_ep_s(bcv,m) > zero) THEN
                  dem_bcmi = dem_bcmi + 1
                  dem_bcmi_map(dem_bcmi) = bcv
                  EXIT m_lp
               ENDIF
            ENDDO m_lp

! Count the number of pressure outflows.
         CASE (p_outflow,mass_outflow)
            IF(bc_po_apply_to_des(bcv)) then
               dem_bcmo = dem_bcmo + 1
               dem_bcmo_map(dem_bcmo) = bcv
            ENDIF

! Flag CG_MI as an error if DEM solids are present.
         CASE (cg_mi)
            DO m=1,m_tot
               IF(solids_model(m)=='DEM') THEN
                  IF(bc_ep_s(bcv,m) /= undefined .AND.                 &
                     bc_ep_s(bcv,m) > zero) THEN
                     WRITE(err_msg,1100) trim(ivar('BC_TYPE',bcv)),    &
                        'GC_MI'
                     CALL flush_err_msg(abort=.true.)
                  ENDIF
               ENDIF
            ENDDO

         CASE (cg_po)
            WRITE(err_msg,1100) trim(ivar('BC_TYPE',bcv)), 'GC_PO'
            CALL flush_err_msg(abort=.true.)

         CASE (outflow, p_inflow)
            WRITE(err_msg,1100) trim(ivar('BC_TYPE',bcv)),             &
               bc_type_enum(bcv)
            CALL flush_err_msg(abort=.true.)

         END SELECT

      ENDDO

      CALL finl_err_msg

      RETURN

 1100 FORMAT('Error 1100: Unsupported boundary condition specified ',  &
         'with',/'DEM simulation: ',a,' = ',a,/'Please correct the ',&
         'mfix.dat file.')

      END SUBROUTINE check_bc_dem