check_bqend.f

Go to the documentation of this file.

!----------------------------------------------------------------------!
!                                                                      !
!  Subroutine: CHECK_BATCH_QUEUE_END                                   !
!  Author: A.Gel                                      Date:            !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!----------------------------------------------------------------------!
      SUBROUTINE check_batch_queue_end(pEXIT_SIGNAL)

      use compar, only: pe_io
      use error_manager
      use machine, only: wall_time
      use run, only: get_tunit
      use mpi_utility, only: bcast
      use run, only: batch_wallclock
      use run, only: term_buffer
      use time_cpu, only: wall_start

      IMPLICIT NONE

      LOGICAL, INTENT(INOUT) :: pEXIT_SIGNAL

! Logical flags for hault cases.
      LOGICAL :: USER_HAULT, WALL_HAULT
! Elapsed wall time, and fancy formatted buffer/batch queue times.
      DOUBLE PRECISION :: WALL_STOP, FANCY_BUFF, FANCY_BATCH
! Time units for formatted output.
      CHARACTER(LEN=4) :: WT_UNIT, BF_UNIT, BC_UNIT

! Calculate the current elapsed wall time.
      wall_stop = wall_time()
      wall_stop = wall_stop - wall_start

! Set flags for wall time exceeded or user specified hault.
      wall_hault = ((wall_stop+term_buffer) >= batch_wallclock)
      INQUIRE(file="MFIX.STOP", exist=user_hault)

! Report that the max user wall time was reached and exit.
      IF(wall_hault) THEN
         CALL get_tunit(wall_stop,wt_unit)
         fancy_buff = term_buffer
         CALL get_tunit(fancy_buff, bf_unit)
         fancy_batch = batch_wallclock
         CALL get_tunit(fancy_batch, bc_unit)
         WRITE(err_msg, 1100) wall_stop, wt_unit, fancy_buff, bf_unit, &
            fancy_batch, bc_unit
         CALL flush_err_msg(header=.false., footer=.false.)
      ENDIF

 1100 FORMAT(2/,15('='),' REQUESTED CPU TIME LIMIT REACHED ',('='),/   &
         'Batch Wall Time:',3x,f9.2,1x,a,/'Elapsed Wall Time: ',f9.2,  &
         1x,a,/'Term Buffer:',7x,f9.2,a,/15('='),' REQUESTED CPU ',    &
         'TIME LIMIT REACHED ',('='))

! Report that the hault signal was detected.
      IF(user_hault) THEN
         WRITE(err_msg, 1200)
         CALL flush_err_msg(header=.false., footer=.false.)
      ENDIF

 1200 FORMAT(2/,19('='),' MFIX STOP SIGNAL DETECTED ',19('='),/'MFIX.',&
         'STOP file detected in run directory. Terminating MFIX.',/    &
         'Please DO NOT FORGET to erase the MFIX.STOP file before ',   &
         'restarting',/19('='),'MFIX STOP SIGNAL DETECTED ',19('='))

! This routine was restructured so all MPI ranks to the same action. As
! a result, broadcasting the BATCHQ flag may not be needed.
      pexit_signal = (wall_hault .OR. user_hault) .OR. pexit_signal
      call bcast (pexit_signal,pe_io)

      END SUBROUTINE check_batch_queue_end