accum_resid.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: ACCUM_RESID                                            C
!                                                                      C
!  Purpose: Accumulate all the residuals and calculate max_resid       C
!                                                                      C
!                                                                      C
!  Author: S. Pannala                                 Date: 14-Jun-07  C
!  Reviewer:                                          Date:            C
!                                                                      C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
!
      SUBROUTINE accum_resid
!
!-----------------------------------------------
!     M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE parallel
      USE geometry
      USE indices
      USE compar
      USE mpi_utility
      USE residual
      USE run
      IMPLICIT NONE
!-----------------------------------------------
!     G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!     D u m m y   A r g u m e n t s
!-----------------------------------------------
      INTEGER          M, NN

!-----------------------------------------------
!     Local variables
!-----------------------------------------------
      INTEGER              LOCAL_INDEX

!
      IF(debug_resid) Return
!
      local_index = 0

! Pack the numerators and denominators into one vector for performing single global operation

!!!$omp parallel do private( NN,M )&
!!!$omp&  REDUCTION(+:LOCAL_INDEX)
      DO nn = 2, nresid
         DO m = 0, dimension_m
            local_index = local_index + 1
            resid_pack(local_index) = num_resid(nn,m)
            local_index = local_index + 1
            resid_pack(local_index) = den_resid(nn,m)
         ENDDO
      ENDDO

      call global_all_sum(resid_pack)

! Unpack the numerators and denominators from the global sum vector

      local_index = 0

!!!$omp parallel do private( NN,M )&
!!!$omp&  REDUCTION(+:LOCAL_INDEX)
      DO nn = 2, nresid
         DO m = 0, dimension_m
            local_index = local_index + 1
            num_resid(nn,m) = resid_pack(local_index)
            local_index = local_index + 1
            den_resid(nn,m) = resid_pack(local_index)
         ENDDO
      ENDDO

!!!$omp parallel do private( NN,M )
      DO nn = 2, nresid
         DO m = 0, dimension_m
            IF (den_resid(nn,m) > zero) THEN
               resid(nn,m) = num_resid(nn,m)/den_resid(nn,m)
            ELSE IF (num_resid(nn,m) == zero) THEN
               resid(nn,m) = zero
            ELSE
               resid(nn,m) = undefined
!     WRITE (LINE, *) 'Warning: All center coefficients are zero.'
!     CALL WRITE_ERROR ('ACCUM_RESID', LINE, 1)
            ENDIF
         ENDDO
      ENDDO

      RETURN
      END