des_functions.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
!
!  Function: DES_GETINDEXFROMPOS
!  Purpose: Knowing the current particle x, y, or z position determine
!  the associated i, j or k index by searching a specific region defined
!  by a lower and upper limit on the index that is known to contain
!  the particles position
!
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

      INTEGER FUNCTION des_getindexfrompos(LIM1,LIM2,PART_POS,&
         grid_pos,axis,axis_index)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE compar
      USE funits
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! given i, j, or k index values defining the upper and lower limits of
! the region in space known to contain the particle
      INTEGER, INTENT (IN) :: LIM1, LIM2
! given current x, y, or z position of the particle
      DOUBLE PRECISION, INTENT (IN) :: PART_POS
! given position for the cell faces on the fluid grid in the x, y or z
! direction
      DOUBLE PRECISION, DIMENSION(:), INTENT (IN) :: GRID_POS
! given axis (x, y, or z) and associated index (i, j, or k)
      CHARACTER(LEN=1), INTENT (IN) :: AXIS, AXIS_INDEX
!-----------------------------------------------
! Local Variables
!-----------------------------------------------
! index & loop counter
      INTEGER IND
!-----------------------------------------------

! error condition
      ind = -1

      IF (lim1 <= lim2) THEN
         DO ind = lim1, lim2
            IF (part_pos >= grid_pos(ind-1) .AND. &
                part_pos <  grid_pos(ind)) EXIT
         ENDDO
      ELSEIF (lim1 > lim2) THEN
         DO ind = lim1, lim2, -1
            IF (part_pos >= grid_pos(ind-1) .AND. &
                part_pos <  grid_pos(ind)) EXIT
         ENDDO
      ENDIF

      IF (ind == -1) THEN
         WRITE (unit_log, 1001) axis_index, axis, part_pos, &
            axis_index, lim1, axis_index, lim2
         WRITE (*,1001) axis_index, axis, part_pos, &
            axis_index, lim1, axis_index, lim2
!         CALL MFIX_EXIT(myPE)
      ENDIF

      des_getindexfrompos = ind

      RETURN

 1001 FORMAT(/1x,70('*')//,' From: DES_GETINDEXFROMPOS',/,' Message: ',&
         'Could not identify the ', a, ' index associated with the ',&
         'particles ',/10x,a, '-position= ',es15.5,' between the ',&
         'limits ',a,'=',i5,/10x,' and ',a,'=',i5,'.',/1x,70('*')/)

      END FUNCTION des_getindexfrompos