read_particle_input.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
! Subroutine: READ_PAR_INPUT                                           !
!                                                                      !
! Purpose: Read the particle input and broadcasts the particle data to !
! respective processors.                                               !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE read_par_input

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE discretelement
      use cdist
      use compar
      use desmpi
      use error_manager
      use functions
      use funits
      use geometry, only: no_k
      use mpi_init_des, only: des_scatter_particle
      use mpi_utility

      implicit none
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! indices
      integer :: k
! index of particle
      INTEGER :: lcurpar
! local unit
      INTEGER, PARAMETER :: lunit=10
! local filename
      character(255) lfilename
! IO Status:
      INTEGER :: IOS
! Flag to indicate if file exists.
      LOGICAL :: lEXISTS
! Read dimension: 2D vs 3D data
      integer :: RDMN
!-----------------------------------------------


      CALL init_err_msg("READ_PAR_INPUT")


      ios = 0
      rdmn = merge(2,3,no_k)

! Setup the file name based on distributed or serial IO.
      IF(bdist_io) THEN
         lfilename = ''
         WRITE(lfilename,'("particle_input_",I4.4,".dat")') mype
      ELSE
         lfilename= "particle_input.dat"
      ENDIF

! Check the the file exists and open it.
      IF(bdist_io .OR. mype == pe_io) THEN
         INQUIRE(file=lfilename, exist=lexists)
         IF(.NOT.lexists) THEN
            WRITE(err_msg, 1100)
            CALL flush_err_msg
            ios = 1
         ELSE
            OPEN(convert='BIG_ENDIAN',unit=lunit, file=lfilename, form="FORMATTED")
         ENDIF
      ENDIF

! Collect the error message and quit.
      CALL global_all_sum(ios)
      IF(ios /= 0) CALL mfix_exit(mype)

 1100 FORMAT('Error 1100: FATAL - DEM particle input file not found!')

! Read the file
!----------------------------------------------------------------->>>
! In distributed IO the first line of the file will be number of
! particles in that processor
      IF (bdist_io) then
         read(lunit,*) pip
         DO lcurpar = 1,pip
            call set_normal(lcurpar)
            read (lunit,*) (des_pos_new(lcurpar,k),k=1,rdmn),&
               des_radius(lcurpar), ro_sol(lcurpar),&
               (des_vel_new(lcurpar,k),k=1,rdmn)
         ENDDO

! Serial IO (not bDIST_IO)
      ELSE
!----------------------------------------------------------------->>>

! Read into temporary variable and scatter
         IF (mype .eq. pe_io) THEN

! Allocate and initialize temporary variables.
            ALLOCATE (dpar_pos(particles,3)); dpar_pos=0.0
            ALLOCATE (dpar_vel(particles,3)); dpar_vel=0.0
            ALLOCATE (dpar_rad(particles));   dpar_rad=0.0
            ALLOCATE (dpar_den(particles));   dpar_den = 0.0
! Loop through the input file.
            DO lcurpar = 1, particles
               read (lunit,*,iostat=ios)                               &
               (dpar_pos(lcurpar,k),k=1,rdmn),dpar_rad(lcurpar),       &
               dpar_den(lcurpar),(dpar_vel(lcurpar,k),k=1,rdmn)

! Report read errors.
               IF(ios > 0) THEN
                  WRITE(err_msg,1200)
                  CALL flush_err_msg
                  EXIT
 1200 FORMAT('Error 1200: Error reported when reading particle input ',&
         'file.',/'A common error is 2D input for 3D cases.')

! Report End-of-File errors.
               ELSEIF(ios < 0) THEN
                  WRITE(err_msg,1201) &
                     trim(ival(lcurpar)), trim(ival(particles))
                  CALL flush_err_msg
                  EXIT
 1201 FORMAT('Error 1201: Error reported when reading particle input ',&
         'file.',/'End-of-File found for particle ',a,' and ',a,1x,    &
         'entries are expected.')

               ENDIF

            ENDDO

         ENDIF

         CALL global_all_sum(ios)
         IF(ios /= 0) CALL mfix_exit(mype)

         CALL des_scatter_particle

         IF(mype == pe_io) &
            deallocate (dpar_pos,dpar_vel,dpar_rad,dpar_den)

      ENDIF   ! end if/else bdist_io
!-----------------------------------------------------------------<<<

      IF(bdist_io .OR. mype == pe_io) CLOSE(lunit)

      CALL finl_err_msg()

      RETURN

      CALL mfix_exit(mype)

      END SUBROUTINE read_par_input