location_check.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: LOCATION_CHECK                                          !
!  Author: P. Nicoletti                               Date: 02-DEC-91  !
!                                                                      !
!  Purpose: Check calculated and given cell locations for consistency  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE location_check(CELL_SPECIFIED, CELL_CALCULATED,       &
         counter, message)

! Global variables:
!---------------------------------------------------------------------//
! Runtime flags stating direction is not solved.
      USE geometry, only: no_i, no_j, no_k
! Flag for reinitializing a run.
      use run, only: reinitializing

! Module procedure for error message management.
      use error_manager

      IMPLICIT NONE

! Dummy arguments:
!---------------------------------------------------------------------//
! Cell index specified in the input file.
      INTEGER, INTENT(INOUT) :: CELL_SPECIFIED
! Cell index calculated for location coordinate.
      INTEGER, INTENT(IN) :: CELL_CALCULATED
! Index for BC, IC, or IS
      INTEGER, INTENT(IN) :: COUNTER
! Error message to print out
      CHARACTER(len=*) :: MESSAGE
!......................................................................!

! During a reinitializing, "old" data is in the I/J/K arrays. This check
! overwrites the old data with the current calculated values.
      IF(reinitializing) cell_specified = cell_calculated

! Check that the cell_specified in the data input equals to the cell
! calculated.
      IF(cell_specified == cell_calculated) RETURN


      IF(no_k .AND. (message(6:6)=='b' .OR. message(6:6)=='t')) RETURN
      IF(no_j .AND. (message(6:6)=='s' .OR. message(6:6)=='n')) RETURN
      IF(no_i .AND. (message(6:6)=='w' .OR. message(6:6)=='e')) RETURN

      CALL init_err_msg('LOCATION_CHECK')

      WRITE(err_msg, 1000) message, counter, cell_specified,           &
         cell_calculated
      CALL flush_err_msg(abort=.true.)

 1000 FORMAT('Error 1000: IC, BC, OR IS consistency error for: ',a,/,  &
      'IC/BC/IS No',5x,'= ',i6,/,'Cell specified',2x,'= ',i6,/,        &
      'Cell calculated',1x,'= ',i6)

      CALL finl_err_msg()

      RETURN
      END SUBROUTINE location_check