vf_gs_x.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: VF_gs_X                                                 !
!  Author: M. Syamlal                                 Date: 20-MAY-96  !
!                                                                      !
!  Purpose: Calculate the average drag coefficient at i+1/2, j, k and  !
!           multiply with u-momentum cell volume.                      !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!

      SUBROUTINE vf_gs_x(VXF_GS)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE compar
      USE discretelement
      USE drag
      USE fun_avg
      USE functions
      USE geometry
      USE indices
      USE param
      USE param1
      USE physprop

      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! Volume x Drag
      DOUBLE PRECISION, INTENT(OUT) :: VxF_gs(dimension_3, dimension_m)
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Indices
      INTEGER :: I, IJK, IJKE
! Index of continuum solids phases
      INTEGER :: M
!-----------------------------------------------

      DO m = 1, smax
         DO ijk = ijkstart3, ijkend3
            IF(ip_at_e(ijk)) THEN
               vxf_gs(ijk,m) = zero
            ELSE
               i = i_of(ijk)
               ijke = east_of(ijk)
               vxf_gs(ijk,m) = vol_u(ijk) * &
                  avg_x(f_gs(ijk,m),f_gs(ijke,m),i)
            ENDIF
         ENDDO
      ENDDO

! Calculate the combined effect for all discrete solids.
      IF(discrete_element .AND. .NOT.des_oneway_coupled) THEN
         DO ijk = ijkstart3, ijkend3
            IF(ip_at_e(ijk)) THEN
               vxf_gds(ijk) = zero
            ELSE
               i = i_of(ijk)
               ijke = east_of(ijk)
               vxf_gds(ijk) = vol_u(ijk) *                             &
                  avg_x(f_gds(ijk),f_gds(ijke),i)
            ENDIF
         ENDDO
      ENDIF

      RETURN
      END SUBROUTINE vf_gs_x

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: VF_SS_X                                                 C
!  Purpose: Calculate the average Solid-Solid drag coefficient at      C
!           i+1/2, j, k and multiply with u-momentum cell volume.      C
!                                                                      C
!  Author: S. Dartevelle, LANL                        Date: 28-FEB-04  C
!  Reviewer:                                          Date:            C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE vf_ss_x(VXF_SS)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param
      USE param1
      USE geometry
      USE indices
      USE physprop
      USE compar
      USE drag
      USE discretelement
      USE fun_avg
      USE functions

      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! Volume x Drag
      DOUBLE PRECISION, INTENT(OUT) :: VxF_SS(dimension_3, dimension_lm)
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Indices
      INTEGER :: I, IJK, IJKE
! Index of continuum solids phases
      INTEGER :: L, M, LM
!-----------------------------------------------

! initialize every call
      vxf_ss(:,:) = zero

      DO m = 1, mmax
         DO l = 1, mmax
            lm = funlm(l,m)
            IF (l .NE. m) THEN
               DO ijk = ijkstart3, ijkend3
                  IF (.NOT.ip_at_e(ijk)) THEN
                     i = i_of(ijk)
                     ijke = east_of(ijk)
                     vxf_ss(ijk,lm) = avg_x(f_ss(ijk,lm),f_ss(ijke,lm),i)*vol_u(ijk)
                  ELSE     !Impermeable wall
                     vxf_ss(ijk,lm) = zero
                  ENDIF
               ENDDO
            ENDIF
         ENDDO   ! end do loop (l=1,mmax)
      ENDDO   ! end do loop (m=1,mmax

      IF (des_continuum_hybrid) THEN
         DO m = 1, mmax
            DO ijk = ijkstart3, ijkend3
               IF (ip_at_e(ijk)) THEN
                  vxf_sds(ijk,m) = zero
               ELSE
                  i = i_of(ijk)
                  ijke = east_of(ijk)
                  vxf_sds(ijk,m) = avg_x(f_sds(ijk,m),f_sds(ijke,m),i)*vol_u(ijk)
               ENDIF
            ENDDO   ! end do loop (dm=1,des_mmax)
         ENDDO   ! end do loop (m=1,mmax)
      ENDIF   ! end if (discrete_element and des_continuum_hybrid)

      RETURN
      END SUBROUTINE vf_ss_x