mfix.f

Go to the documentation of this file.

! -*- f90 -*-
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: MFIX                                                    !
!  Author: M. Syamlal                                 Date: 29-JAN-92  !
!                                                                      !
!  Purpose: The main module in the MFIX program                        !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
!

      PROGRAM mfix

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE discretelement, ONLY: des_continuum_coupled, discrete_element
      USE iterate, ONLY: converged, diverged, adjustdt
      USE iterate, ONLY: iterate_init, do_iteration, post_iterate
      USE iterate, ONLY: log_converged, log_diverged, nit, max_nit
      USE main, ONLY: add_command_line_argument, initialize, finalize, exit_signal
      USE run, ONLY:  dt, ier, dem_solids, pic_solids, steady_state, time, tstop
      USE step, ONLY: time_step_init, time_step_end

      IMPLICIT NONE

!-----------------------------------------------
! Local variables
!-----------------------------------------------

      INTEGER :: II
      CHARACTER(LEN=80) :: tmp

      DO ii=1, command_argument_count()
         CALL get_command_argument(ii,tmp)
         CALL add_command_line_argument(tmp)
      ENDDO

! Initialize the simulation
      CALL initialize

! Time march loop.

      IF(discrete_element .AND. .NOT.des_continuum_coupled) THEN

! Uncoupled discrete element simulations
         IF (dem_solids) CALL des_time_march
         IF (pic_solids) CALL pic_time_march

      ELSE

! Transient or steady state simulation
         DO WHILE (time + 0.1d0*dt < tstop .AND. .NOT. exit_signal)
            CALL time_step_init
            DO
               CALL iterate_init
               DO WHILE (nit<max_nit .AND. .NOT.(converged.OR.diverged))
                  nit = nit + 1
                  CALL do_iteration
               ENDDO

               CALL post_iterate

               IF(steady_state) EXIT
               IF(.NOT.adjustdt()) EXIT
            ENDDO
            CALL time_step_end
            IF (steady_state) EXIT
         ENDDO

      ENDIF
      CALL finalize

      stop
      END PROGRAM mfix