check_ic_mppic.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_IC_MPPIC                                          !
!  Author:   R.Garg                                   Date: 11-Mar-14  !
!                                                                      !
!  Purpose: check the initial conditions input section for MPPIC model !
!     - ensure the first IC is defined over the entire domain with     !
!        ep_g = 1 when more than one IC has solids                     !
!     - ensure the ICs are non-overlapping                             !
!     - calculate the number of particles needed to initialize the      !
!        MPPIC model                                                   !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_ic_mppic


! Runtime Flag: Generate initial particle configuration.
      USE discretelement, only : gener_part_config
! Simulation dimension (2D/3D)
      USE discretelement, only: dimn
! Number of DEM solids phases.
      USE discretelement, only: des_mmax

! Flag indicating that the IC region is defined.
      USE ic, only: ic_defined
! IC Region gas volume fraction.
      USE ic, only: ic_ep_g
! IC Region solid volume fraction.
      USE ic, only: ic_ep_s

      USE param1, only: zero, one

! MPPIC specific IC region specification.
      USE ic, only: ic_pic_const_npc, ic_pic_const_statwt
! Maximum number of IC regions and solids phases
      USE param, only: dimension_ic

! direction wise spans of the domain and grid spacing in each direction
      Use geometry, only: zlength, dz

      use physprop, only: mmax
      USE mpi_utility
      USE functions

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      implicit none

! Temp logical variables for checking constant npc and statwt specification
      LOGICAL :: CONST_NPC, CONST_STATWT

! Volume of the cell
      INTEGER :: ICV, M

      IF (.NOT.gener_part_config) RETURN

! Initialize the error manager.
      CALL init_err_msg("CHECK_IC_MPPIC")

! First check if either a constant npc or constant statwt
! is specified for each IC
      DO icv = 1, dimension_ic

         IF(.not.ic_defined(icv)) cycle

         IF (ic_ep_g(icv).lt.one) THEN
            DO m = mmax+1, des_mmax+mmax
               const_npc    = (ic_pic_const_npc  (icv, m) .ne. 0)
               const_statwt = (ic_pic_const_statwt(icv, m) .ne. zero  )
               IF(const_npc.and.const_statwt.and.ic_ep_s(icv,m).gt.zero) then
                  WRITE(err_msg, 1100) icv, m
                  CALL flush_err_msg(abort=.true.)
               ENDIF

               IF(.not.const_npc.and.(.not.const_statwt).and. &
               ic_ep_s(icv,m).gt.zero) then
                  WRITE(err_msg, 1101) icv, m
                  CALL flush_err_msg(abort=.true.)
               ENDIF
            ENDDO
         ENDIF
      ENDDO

 1100 FORMAT('Error 1100: In MPPIC model for IC # ',i5, &
      ' and solid phase # ', i5, /, &
      'Non zero Values specified for both ', &
      'IC_PIC_CONST_NPC and IC_PIC_CONST_STATWT.', /, &
      'Choose between constant number of parcels per cell or ', &
      'constant statistical weight', /, &
      'See MFIX readme',/'Please correct the data file.')


 1101 FORMAT('Error 1101: In MPPIC model for IC # ',i5, &
      ' and solid phase # ', i5, /, &
      'A non-zero value not specified for ', &
      'IC_PIC_CONST_NPC or IC_PIC_CONST_STATWT. ', /, &
      'Choose between constant number of parcels per cell or ', &
      'constant statistical weight', /, &
      'See MFIX readme',/'Please correct the data file.')



      IF(dimn.EQ.2) THEN
! require that DZ(1)/ZLENGTH be specified for 2-dimensional case.
! unclear why this cannot be one - other than the user may be unaware
! that a depth has been set (a value of one implies default setting)
         IF (dz(1) == one) THEN
            WRITE(*,'(5X,A,A,/5X,A,A)') &
            'For DIMN = 2, specify a value for DZ(1) or ',&
            'ZLENGTH in mfix.dat which is not',&
            'equal to one. If you want it to be one then ',&
            'set it close to one but not exactly one'
            CALL flush_err_msg(abort=.true.)
         ENDIF

         IF (dz(1) .NE. zlength) THEN
            WRITE(err_msg,'(5X,A,/5x,A,/5X,2(A20,2X,G17.8))')        &
            'For DIMN = 2, DZ(1) and ZLENGTH are used ',         &
            'interchangeably', ' Specify same values for ',      &
            'DZ(1) and ZLENGTH','DZ(1) = ', dz(1), 'ZLENGTH = ', &
            zlength
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF


      CALL finl_err_msg

      END SUBROUTINE check_ic_mppic