set_geometry1.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: SET_GEOMETRY1                                          C
!  Purpose: Calculate cell volumes and face areas                      C
!                                                                      C
!  Author: M. Syamlal                                 Date: 1-MAY-96   C
!  Reviewer:                                                           C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced: COORDINATES, IMAX2, DT, DX, JMAX2, DY, KMAX2, C
!                        DZ,                                           C
!                                                                      C
!  Variables modified:                                                 C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
!
      SUBROUTINE set_geometry1
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!
!  Include param.inc file to specify parameter values
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE parallel
      USE run
      USE geometry
      USE indices
      USE compar
      USE functions

      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   V a r i a b l e s
!-----------------------------------------------
!
!                      Indices
      INTEGER          I, J, K, IP, JP, KP, IJK
      INTEGER          i_cyl_min, i_cyl_max
!
!-----------------------------------------------
!
!                      Indices
!
!!!!$omp  parallel do private( I, J, K, IP, JP, KP, IJK)  &
!!!!$omp  schedule(dynamic,chunk_size)
!  For cylindrical_2D simulations
      IF(cylindrical_2d)THEN
         if(mod(imax,2).eq.1)then     ! odd
            i_cyl_min = (imax+1)/2 + 1 - i_cyl_num
            i_cyl_max = (imax+1)/2 + 1 + i_cyl_num
         else
            i_cyl_min = (imax)/2 + 2 - i_cyl_num
            i_cyl_max = (imax)/2 + 1 + i_cyl_num
         endif
      ENDIF

      DO ijk = ijkstart3, ijkend3

!
         i = i_of(ijk)
         ip = ip1(i)
         j = j_of(ijk)
         jp = jp1(j)
         k = k_of(ijk)
         kp = kp1(k)

         IF(.NOT.is_on_mype_plus2layers(i,j,k)) cycle
         IF (dead_cell_at(i,j,k)) cycle  ! skip dead cells

!
         vol(ijk) = dx(i)*dy(j)*(x(i)*dz(k))
         vol_u(ijk) = half*(dx(i)+dx(ip))*dy(j)*(half*(x(i)+x(ip))*dz(k))
         vol_v(ijk) = dx(i)*half*(dy(j)+dy(jp))*(x(i)*dz(k))
         vol_w(ijk) = dx(i)*dy(j)*(x(i)*half*(dz(k)+dz(kp)))
!
         ayz(ijk) = dy(j)*(x_e(i)*dz(k))
         ayz_u(ijk) = dy(j)*(x(ip)*dz(k))
         ayz_v(ijk) = half*(dy(j)+dy(jp))*(x_e(i)*dz(k))
         ayz_w(ijk) = dy(j)*(x_e(i)*half*(dz(k)+dz(kp)))
!
         axy(ijk) = dx(i)*dy(j)
         axy_u(ijk) = half*(dx(i)+dx(ip))*dy(j)
         axy_v(ijk) = dx(i)*half*(dy(j)+dy(jp))
         axy_w(ijk) = axy(ijk)
!
         axz(ijk) = dx(i)*(x(i)*dz(k))
         axz_u(ijk) = half*(dx(i)+dx(ip))*(half*(x(i)+x(ip))*dz(k))
         axz_v(ijk) = axz(ijk)
         axz_w(ijk) = dx(i)*(x(i)*half*(dz(k)+dz(kp)))


      if(cylindrical_2d)then
         vol(ijk) = dx(i)*dy(j)*(cyl_x(i))
         vol_u(ijk) = half*(dx(i)+dx(ip))*dy(j)*(half*(cyl_x(i)+cyl_x(ip)))
         vol_v(ijk) = dx(i)*half*(dy(j)+dy(jp))*(cyl_x(i))
         vol_w(ijk) = dx(i)*dy(j)*(cyl_x(i))
!
         ayz(ijk) = dy(j)*(cyl_x_e(i))
         ayz_u(ijk) = dy(j)*(cyl_x(ip))
         ayz_v(ijk) = half*(dy(j)+dy(jp))*(cyl_x_e(i))
         ayz_w(ijk) = dy(j)*(cyl_x_e(i))
!
         axy(ijk) = dx(i)*dy(j)
         axy_u(ijk) = half*(dx(i)+dx(ip))*dy(j)
         axy_v(ijk) = dx(i)*half*(dy(j)+dy(jp))
         axy_w(ijk) = axy(ijk)
!
         axz(ijk) = dx(i)*(cyl_x(i))
         axz_u(ijk) = half*(dx(i)+dx(ip))*(half*(cyl_x(i)+cyl_x(ip)))
         axz_v(ijk) = axz(ijk)
         axz_w(ijk) = dx(i)*(cyl_x(i))

         if(i.ge.i_cyl_min -i_cyl_transition .and. i.le.i_cyl_max +i_cyl_transition)then
            vol_u(ijk) = half*dx(i)*dy(j)*half*(half*(cyl_x_e(i-1) + cyl_x_e(i))+cyl_x_e(i)) + &
               half*dx(i+1)*dy(j)*half*(half*(cyl_x_e(i) + cyl_x_e(i+1))+cyl_x_e(i))
            axz_u(ijk) = half*dx(i)*half*(half*(cyl_x_e(i-1) + cyl_x_e(i))+cyl_x_e(i)) + &
               half*dx(i+1)*half*(half*(cyl_x_e(i) + cyl_x_e(i+1))+cyl_x_e(i))
         endif
      endif

      END DO
      RETURN
      END SUBROUTINE set_geometry1

!// Comments on the modifications for DMP version implementation
!// 350 1025 change do loop limits: 1,ijkmax2-> ijkstart3, ijkend3
!// 360 Check if i,j,k resides on current processor