vf_gs_y.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: VF_gs_Y                                                 C
!  Purpose: Calculate the average drag coefficient at i, j+1/2, k and  C
!           multiply with v-momentum cell volume.                      C
!                                                                      C
!  Author: M. Syamlal                                 Date: 17-JUN-96  C
!  Reviewer:                                          Date:            C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE vf_gs_y(VXF_GS)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param
      USE param1
      USE geometry
      USE indices
      USE physprop
      USE compar
      USE drag
      USE discretelement
      USE fun_avg
      USE functions

      IMPLICIT NONE
!-----------------------------------------------
! Volume x Drag
      DOUBLE PRECISION, INTENT(OUT) :: VxF_gs(dimension_3, dimension_m)
!-----------------------------------------------
! Local Variables
!-----------------------------------------------
! Indices
      INTEGER :: J, IJK, IJKN
! Index of continuum solids phases
      INTEGER :: M
!-----------------------------------------------


      DO m = 1, smax
         DO ijk = ijkstart3, ijkend3
            IF (ip_at_n(ijk)) THEN
               vxf_gs(ijk,m) = zero
            ELSE
               j = j_of(ijk)
               ijkn = north_of(ijk)
               vxf_gs(ijk,m) = vol_v(ijk) *                            &
                  avg_y(f_gs(ijk,m),f_gs(ijkn,m),j)
            ENDIF
         ENDDO
      ENDDO


      IF(discrete_element .AND. .NOT.des_oneway_coupled) THEN
         DO ijk = ijkstart3, ijkend3
            IF(ip_at_n(ijk)) THEN
               vxf_gds(ijk) = zero
            ELSE
               j = j_of(ijk)
               ijkn = north_of(ijk)
               vxf_gds(ijk) = vol_v(ijk) *                             &
                  avg_y(f_gds(ijk),f_gds(ijkn),j)
            ENDIF
         ENDDO
      ENDIF

      RETURN
      END SUBROUTINE vf_gs_y


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: VF_SS_Y                                                 C
!  Purpose: Calculate the average Solid-Solid drag coefficient at      C
!           i, j+1/2, k and multiply with V-momentum cell volume.      C
!                                                                      C
!  Author: S. Dartevelle, LANL                        Date: 28-FEB-04  C
!  Reviewer:                                          Date:            C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE vf_ss_y(VXF_SS)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param
      USE param1
      USE geometry
      USE indices
      USE physprop
      USE compar
      USE drag
      USE discretelement
      USE fun_avg
      USE functions

      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! Volume x Drag
      DOUBLE PRECISION, INTENT(OUT) :: VxF_SS(dimension_3, dimension_lm)
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Indices
      INTEGER :: J, IJK, IJKN
! Index of continuum solids phases
      INTEGER :: L, M, LM
!-----------------------------------------------

! initialize every call
      vxf_ss(:,:) = zero

      DO m = 1, mmax
         DO l = 1, mmax
            lm = funlm(l,m)
            IF (l .NE. m) THEN
               DO ijk = ijkstart3, ijkend3
                  IF (.NOT.ip_at_n(ijk)) THEN
                     j = j_of(ijk)
                     ijkn = north_of(ijk)
                     vxf_ss(ijk,lm) = avg_y(f_ss(ijk,lm),f_ss(ijkn,lm),j)*vol_v(ijk)
                  ELSE     !Impermeable wall
                     vxf_ss(ijk,lm) = zero
                  ENDIF
               ENDDO
            ENDIF
         ENDDO   ! end do loop (l=1,mmax)
      ENDDO   ! end do loop (m=1,mmax)

      IF (des_continuum_hybrid) THEN
! initialize every call
         DO m = 1, mmax
            DO ijk = ijkstart3, ijkend3
               IF (ip_at_n(ijk)) THEN
                  vxf_sds(ijk,m) = zero
               ELSE
                  j = j_of(ijk)
                  ijkn = north_of(ijk)
                  vxf_sds(ijk,m) = avg_y(f_sds(ijk,m),f_sds(ijkn,m),j)*vol_v(ijk)
               ENDIF
            ENDDO      ! end do loop (ijk=ijkstart3,ijkend3)
         ENDDO   ! end do loop (m=1,mmax)
      ENDIF   ! end if (discrete_element and des_continuum_hybrid)

      RETURN
      END SUBROUTINE vf_ss_y