check_run_control.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_RUN_CONTROL                                       !
!  Purpose: Check the run control namelist section                     !
!                                                                      !
!  Author: P.Nicoletti                                Date: 27-NOV-91  !
!          J.Musser                                   Date: 31-JAN-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_run_control


! Global Variables:
!---------------------------------------------------------------------//
! New or restart
      USE run, only: run_type
! Brief description of simulation.
      USE run, only: description
! Simulation units: SI, CGS
      USE run, only: units
! Simulation start/stop times.
      USE run, only: time, tstop
! Time step size, one over time step size.
      USE run, only: dt, odt, steady_state
! Flag: Use K-Epsilon turbulence model.
      USE run, only: k_epsilon
      USE run, only: ishii, jackson
! Turbulence lenghth scale and viscosity bound.
      use constant, only: l_scale0, mu_gmax

! Global Parameters:
!---------------------------------------------------------------------//
      USE param1, only: undefined, undefined_c
      USE param1, only: one, zero

! Global Module procedures:
!---------------------------------------------------------------------//
      USE error_manager

      IMPLICIT NONE


! Local Variables:
!---------------------------------------------------------------------//


!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_RUN_CONTROL")


! Clear out the run description if not specified.
      IF (description == undefined_c) description = ' '

! Verify UNITS input.
      IF(units == undefined_c) THEN
         WRITE(err_msg,1000) 'UNITS'
         CALL flush_err_msg(abort=.true.)
      ELSEIF((units /= 'CGS') .AND. (units /= 'SI')) THEN
         WRITE(err_msg,1001) 'UNITS', units
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Verify that DT is valid.
      IF (dt < zero) THEN
         WRITE(err_msg,1002) 'DT', dt
         CALL flush_err_msg(abort=.true.)

! Steady-state simulation.
      ELSEIF(dt == undefined .OR. dt == zero) THEN
         steady_state = .true.
         dt = zero
         odt = zero
         time = zero

! Transient simulation.
      ELSE
         steady_state = .false.
! Calculate reciprocal of initial timestep.
         odt = one/dt
! Verify the remaining time settings.
         IF (time == undefined) THEN
            WRITE(err_msg,1000) 'TIME'
            CALL flush_err_msg(abort=.true.)

         ELSEIF (tstop == undefined) THEN
            WRITE(err_msg,1000) 'TSTOP'
            CALL flush_err_msg(abort=.true.)

         ELSEIF (time < zero) THEN
            WRITE(err_msg,1002)'TIME', time
            CALL flush_err_msg(abort=.true.)

         ELSEIF (tstop < zero) THEN
            WRITE(err_msg,1002) 'TSTOP', tstop
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

! Verify the run type.
      IF(.NOT.(run_type=='NEW' .OR. run_type=='RESTART_1'              &
         .OR. run_type=='RESTART_2')) THEN
         WRITE(err_msg,1001) 'RUN_TYPE', run_type
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Turbulence model:
      IF (k_epsilon .AND. l_scale0 /= zero) THEN
         WRITE(err_msg,2001)
         CALL flush_err_msg(abort=.true.)
 2001 FORMAT('Error 2001: Cannot set K_EPSILON = .T. and specify ',    &
         'L_SCALE0 /= ZERO')
      ENDIF

! Ishii and jackson form of governing equations cannot both be invoked
      IF (ishii .AND. jackson) THEN
         WRITE(err_msg,2002)
         CALL flush_err_msg(abort=.true.)
 2002 FORMAT('Error 2002: Cannot set both ISHII = .T. and JACKSON = ',&
             '.T.',/,'Please correct the mfix.dat file.')
      ENDIF

!  Check whether MU_gmax is specified for turbulence (sof)
      IF (k_epsilon .AND. mu_gmax==undefined) THEN
         WRITE(err_msg, 1000) 'MU_GMAX'
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Clear the error manager
      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/      &
         'Please correct the mfix.dat file.')

 1002 FORMAT('Error 1002: Illegal or unknown input: ',a,' = ',g14.4,/  &
         'Please correct the mfix.dat file.')

 1003 FORMAT('Error 1003: Illegal or unknown input: ',a,' = ',i4,/     &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_run_control