vf_gs_z.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: VF_gs_Z                                                 C
!  Purpose: Calculate the average drag coefficient at i, j, k+1/2 and  C
!           multiply with W-momentum cell volume.                      C
!                                                                      C
!  Author: M. Syamlal                                 Date: 17-JUN-96  C
!  Reviewer:                                          Date:            C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE vf_gs_z(VXF_GS)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param
      USE param1
      USE geometry
      USE indices
      USE physprop
      USE compar
      USE drag
      USE discretelement
      USE fun_avg
      USE functions

      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! Volume x Drag
      DOUBLE PRECISION, INTENT(OUT) :: VxF_gs(dimension_3, dimension_m)
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Indices
      INTEGER :: K, IJK, IJKT
! Index of continuum solids phases
      INTEGER :: M
!-----------------------------------------------


      DO m = 1, smax
         DO ijk = ijkstart3, ijkend3
            IF(ip_at_t(ijk)) THEN
               vxf_gs(ijk,m) = zero
            ELSE
               k = k_of(ijk)
               ijkt = top_of(ijk)
               vxf_gs(ijk,m) = vol_w(ijk) *                            &
                  avg_z(f_gs(ijk,m),f_gs(ijkt,m),k)
            ENDIF
         ENDDO
      ENDDO


      IF(discrete_element .AND. .NOT.des_oneway_coupled) THEN
         DO ijk = ijkstart3, ijkend3
            IF (ip_at_t(ijk)) THEN
               vxf_gds(ijk) = zero
            ELSE
               k = k_of(ijk)
               ijkt = top_of(ijk)
               vxf_gds(ijk) = vol_w(ijk) *                             &
                  avg_z(f_gds(ijk),f_gds(ijkt),k)
            ENDIF
         ENDDO
      ENDIF


      RETURN
      END SUBROUTINE vf_gs_z


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: VF_SS_Z                                                 C
!  Purpose: Calculate the average Solid-Solid drag coefficient at      C
!           i, j, k+1/2 and multiply with W-momentum cell volume.      C
!                                                                      C
!  Author: S. Dartevelle, LANL                        Date: 28-FEB-04  C
!  Reviewer:                                          Date:            C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE vf_ss_z(VXF_SS)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param
      USE param1
      USE geometry
      USE indices
      USE physprop
      USE compar
      USE drag
      USE discretelement
      USE fun_avg
      USE functions

      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! Volume x Drag
      DOUBLE PRECISION, INTENT(OUT) :: VxF_SS(dimension_3, dimension_lm)
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Indices
      INTEGER :: K, IJK, IJKT
! Index of continuum solids phases
      INTEGER :: L, M, LM
!-----------------------------------------------

! initialize every call
      vxf_ss(:,:) = zero

      DO m = 1, mmax
         DO l = 1, mmax
            lm = funlm(l,m)
            IF (l .NE. m) THEN
               DO ijk = ijkstart3, ijkend3
                  IF(ip_at_t(ijk)) THEN
                     vxf_ss(ijk,lm) = zero
                  ELSE     !Impermeable wall
                     k = k_of(ijk)
                     ijkt = top_of(ijk)
                     vxf_ss(ijk,lm) = avg_z(f_ss(ijk,lm),f_ss(ijkt,lm),k)*vol_w(ijk)
                  ENDIF
               ENDDO
            ENDIF
         ENDDO   ! end do loop (l=1,mmax)
      ENDDO   ! end do loop (m=1,mmax)

      IF (des_continuum_hybrid) THEN
         DO m = 1, mmax
            DO ijk = ijkstart3, ijkend3
               IF(ip_at_t(ijk)) THEN
                  vxf_sds(ijk,m) = zero
               ELSE
                  k = k_of(ijk)
                  ijkt = top_of(ijk)
                  vxf_sds(ijk,m) = avg_z(f_sds(ijk,m),f_sds(ijkt,m),k)*vol_w(ijk)
               ENDIF
            ENDDO      ! end do loop (ijk=ijkstart3,ijkend3)
         ENDDO   ! end do loop (m=1,mmax)
      ENDIF   ! end if (discrete_element and des_continuum_hybrid)

      RETURN
      END SUBROUTINE vf_ss_z