read_res0_des.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: DES_READ_RESTART                                        !
!  Purpose : Reads either single restart file or multiple restart      !
!  fles (based on bdist_io) flag.                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE read_res0_des

      use cdist
      use compar
      use des_allocate
      use des_bc
      use des_rxns
      use des_thermo
      use desmpi
      use discretelement
      use error_manager
      use machine
      use mfix_pic, only: mppic, des_stat_wt
      use mpi_utility
      use param, only: dimension_n_s
      use read_res1_des
      use run

      implicit none

      INTEGER :: LC1, LC2
      INTEGER :: lDIMN, lNEXT_REC

      INTEGER :: lVAR_SIZE
      DOUBLE PRECISION :: VERSION

      ldimn = merge(2,3,no_k)

      CALL init_read_res_des(trim(run_name), version, lnext_rec)

      CALL read_res_des(lnext_rec, vtp_findex)
      CALL read_res_des(lnext_rec, tecplot_findex)
      CALL read_res_des(lnext_rec, dtsolid)

! Position data is read and used to setup pARRAY reads.
      CALL read_par_pos(lnext_rec)

      CALL read_res_parray(lnext_rec, iglobal_id)

      CALL read_res_parray(lnext_rec, particle_state)

      DO lc1 = 1, ldimn
         CALL read_res_parray(lnext_rec, des_vel_new(:,lc1))
      ENDDO

      DO lc1 = 1, merge(1,3,no_k)
         CALL read_res_parray(lnext_rec, omega_new(:,lc1))
      ENDDO

      CALL read_res_parray(lnext_rec, des_radius)
      CALL read_res_parray(lnext_rec, ro_sol)

      IF(mppic) CALL read_res_parray(lnext_rec, des_stat_wt)
      IF(energy_eq) CALL read_res_parray(lnext_rec, des_t_s)

      IF(any_species_eq) THEN
        CALL read_res_parray(lnext_rec, pijk(:,5))
        DO lc1=1, dimension_n_s
            CALL read_res_parray(lnext_rec, des_x_s(:,lc1))
         ENDDO
      ENDIF

      IF(version >= 1.1) THEN
         CALL read_res_des(lnext_rec, lvar_size)
         DO lc1=1, lvar_size
            if(lvar_size <= des_usr_var_size) &
            CALL read_res_parray(lnext_rec, des_usr_var(lc1,:))
         ENDDO
      ENDIF

! RES2 does not need the collision of BC information.
      IF(run_type == 'RESTART_2') RETURN

! Collision/neighbor data is read and used to setup cARRAY reads.
      IF(.NOT.mppic) THEN
         CALL read_par_col(lnext_rec)
         DO lc1=1, ldimn
            CALL read_res_carray(lnext_rec, pft_neighbor(lc1,:))
         ENDDO
      ENDIF

! Save the number of BCMI's read from input file, then read the
! value from the restart file.
      CALL read_res_des(lnext_rec, dem_bcmi)

! Allocation of MIs is done here to ignore changes to the mfix.dat
! file during RES1.
      IF(dem_bcmi > 0) CALL allocate_dem_mi

! Only save the number of mass inflows for RESTART_1. This allows
! for mass inflows to be added/removed with RESTART_2.
! Todo: Prune entering/exiting flagged particles for RESTART_2.
      DO lc1=1, dem_bcmi
         CALL read_res_des(lnext_rec, dem_mi_time(lc1))
         CALL read_res_des(lnext_rec, dem_mi(lc1)%VACANCY)
         CALL read_res_des(lnext_rec, dem_mi(lc1)%OCCUPANTS)
         CALL read_res_des(lnext_rec, dem_mi(lc1)%WINDOW)
         CALL read_res_des(lnext_rec, dem_mi(lc1)%OFFSET)
         CALL read_res_des(lnext_rec, dem_mi(lc1)%L)

         lc2 = dem_mi(lc1)%OCCUPANTS

         allocate(dem_mi(lc1)%W(lc2))
         CALL read_res_des(lnext_rec, dem_mi(lc1)%W(:))
         allocate(dem_mi(lc1)%H(lc2))
         CALL read_res_des(lnext_rec, dem_mi(lc1)%H(:))
         allocate(dem_mi(lc1)%P(lc2))
         CALL read_res_des(lnext_rec, dem_mi(lc1)%P(:))
         allocate(dem_mi(lc1)%Q(lc2))
         CALL read_res_des(lnext_rec, dem_mi(lc1)%Q(:))
      ENDDO

      CALL finl_read_res_des


      WRITE(err_msg,"('DES restart file read at Time = ',g12.5)") time
      CALL flush_err_msg(header=.false., footer=.false.)

      RETURN
      END SUBROUTINE read_res0_des