des_thermo_mod.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: DES_THERMO                                             !
!  Author: J.Musser                                   Date: 16-Jun-10  !
!                                                                      !
!  Purpose: Common elements for MFIX-DEM heat transfer.                !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      MODULE des_thermo

      USE param, only: dim_m

! Heat transfer correlation specified in mfix.dat
! Default [RANZ_1952]
      CHARACTER(LEN=24) :: des_conv_corr

      INTEGER :: des_conv_corr_enum
      INTEGER, PARAMETER :: ranz_1952 = 0

! Run time flags for calculating the various modes of heat transfer
      LOGICAL :: calc_conv_des = .false.
      LOGICAL :: calc_cond_des(dim_m) = .false.
      LOGICAL :: calc_radt_des(dim_m) = .false.

! Particle properties
!-----------------------------------------------------------------------
! Particle temperature
      DOUBLE PRECISION, ALLOCATABLE :: des_t_s(:)

! DES specific heat of particles by particle
      DOUBLE PRECISION, ALLOCATABLE :: des_c_ps(:)

! Emissivity of particles
      DOUBLE PRECISION :: des_em(dim_m)
! Stefan-Boltzmann Constant
      DOUBLE PRECISION :: sb_const
! Bulk solids temperature for radiative heat transfer
      DOUBLE PRECISION, ALLOCATABLE :: avgdes_t_s(:)

! Convective heat transfer coefficient TIMES particle surface area
      DOUBLE PRECISION, ALLOCATABLE :: gammaxsa(:)


! Thermodynamic Neighborhood
!-----------------------------------------------------------------------
! Fluid Lens Proportion Constant used to calculate the radius of the
! fluid lens that surrounds the particle for particle-fluid-particle
! conduction.  Default [ 0.2 ]
      DOUBLE PRECISION :: flpc

! Mininum separation distance between the surface of two contacting
! particles. This value is used to remove the singluarity that the
! particle-fluid-particle conduciton model develops at the contact
! interface. [4.0x10^(-10) meters]
      DOUBLE PRECISION :: des_min_cond_dist



! Rates of heat transfer
!-----------------------------------------------------------------------
! Generic heat transfer source to the particle.
      DOUBLE PRECISION, ALLOCATABLE :: q_source(:), q_source0(:)
! Convective heat transfer source
      DOUBLE PRECISION, ALLOCATABLE :: conv_qs(:)
! Heat source resulting from chemical reactions
      DOUBLE PRECISION, ALLOCATABLE :: rxns_qs(:)


! Fluid/Particle coupling
!---------------------------------------------------------------------//
! Gas Phase Energy Eq source terms for gas-particle convection
      DOUBLE PRECISION, ALLOCATABLE :: conv_sc(:), conv_sp(:)

      contains


!----------------------------------------------------------------------!
! Function: CALC_Cp_DES                                                !
! Author: J.Musser                                    Date: 11-DEC-15  !
!                                                                      !
! Purpose: Calculate the specific heat of a particle.                  !
!----------------------------------------------------------------------!
      PURE DOUBLE PRECISION FUNCTION calc_cp_des(pNP)

! Universal gas constant in cal/mol.K
      use constant, only: rgas => gas_const_cal
! Calculate the specific heat from polynomical data obtained from the
! thermodynamic databases.
      use read_thermochemical, only: calc_cpor
! Number of species comprising species
      use physprop, only: nmax_s
      use physprop, only: c_ps0
      use physprop, only: mw_s
      use discretelement, only: pijk
      use des_rxns, only: des_x_s
      use run, only: units

      use param1, only: zero, undefined

      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
      INTEGER, INTENT(IN) :: pNP
!     DOUBLE PRECISION, INTENT(IN) :: pTs
! Local Variables
!---------------------------------------------------------------------//
! loop counter and error indicator
      INTEGER :: NN, IER, MM
      DOUBLE PRECISION :: lTs
!......................................................................!

! Temperature of particle
      lts = des_t_s(pnp)
! Phase of particle.
      mm=pijk(pnp,5)

! Calculate the specific heat based on the species composition of the
! particle and the data from the thermodynamic databases.
      IF(c_ps0(mm) == undefined) THEN
         calc_cp_des = zero
         DO nn = 1, nmax_s(mm)
            calc_cp_des = calc_cp_des + calc_cpor(lts, mm, nn) *  &
               des_x_s(pnp,nn)*rgas / mw_s(mm,nn)
         ENDDO
! Convert to SI units if needed.
         IF (units == 'SI') calc_cp_des = 4183.925d0*calc_cp_des
      ELSE
! If a constant value specific heat has been assigned to the particle
! in the mfix.dat file, use this value.
         calc_cp_des = c_ps0(mm)
      ENDIF
      END FUNCTION calc_cp_des

      END MODULE des_thermo