write_res0_des.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvc
!
!  module name: des_write_restart
!  purpose: writing des data for restart
!
!  Author : Pradeep G
!  Purpose : Reads either single restart file or multiple restart files
!            (based on bdist_io) flag
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^c
      subroutine write_res0_des

      use compar
      use des_bc
      use des_rxns
      use des_thermo
      use discretelement
      use error_manager
      use mfix_pic, only: des_stat_wt
      use mfix_pic, only: mppic
      use mpi_utility
      use param, only: dimension_n_s
      use param1
      use run
      use write_res1_des

      implicit none
!-----------------------------------------------
! local variables
!-----------------------------------------------
      INTEGER :: LC1
      INTEGER :: lNEXT_REC
      INTEGER :: lDIMN

      DOUBLE PRECISION :: VERSION

! Set the version of the DES RES file.
      version = 1.1

! Set the output dimension.
      ldimn = merge(2,3,no_k)

      CALL init_write_res_des(trim(run_name), version, lnext_rec)

      CALL write_res_des(lnext_rec, vtp_findex)
      CALL write_res_des(lnext_rec, tecplot_findex)
      CALL write_res_des(lnext_rec, dtsolid)

      DO lc1 = 1, ldimn
         CALL write_res_parray(lnext_rec, des_pos_new(:,lc1))
      ENDDO

      CALL write_res_parray(lnext_rec, iglobal_id)

      CALL write_res_parray(lnext_rec, particle_state)

      DO lc1 = 1, ldimn
         CALL write_res_parray(lnext_rec, des_vel_new(:,lc1))
      ENDDO

      DO lc1 = 1, merge(1,3,no_k)
         CALL write_res_parray(lnext_rec, omega_new(:,lc1))
      ENDDO

      CALL write_res_parray(lnext_rec, des_radius)
      CALL write_res_parray(lnext_rec, ro_sol)

      IF(mppic) &
         CALL write_res_parray(lnext_rec, des_stat_wt)

      IF(energy_eq) &
         CALL write_res_parray(lnext_rec, des_t_s)

      IF(any_species_eq) THEN
         CALL write_res_parray(lnext_rec, pijk(:,5))
         DO lc1=1, dimension_n_s
            CALL write_res_parray(lnext_rec, des_x_s(:,lc1))
         ENDDO
      ENDIF

! DES User defined variable :: added for VERSION>= 1.1
      CALL write_res_des(lnext_rec, des_usr_var_size)
      DO lc1=1,des_usr_var_size
         CALL write_res_parray(lnext_rec, des_usr_var(lc1,:))
      ENDDO


      IF(.NOT.mppic) THEN
         CALL write_res_carray(lnext_rec, neighbors(:), ploc2glb=.true.)
         CALL write_res_carray(lnext_rec, neighbor_index(:), ploc2glb=.true.)
      ENDIF

      DO lc1=1, ldimn
         CALL write_res_carray(lnext_rec,pft_neighbor(lc1,:))
      ENDDO

      CALL write_res_des(lnext_rec, dem_bcmi)
      DO lc1=1, dem_bcmi
         CALL write_res_des(lnext_rec, dem_mi_time(lc1))
         CALL write_res_des(lnext_rec, dem_mi(lc1)%VACANCY)
         CALL write_res_des(lnext_rec, dem_mi(lc1)%OCCUPANTS)
         CALL write_res_des(lnext_rec, dem_mi(lc1)%WINDOW)
         CALL write_res_des(lnext_rec, dem_mi(lc1)%OFFSET)
         CALL write_res_des(lnext_rec, dem_mi(lc1)%L)
         CALL write_res_des(lnext_rec, dem_mi(lc1)%W(:))
         CALL write_res_des(lnext_rec, dem_mi(lc1)%H(:))
         CALL write_res_des(lnext_rec, dem_mi(lc1)%P(:))
         CALL write_res_des(lnext_rec, dem_mi(lc1)%Q(:))
      ENDDO

      CALL finl_write_res_des

      RETURN
      END SUBROUTINE write_res0_des