out_array_kc.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: OUT_ARRAY_KC (ARRAY, K)                                C
!  Purpose: print out a 2D (constant k-plane) array to standard output C
!           (character)                                                C
!                                                                      C
!  Author: P.Nicoletti                                Date: 02-DEC-91  C
!  Reviewer: W. Rogers, M. Syamlal, S. Venkatesan     Date: 31-JAN-92  C
!                                                                      C
!  Revision Number:                                                    C
!  Purpose:                                                            C
!  Author:                                            Date: dd-mmm-yy  C
!  Reviewer:                                          Date: dd-mmm-yy  C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced: IMAX2, JMAX2                                  C
!  Variables modified: None                                            C
!                                                                      C
!  Local variables: NCOL, NTAB, LL1, LL2, LL3, IFORM1, IFORM2, IJK, IJ2
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE out_array_kc(ARRAY)
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE geometry
      USE fldvar
      USE physprop
      USE indices
      USE funits
      USE compar
      USE mpi_utility
      USE functions
      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   D u m m y   A r g u m e n t s
!-----------------------------------------------
!
!                      2D array to print out
      CHARACTER(LEN=4) :: ARRAY(*)
!
! local variables
!
!                      A line of characters to print
      CHARACTER(LEN=132) :: LINE
!
!                      number of columns to print out across the page
      INTEGER          NCOL
!
!                      number of tables the 2D array must be split into
!                      for printing
      INTEGER          NTAB
!
!                      loop indices
      INTEGER          LL1, LL2, LL3, LL4
!
!                      start and end 'I' for current table
      INTEGER          IFORM1 , IFORM2
!
!                      start 'IJ' and end 'IJ' for a given 'J' to print out
      INTEGER          IJK , IJ2
!
!-----------------------------------------------

!
! NOTE:  IF NCOL IS CHANGED TO A NUMBER OTHER THAN 24, THEN THE "24"
!        IN FORMATS 5050 AND 5100 MUST BE CHANGED TO THAT NUMBER.
!
      ncol = 24
      ntab = imax2/ncol + 1
      IF (mod(imax2,ncol) == 0) ntab = ntab - 1
!
      DO ll1 = 1, ntab
         iform1 = 1 + ncol*(ll1 - 1)
         iform2 = ncol*ll1
         iform2 = min(iform2,imax2)
         WRITE (unit_out, 5050) (ll3,ll3=iform1,iform2)
         DO ll2 = jmax2, 1, -1
            ijk = funijk_io(iform1,ll2,1)
            ij2 = funijk_io(iform2,ll2,1)
!efd
            WRITE (line, 5100) ll2, (array(ll3),ll3=ijk,ij2)

            ll4 = 12 + (iform2 - iform1 + 1)*5
            WRITE (unit_out, '(A)') line(1:ll4)
         END DO
      END DO


 5050 FORMAT(3x,'J',3x,'I=',3x,24(i3,2x))
 5100 FORMAT(1x,i3,8x,24(a4,1x))
      RETURN
      END SUBROUTINE out_array_kc