vavg_u_g.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: VAVG_U_g                                               C
!  Purpose: Volume average U_g                                         C
!                                                                      C
!  Author: M. Syamlal                                 Date: 28-APR-94  C
!  Reviewer:                                          Date: dd-mmm-yy  C
!                                                                      C
!  Revision Number:                                                    C
!  Purpose:                                                            C
!  Author:                                            Date: dd-mmm-yy  C
!  Reviewer:                                          Date: dd-mmm-yy  C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!                                                                      C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
!
      DOUBLE PRECISION FUNCTION vavg_u_g ()
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE bc
      USE compar
      USE fldvar
      USE functions
      USE geometry
      USE indices
      USE mpi_utility
      USE parallel
      USE param
      USE param1
      USE physprop
      USE run
      USE utilities, ONLY: mfix_isnan
      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   V a r i a b l e s
!-----------------------------------------------
!
!                      Indices
      INTEGER          IJK
!
!                      Integral of U_g*EP_g for entire volume
      DOUBLE PRECISION SUM_U_g
!
!                      Total volume of computational cells
      DOUBLE PRECISION SUM_VOL

!  Integrate the velocity values for the whole domain,
!
      sum_u_g = zero
      sum_vol = zero


!!!!$omp   parallel do private(IJK) reduction(+:SUM_VOL,SUM_U_G)
      DO ijk = ijkstart3, ijkend3
      IF(.NOT.is_on_mype_wobnd(i_of(ijk), j_of(ijk), k_of(ijk))) cycle
         IF (fluid_at(ijk)) THEN
            sum_vol = sum_vol + vol_u(ijk)
            sum_u_g = sum_u_g + u_g(ijk)*ep_g(ijk)*vol_u(ijk)
         ENDIF
      END DO

      CALL global_all_sum(sum_vol)
      CALL global_all_sum(sum_u_g)

      vavg_u_g = sum_u_g/sum_vol
!
! uncomment the following lines to enable trapping NaN's.
!      IF( mfix_isnan(VAVG_U_G) ) THEN
!        write(*,*) VAVG_U_G,  ' NaN being caught in VAVG_U_G.f '
!        AUTOMATIC_RESTART = .TRUE.
!      ENDIF
!
      RETURN
      END FUNCTION vavg_u_g



      DOUBLE PRECISION FUNCTION vavg_flux_u_g ()
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE parallel
      USE run
      USE fldvar
      USE bc
      USE geometry
      USE physprop
      USE indices
      USE compar
      USE mpi_utility
      USE mflux
      USE functions

      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   V a r i a b l e s
!-----------------------------------------------
!
!                      Indices
      INTEGER          IJK
!
!                      Integral of U_g*ROP_g*Area
      DOUBLE PRECISION SUM_U_g
!
!                      Total area of computational cells
      DOUBLE PRECISION SUM_AREA

!  Integrate the velocity values for the whole domain,
!
      sum_u_g = zero
      sum_area = zero


!!!!$omp   parallel do private(IJK) reduction(+:SUM_AREA,SUM_U_G)
      DO ijk = ijkstart3, ijkend3
      IF(.NOT.is_on_mype_wobnd(i_of(ijk), j_of(ijk), k_of(ijk))) cycle
         IF (fluid_at(ijk)) THEN
           IF(.NOT.added_mass) THEN
              sum_u_g = sum_u_g + flux_ge(ijk)
           ELSE
              sum_u_g = sum_u_g + flux_gse(ijk)
           ENDIF
           sum_area = sum_area + ayz(ijk)
         ENDIF
      END DO

      CALL global_all_sum(sum_area)
      CALL global_all_sum(sum_u_g)

      vavg_flux_u_g = sum_u_g/sum_area
!
      RETURN
      END FUNCTION vavg_flux_u_g