cfwallposvel.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
!
!  Subroutine: CFWALLPOSVEL
!  Purpose: Calculate the position and velocity of wall particle
!
!  Author: Jay Boyalakuntla                           Date: 12-Jun-04
!  Reviewer:                                          Date:
!
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

      SUBROUTINE cfwallposvel(L, IW, WALL_POS, WALL_VEL)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE discretelement
      USE des_bc
      USE param
      USE param1
      USE parallel
      USE fldvar
      USE run
      USE geometry
      USE indices
      USE physprop
      USE drag
      USE constant
      USE compar
      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
! particle no. index
      INTEGER, INTENT(IN) :: L
! index of wall no. (1-6)
      INTEGER, INTENT(IN) :: IW
! wall position is returned, set based on particle position and radius
      DOUBLE PRECISION, INTENT(INOUT) :: WALL_POS(3)
! wall velocity is returned, set based on any wall bc settings
      DOUBLE PRECISION, INTENT(INOUT) :: WALL_VEL(3)
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! solids phase index of particle L
      INTEGER M
! local value for particle radius
      DOUBLE PRECISION DES_R
!-----------------------------------------------

! initialize wall velocity
      wall_vel = zero
      wall_pos = zero

      des_r = des_radius(l)

! Assigning wall position and velocity
! Find which solids phase the particle belongs to
      m = pijk(l,5)

! west wall; in 3D on yz plane (x=wx1->0)
      IF(iw.EQ.1) THEN
         wall_pos(1) = wx1 - des_r
         wall_pos(2) = des_pos_new(l,2)
         IF(do_k) wall_pos(3) = des_pos_new(l,3)

         wall_vel(1) = zero
         wall_vel(2) = des_bc_vw_s(iw,m)
         IF(do_k) wall_vel(3) = des_bc_ww_s(iw,m)

         wall_normal(1,1) = -one
         wall_normal(1,2) = zero
         wall_normal(1,3) = zero

! east wall; in 3D on yz plane (x=ex2->xlength)
      ELSEIF(iw.EQ.2) THEN
         wall_pos(1) = ex2 + des_r
         wall_pos(2) = des_pos_new(l,2)
         IF(do_k) wall_pos(3) = des_pos_new(l,3)

         wall_vel(1) = zero
         wall_vel(2) = des_bc_vw_s(iw,m)
         IF(do_k) wall_vel(3) = des_bc_ww_s(iw,m)

         wall_normal(2,1) = one
         wall_normal(2,2) = zero
         wall_normal(2,3) = zero

! bottom wall; in 3D on xz plane (y=by1->0)
      ELSEIF(iw.EQ.3) THEN
         wall_pos(1) = des_pos_new(l,1)
         wall_pos(2) = by1 - des_r
         IF(do_k) wall_pos(3) = des_pos_new(l,3)

         wall_vel(1) = des_bc_uw_s(iw,m)
         wall_vel(2) = zero
         IF(do_k) wall_vel(3) = des_bc_ww_s(iw,m)

         wall_normal(3,1) = zero
         wall_normal(3,2) = -one
         wall_normal(3,3) = zero

! top wall; in 3D on xz plane (y=ty2->ylength)
      ELSEIF(iw.EQ.4) THEN
         wall_pos(1) = des_pos_new(l,1)
         wall_pos(2) = ty2 + des_r
         IF(do_k) wall_pos(3) = des_pos_new(l,3)

         wall_vel(1) = des_bc_uw_s(iw,m)
         wall_vel(2) = zero
         IF(do_k) wall_vel(3) = des_bc_ww_s(iw,m)

         wall_normal(4,1) = zero
         wall_normal(4,2) = one
         wall_normal(4,3) = zero

! south wall; in 3D on xy plane (z=sz1->0)
      ELSEIF(iw.EQ.5) THEN
         wall_pos(1) = des_pos_new(l,1)
         wall_pos(2) = des_pos_new(l,2)
         wall_pos(3) = sz1 - des_r

         wall_vel(1) = des_bc_uw_s(iw,m)
         wall_vel(2) = des_bc_vw_s(iw,m)
         wall_vel(3) = zero

         wall_normal(5,1) = zero
         wall_normal(5,2) = zero
         wall_normal(5,3) = -one

! north wall; in 3D on xy plane (z=nz2->zlength)
      ELSEIF(iw.EQ.6) THEN
         wall_pos(1) = des_pos_new(l,1)
         wall_pos(2) = des_pos_new(l,2)
         wall_pos(3) = nz2 + des_r

         wall_vel(1) = des_bc_uw_s(iw,m)
         wall_vel(2) = des_bc_vw_s(iw,m)
         wall_vel(3) = zero

         wall_normal(6,1) = zero
         wall_normal(6,2) = zero
         wall_normal(6,3) = one

      ENDIF

      RETURN
      END SUBROUTINE cfwallposvel