check_ic_dem.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_IC_DEM                                            !
!  Author:   R.Garg                                   Date: 11-Mar-14  !
!                                                                      !
!  Purpose: check the initial conditions input section for DEM model   !
!     - calculate the number of particles needed to initialize the      !
!        DEM model                                                     !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_ic_dem

! Global variables
!---------------------------------------------------------------------//
! Runtime Flag: Generate initial particle configuration.
      USE discretelement, only : gener_part_config
! Simulation dimension (2D/3D)
      USE discretelement, only: dimn
! Number of DEM solids phases.
      USE discretelement, only: des_mmax
! runtime flag to specify if the simulation uses both discrete/continuum
! solids
      USE discretelement, only: des_continuum_hybrid

! direction wise spans of the domain and grid spacing in each direction
      Use geometry, only: zlength
! Use the error manager for posting error messages.
      use error_manager

      use physprop, only: mmax, d_p0
      use toleranc

      implicit none
! Local variables
!---------------------------------------------------------------------//
      integer :: dm
!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("CHECK_IC_DEM")

! Determine the domain volume which is used to calculate the total
! number of particles and the number of particles in each phase.
! Values of DZ(1) or zlength are guaranteed at this point due to
! check_geometry_prereqs. If the user left both undefined and
! NO_K = .T., then they are set to ONE. If dz(1) is undefined but
! zlength is defined, then dz(1) is set to zlength (and vice versa).
! If both are defined they must be equal.
      IF(dimn.EQ.2) THEN
         IF (des_mmax.EQ.1) THEN
! account for a possible offset index when using d_p0 and ro_s.
            dm = mmax+1
! Warn the user if the domain depth is not equal to the particle
! diameter as it may cause problems for coupled simulations.
! The user should also be aware of this when interpreting
! volume/void fraction calculations (including bulk density).
            IF(.NOT.compare(zlength,d_p0(dm))) THEN
               WRITE(err_msg, 1000) ival(d_p0(dm))
               CALL flush_err_msg
            ENDIF
         ELSE
! Let the user know basis of depth dimension for calculating number of
! particles. this will also be important when considering volume/void
! fraction calculations.
            WRITE(err_msg, 1001)
            CALL flush_err_msg
         ENDIF
      ENDIF


 1000 FORMAT(' Message: ',&
      'WARNING: zlength or dz(1) is used to calculate the ',&
      'number of particles in the 2D simulation when ',&
      'GENER_PART_CONFIG is T and DIMN = 2.',/10x,'This depth ',&
      'does not equal D_P0 = ', a, '.')

 1001 FORMAT(' Message: ',&
      'WARNING: zlength or dz(1) is used to calculate the ',&
      'number of particles in the 2D simulation when ',&
      'GENER_PART_CONFIG is T and DIMN = 2.')


      IF (gener_part_config.and.des_continuum_hybrid) THEN
         WRITE(err_msg, 999)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 999  format('Error # 999: Gener_part_config set to', &
      ' true for DES_continuum hybrid', /, &
      ' This is not allowed, specify the initial particle', &
      ' configuration explicitly', /, &
      ' See MFIX readme', /,  &
      ' Please correct the data file.')

      CALL finl_err_msg

      END SUBROUTINE check_ic_dem