calc_gamma_des.f

Go to the documentation of this file.

#include "version.inc"
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  Subroutine: DES_CALC_GAMMA                                          !
!                                                                      !
!  Purpose: Calculate the heat transfer coefficient (GAMMAxSA) for     !
!  particle-fluid heat transfer.                                       !
!                                                                      !
!  Author: J.Musser                                   Date: 16-Jun-10  !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!  REF: Ranz, W.E. and Marshall, W.R., "Friction and transfer          !
!       coefficients for single particles and packed beds," Chemical   !
!       Engineering Science, Vol. 48, No. 5, pp 247-253, 1925.         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_gamma_des(NP, pGAMMA)

      USE compar
      USE constant
      USE des_thermo
      USE discretelement
      USE exit, only: mfix_exit
      USE fldvar
      USE geometry
      USE indices
      USE param1
      USE physprop
      USE fun_avg
      USE functions

      IMPLICIT NONE

! Passed variables
!---------------------------------------------------------------------//
! Index value of particle
      INTEGER, INTENT(IN) :: NP
! Convective heat transfer coefficient
      DOUBLE PRECISION, INTENT(OUT) :: pGAMMA

! Local variables
!---------------------------------------------------------------------//
! Fluid cell indices
      INTEGER IMJK, IJMK, IJKM
! Double precision value for 1/3
      DOUBLE PRECISION, PARAMETER  :: THIRD = (1.0d0/3.0d0)

      DOUBLE PRECISION N_Pr  ! Prandtl Number
      DOUBLE PRECISION N_Re  ! Reynolds Number
      DOUBLE PRECISION N_Nu  ! Nusselt Number

! Magnitude of slip velocity
      DOUBLE PRECISION SLIP
! Fluid velocity
      DOUBLE PRECISION cUg, cVg, cWg
      DOUBLE PRECISION Us, Vs, Ws
! Index value of fluid cell
      INTEGER :: IJK
!---------------------------------------------------------------------//

      ijk = pijk(np,4)
! Initialization
      imjk = im_of(ijk)
      ijmk = jm_of(ijk)
      ijkm = km_of(ijk)

      SELECT CASE(des_conv_corr_enum)

         CASE (ranz_1952) ! (Ranz and Mrshall, 1952)
! Initialize variables
            slip = zero
            n_re = zero
            n_nu = zero
! Gas velocity in fluid cell IJK
            cug = avg_x_e(u_g(imjk), u_g(ijk), 1)
            cvg = avg_y_n(v_g(ijmk), v_g(ijk))
! Particle Velocity
            us = des_vel_new(np,1)
            vs = des_vel_new(np,2)

! Calculate the magnitude of the slip velocity
            IF(no_k) THEN
               slip = sqrt((cug-us)**2 + (cvg-vs)**2)
            ELSE
               cwg = avg_z_t(w_g(ijkm), w_g(ijk))
               ws = des_vel_new(np,3)
               slip = sqrt((cug-us)**2 + (cvg-vs)**2 + (cwg-ws)**2)
            ENDIF

! Calculate the Prandtl Number
            IF(k_g(ijk) > zero) THEN
               n_pr = (c_pg(ijk)*mu_g(ijk))/k_g(ijk)
            ELSE
               n_pr = large_number
            ENDIF

! Calculate the particle Reynolds Number
            IF(mu_g(ijk) > zero) THEN
               n_re = (2.0d0*des_radius(np)*slip*ro_g(ijk)) / mu_g(ijk)
            ELSE
               n_re = large_number
            ENDIF

! Calculate the Nusselt Number
            n_nu = 2.0d0 + 0.6d0 *((n_re)**half * (n_pr)**third)

! Calculate the convective heat transfer coefficient
            pgamma = (n_nu * k_g(ijk))/(2.0d0 * des_radius(np))

         CASE DEFAULT
            WRITE(*,*)'INVALID DES CONVECTION MODEL'
            error_stop 'INVALID DES CONVECTION MODEL'
            CALL mfix_exit(mype)
      END SELECT

      RETURN
      END SUBROUTINE calc_gamma_des