set_phase_index.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: SET_PHASE_INDEX                                         !
!                                                                      !
!  Purpose: Set the index of all particles based on their diameter and !
!  density.                                                            !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE set_phase_index

! Modules
!---------------------------------------------------------------------//
      use discretelement, only: pijk
      USE discretelement, only: des_radius, ro_sol
      USE discretelement, only: des_mmax
      USE discretelement, only: max_pip
      USE functions, only: is_nonexistent, is_ghost, is_entering_ghost
      USE functions, only: is_exiting_ghost
      USE error_manager
      use mpi_funs_des, only: des_par_exchange
      use mpi_utility
      use param1, only: small_number
      USE physprop, only: mmax, d_p0, ro_s0
      USE run, only: run_type, solids_model
      USE run, only: any_species_eq
      use sendrecv
      IMPLICIT NONE

! Local Variables
!---------------------------------------------------------------------//
! particle no.
      INTEGER :: L
! solids phase no.
      INTEGER :: M
! May need to offset index when using d_p0 and ro_s
      INTEGER :: DM
! IER for error reporting
      INTEGER :: IER
! Difference between a particles diameter (density) and the diameter
! (density) of a phase specified in the data file.
      DOUBLE PRECISION dDp, dRho
!......................................................................!


! The restart file contains the phase index for reacting cases as the
! diameter and/or density of the particle may have changed.
      IF(run_type /= 'NEW' .AND. any_species_eq) RETURN

! Initialize the error flag.
      ier = 0

! solids phase index of particle.
! ---------------------------------------------------------------->>>
      DO l = 1, max_pip
         IF(is_nonexistent(l)) cycle
         IF(is_ghost(l) .OR. is_entering_ghost(l) .OR. is_exiting_ghost(l)) cycle

! Determining the solids phase of each particle by matching the diameter
! and density to those specified in the data file.
         m_lp: DO m = mmax+1, mmax+des_mmax
            ddp  = abs(2.0d0*des_radius(l)-d_p0(m))
            drho = abs( ro_sol(l)-ro_s0(m))
            IF( ddp < small_number .AND. drho < small_number) THEN
               pijk(l,5) = m
               EXIT m_lp
            ENDIF
         ENDDO m_lp
! Flag error if no match is found.
         IF(pijk(l,5).EQ.0) ier = 1
      ENDDO

! Sync up the error flag across all processes.
      CALL global_all_sum(ier)
      IF(ier == 0) RETURN

! Point of no return: Report errors and abort
!----------------------------------------------------------------------
      CALL init_err_msg("SET_PHASE_INDEX")

      CALL open_pe_log(ier)

      WRITE(err_msg, 1100)
      CALL flush_err_msg(footer=.false.)

 1100 FORMAT('Error 1100: Unable to determine the phase of one or ',&
         'more particles.',/8x,'ID',4x,'Diameter',6x,'Density',/)

      DO l = 1, max_pip
! skipping particles that do not exist
         IF(is_nonexistent(l)) cycle
         IF(is_ghost(l) .OR. is_entering_ghost(l) .OR. is_exiting_ghost(l)) cycle

! Flag as an error if no match is found.
         IF(pijk(l,5).EQ.0) THEN
            WRITE(err_msg,9000) l,  2.0*des_radius(l), ro_sol(l)
            CALL flush_err_msg(header=.false., footer=.false.)
         ENDIF
      ENDDO

      WRITE(err_msg, 1101)
      CALL flush_err_msg(header=.false., footer=.false.)

 1101 FORMAT(' ',/'Defined phase parameters from mfix.dat:',/3x,'ID',&
         5x,'Diameter',5x,'Density')

      DO m = mmax+1, des_mmax+mmax
         WRITE(err_msg, 9000) m, d_p0(m), ro_s0(m)
         CALL flush_err_msg(header=.false., footer=.false.)
      ENDDO

      WRITE(err_msg, 1102)
      CALL flush_err_msg(header=.false., abort=.true.)

 1102 FORMAT('Please correct the mfix.dat or particle_input.dat files.')

 9000 FORMAT(i10,2(2x,g12.5))

      END SUBROUTINE set_phase_index